git.mutantstargoat.com Git - faros-demo/blob - glsl-noise/periodic/3d.glsl

   1 //
   2 // GLSL textureless classic 3D noise "cnoise",
   3 // with an RSL-style periodic variant "pnoise".
   4 // Author:  Stefan Gustavson (stefan.gustavson@liu.se)
   5 // Version: 2011-10-11
   6 //
   7 // Many thanks to Ian McEwan of Ashima Arts for the
   8 // ideas for permutation and gradient selection.
   9 //
  10 // Copyright (c) 2011 Stefan Gustavson. All rights reserved.
  11 // Distributed under the MIT license. See LICENSE file.
  12 // https://github.com/ashima/webgl-noise
  13 //
  14
  15 vec3 mod289(vec3 x)
  16 {
  17   return x - floor(x * (1.0 / 289.0)) * 289.0;
  18 }
  19
  20 vec4 mod289(vec4 x)
  21 {
  22   return x - floor(x * (1.0 / 289.0)) * 289.0;
  23 }
  24
  25 vec4 permute(vec4 x)
  26 {
  27   return mod289(((x*34.0)+1.0)*x);
  28 }
  29
  30 vec4 taylorInvSqrt(vec4 r)
  31 {
  32   return 1.79284291400159 - 0.85373472095314 * r;
  33 }
  34
  35 vec3 fade(vec3 t) {
  36   return t*t*t*(t*(t*6.0-15.0)+10.0);
  37 }
  38
  39 // Classic Perlin noise, periodic variant
  40 float pnoise(vec3 P, vec3 rep)
  41 {
  42   vec3 Pi0 = mod(floor(P), rep); // Integer part, modulo period
  43   vec3 Pi1 = mod(Pi0 + vec3(1.0), rep); // Integer part + 1, mod period
  44   Pi0 = mod289(Pi0);
  45   Pi1 = mod289(Pi1);
  46   vec3 Pf0 = fract(P); // Fractional part for interpolation
  47   vec3 Pf1 = Pf0 - vec3(1.0); // Fractional part - 1.0
  48   vec4 ix = vec4(Pi0.x, Pi1.x, Pi0.x, Pi1.x);
  49   vec4 iy = vec4(Pi0.yy, Pi1.yy);
  50   vec4 iz0 = Pi0.zzzz;
  51   vec4 iz1 = Pi1.zzzz;
  52
  53   vec4 ixy = permute(permute(ix) + iy);
  54   vec4 ixy0 = permute(ixy + iz0);
  55   vec4 ixy1 = permute(ixy + iz1);
  56
  57   vec4 gx0 = ixy0 * (1.0 / 7.0);
  58   vec4 gy0 = fract(floor(gx0) * (1.0 / 7.0)) - 0.5;
  59   gx0 = fract(gx0);
  60   vec4 gz0 = vec4(0.5) - abs(gx0) - abs(gy0);
  61   vec4 sz0 = step(gz0, vec4(0.0));
  62   gx0 -= sz0 * (step(0.0, gx0) - 0.5);
  63   gy0 -= sz0 * (step(0.0, gy0) - 0.5);
  64
  65   vec4 gx1 = ixy1 * (1.0 / 7.0);
  66   vec4 gy1 = fract(floor(gx1) * (1.0 / 7.0)) - 0.5;
  67   gx1 = fract(gx1);
  68   vec4 gz1 = vec4(0.5) - abs(gx1) - abs(gy1);
  69   vec4 sz1 = step(gz1, vec4(0.0));
  70   gx1 -= sz1 * (step(0.0, gx1) - 0.5);
  71   gy1 -= sz1 * (step(0.0, gy1) - 0.5);
  72
  73   vec3 g000 = vec3(gx0.x,gy0.x,gz0.x);
  74   vec3 g100 = vec3(gx0.y,gy0.y,gz0.y);
  75   vec3 g010 = vec3(gx0.z,gy0.z,gz0.z);
  76   vec3 g110 = vec3(gx0.w,gy0.w,gz0.w);
  77   vec3 g001 = vec3(gx1.x,gy1.x,gz1.x);
  78   vec3 g101 = vec3(gx1.y,gy1.y,gz1.y);
  79   vec3 g011 = vec3(gx1.z,gy1.z,gz1.z);
  80   vec3 g111 = vec3(gx1.w,gy1.w,gz1.w);
  81
  82   vec4 norm0 = taylorInvSqrt(vec4(dot(g000, g000), dot(g010, g010), dot(g100, g100), dot(g110, g110)));
  83   g000 *= norm0.x;
  84   g010 *= norm0.y;
  85   g100 *= norm0.z;
  86   g110 *= norm0.w;
  87   vec4 norm1 = taylorInvSqrt(vec4(dot(g001, g001), dot(g011, g011), dot(g101, g101), dot(g111, g111)));
  88   g001 *= norm1.x;
  89   g011 *= norm1.y;
  90   g101 *= norm1.z;
  91   g111 *= norm1.w;
  92
  93   float n000 = dot(g000, Pf0);
  94   float n100 = dot(g100, vec3(Pf1.x, Pf0.yz));
  95   float n010 = dot(g010, vec3(Pf0.x, Pf1.y, Pf0.z));
  96   float n110 = dot(g110, vec3(Pf1.xy, Pf0.z));
  97   float n001 = dot(g001, vec3(Pf0.xy, Pf1.z));
  98   float n101 = dot(g101, vec3(Pf1.x, Pf0.y, Pf1.z));
  99   float n011 = dot(g011, vec3(Pf0.x, Pf1.yz));
 100   float n111 = dot(g111, Pf1);
 101
 102   vec3 fade_xyz = fade(Pf0);
 103   vec4 n_z = mix(vec4(n000, n100, n010, n110), vec4(n001, n101, n011, n111), fade_xyz.z);
 104   vec2 n_yz = mix(n_z.xy, n_z.zw, fade_xyz.y);
 105   float n_xyz = mix(n_yz.x, n_yz.y, fade_xyz.x);
 106   return 2.2 * n_xyz;
 107 }
 108
 109 #pragma glslify: export(pnoise)