git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # OpenGL ES support
  28 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  29 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  30
  31
  32 SET(FREEGLUT_HEADERS
  33     include/GL/freeglut.h
  34     include/GL/freeglut_ext.h
  35     include/GL/freeglut_std.h
  36     include/GL/glut.h
  37 )
  38 SET(FREEGLUT_SRCS
  39     ${FREEGLUT_HEADERS}
  40     src/fg_callbacks.c
  41     src/fg_cursor.c
  42     src/fg_display.c
  43     src/fg_ext.c
  44     src/fg_font_data.c
  45     src/fg_gamemode.c
  46     src/fg_init.c
  47     src/fg_internal.h
  48     src/fg_input_devices.c
  49     src/fg_joystick.c
  50     src/fg_main.c
  51     src/fg_misc.c
  52     src/fg_overlay.c
  53     src/fg_spaceball.c
  54     src/fg_state.c
  55     src/fg_stroke_mono_roman.c
  56     src/fg_stroke_roman.c
  57     src/fg_structure.c
  58     src/fg_videoresize.c
  59     src/fg_window.c
  60 )
  61 # TODO: OpenGL ES requires a compatible version of these files:
  62 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  63     LIST(APPEND FREEGLUT_SRCS
  64         src/fg_font.c
  65         src/fg_geometry.c
  66         src/fg_menu.c
  67         src/fg_teapot.c
  68     )
  69 ELSE()
  70     LIST(APPEND FREEGLUT_SRCS
  71         src/gles_stubs.c
  72     )
  73 ENDIF()
  74
  75 IF(WIN32)
  76     LIST(APPEND FREEGLUT_SRCS
  77         src/mswin/fg_cursor_mswin.c
  78         src/mswin/fg_display_mswin.c
  79         src/mswin/fg_ext_mswin.c
  80         src/mswin/fg_gamemode_mswin.c
  81         src/mswin/fg_init_mswin.c
  82         src/mswin/fg_internal_mswin.h
  83         src/mswin/fg_input_devices_mswin.c
  84         src/mswin/fg_joystick_mswin.c
  85         src/mswin/fg_main_mswin.c
  86         src/mswin/fg_menu_mswin.c
  87         src/mswin/fg_spaceball_mswin.c
  88         src/mswin/fg_state_mswin.c
  89         src/mswin/fg_structure_mswin.c
  90         src/mswin/fg_window_mswin.c
  91         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  92     )
  93     IF (MSVC AND NOT CMAKE_CL_64)
  94         # .def file only for 32bit Windows builds
  95         LIST(APPEND FREEGLUT_SRCS
  96             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
  97         )
  98     ENDIF()
  99
 100 ELSEIF(ANDROID)
 101     LIST(APPEND FREEGLUT_SRCS
 102         src/egl/fg_internal_egl.h
 103         src/egl/fg_display_egl.c
 104         src/egl/fg_init_egl.c
 105         src/egl/fg_structure_egl.c
 106         src/egl/fg_structure_egl.h
 107         src/egl/fg_window_egl.c
 108         src/egl/fg_window_egl.h
 109         src/android/native_app_glue/android_native_app_glue.c
 110         src/android/native_app_glue/android_native_app_glue.h
 111         src/android/fg_runtime_android.c
 112         src/android/fg_gamemode_android.c
 113         src/android/fg_structure_android.c
 114         src/android/fg_init_android.c
 115         src/android/fg_input_devices_android.c
 116         src/android/fg_joystick_android.c
 117         src/android/fg_main_android.c
 118         src/android/fg_spaceball_android.c
 119         src/android/fg_state_android.c
 120         src/android/fg_window_android.c
 121         src/android/fg_internal_android.h
 122     )
 123 ELSE()
 124     LIST(APPEND FREEGLUT_SRCS
 125         src/x11/fg_cursor_x11.c
 126         src/x11/fg_display_x11.c
 127         src/x11/fg_ext_x11.c
 128         src/x11/fg_gamemode_x11.c
 129         src/x11/fg_glutfont_definitions_x11.c
 130         src/x11/fg_init_x11.c
 131         src/x11/fg_internal_x11.h
 132         src/x11/fg_input_devices_x11.c
 133         src/x11/fg_joystick_x11.c
 134         src/x11/fg_main_x11.c
 135         src/x11/fg_menu_x11.c
 136         src/x11/fg_spaceball_x11.c
 137         src/x11/fg_state_x11.c
 138         src/x11/fg_structure_x11.c
 139         src/x11/fg_window_x11.c
 140         src/x11/fg_xinput_x11.c
 141     )
 142 ENDIF()
 143
 144 # For OpenGL ES (GLES):
 145 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 146 #   bootstrap headers inclusion in freeglut_std.h; these constants
 147 #   also need to be defined in client applications (e.g through
 148 #   pkg-config), but use GLES constants directly for all other needs
 149 # - define GLES version-specific library
 150 IF(FREEGLUT_GLES2)
 151   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 152   LIST(APPEND LIBS GLESv2 EGL)
 153 ELSEIF(FREEGLUT_GLES1)
 154   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 155   LIST(APPEND LIBS GLESv1 EGL)
 156 ELSE()
 157   FIND_PACKAGE(OpenGL REQUIRED)
 158   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 159   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 160 ENDIF()
 161
 162 # lib m for math, not needed on windows
 163 IF (NOT WIN32)
 164     LIST(APPEND LIBS m)
 165 ENDIF()
 166
 167 IF(WIN32)
 168     # hide insecure CRT warnings, common practice
 169     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 170 ENDIF()
 171
 172 if(UNIX AND NOT ANDROID)
 173     FIND_PACKAGE(X11 REQUIRED)
 174     LIST(APPEND LIBS ${X11_LIBRARIES})
 175     IF(X11_Xrandr_FOUND)
 176         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 177         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 178     ENDIF()
 179     IF(X11_xf86vmode_FOUND)
 180         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 181         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 182         IF(NOT "${X11_Xxf86vm_LIB}")
 183             SET(X11_Xxf86vm_LIB "Xxf86vm")
 184         ENDIF()
 185         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 186     ENDIF()
 187 ENDIF()
 188
 189 INCLUDE(CheckIncludeFiles)
 190 INCLUDE(CheckFunctionExists)
 191 INCLUDE(CheckTypeSize)
 192 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 193 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 194 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 195 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 196 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 197 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 198 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 199 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 200 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 201 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 202 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 203 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 204 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 205 IF (NOT HAVE_XPARSEGEOMETRY)
 206    LIST(APPEND FREEGLUT_SRCS
 207         src/util/xparsegeometry_repl.c
 208         src/util/xparsegeometry_repl.h)
 209    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 210 ENDIF()
 211 # decide on suitable type for internal time keeping, 64-bit if possible
 212 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 213 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 214 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 215     IF (MSVC)
 216         # Some old Microsoft VC don't support unsigned long long, but all we
 217         # care about support unsigned __int64, so test for presence of that
 218         # type
 219         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 220     ELSEIF()
 221         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 222     ENDIF()
 223 ENDIF()
 224
 225
 226 # The generated config.h is placed in the project's build directory, just to
 227 # ensure that all CMake-generated files are kept away from the main source tree.
 228 # As a result, the build directory must to be added to the include path list.
 229 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 230 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 231 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 232 IF(WIN32)
 233     # we also have to generate freeglut.rc, which contains the version
 234     # number
 235     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 236     IF (MSVC AND NOT CMAKE_CL_64)
 237         # .def file only for 32bit Windows builds with Visual Studio
 238         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 239     ENDIF()
 240 ENDIF()
 241
 242 IF(BUILD_SHARED_LIBS)
 243     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 244 ENDIF()
 245 IF(BUILD_STATIC_LIBS)
 246     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 247 ENDIF()
 248
 249
 250 IF(WIN32)
 251     LIST(APPEND LIBS winmm)
 252     IF(BUILD_SHARED_LIBS)
 253         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 254     ENDIF()
 255     IF(BUILD_STATIC_LIBS)
 256         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 257         # need to set machine:x64 for linker, at least for VC10, and
 258         # doesn't hurt for older compilers:
 259         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 260         IF (CMAKE_CL_64)
 261             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 262         ENDIF()
 263     ENDIF()
 264 ELSE()
 265     # on UNIX we need to make sure:
 266     # - all shared libraries must have a soname/version, see :
 267     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 268     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 269     #   Current: -version-info 12:0:9 -> 3.9.0
 270     # - the output library should be named glut so it'll be linkable with -lglut
 271     # - the shared library should link to the dependency libraries so that the user
 272     #   won't have to link them explicitly (they shouldn't have to know that we depend
 273     #   on Xrandr or Xxf86vm)
 274     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 275     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 276     IF(ANDROID)
 277         # Not in CMake toolchain file, because the toolchain
 278         # file is called several times and generally doesn't
 279         # seem to be meant for modifying CFLAGS:
 280         # '-mandroid' is not mandatory but doesn't hurt
 281         # '-O0 -gstabs+' helps the currently buggy GDB port
 282         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 283         # Not using _INIT variables, they seem to be used internally only
 284         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 285         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 286     ENDIF()
 287 ENDIF()
 288 IF(BUILD_SHARED_LIBS)
 289     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 290 ENDIF()
 291 IF(BUILD_STATIC_LIBS)
 292     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 293 ENDIF()
 294
 295 IF(BUILD_SHARED_LIBS)
 296     INSTALL(TARGETS freeglut DESTINATION lib)
 297 ENDIF()
 298 IF(BUILD_STATIC_LIBS)
 299     INSTALL(TARGETS freeglut_static DESTINATION lib)
 300 ENDIF()
 301 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 302
 303
 304
 305 # Optionally build demos, on by default.
 306 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 307
 308 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 309 # lib m for math, not needed on windows
 310 IF (NOT WIN32)
 311     LIST(APPEND DEMO_LIBS m)
 312 ENDIF()
 313
 314 MACRO(ADD_DEMO name)
 315     IF( FREEGLUT_BUILD_DEMOS )
 316         IF(BUILD_SHARED_LIBS)
 317             ADD_EXECUTABLE(${name} ${ARGN})
 318             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 319         ENDIF()
 320         IF(BUILD_STATIC_LIBS)
 321             ADD_EXECUTABLE(${name}_static ${ARGN})
 322             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 323             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 324         ENDIF()
 325     ENDIF()
 326 ENDMACRO()
 327
 328 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 329 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 330 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 331 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 332 ADD_DEMO(One             progs/demos/One/one.c)
 333 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 334 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 335 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 336 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 337                          progs/demos/spaceball/vmath.c
 338                          progs/demos/spaceball/vmath.h)
 339 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 340 ADD_DEMO(timer           progs/demos/timer/timer.c)
 341
 342 # finally, if any demos are built, copy needed files to output directory
 343 # (currently, thats just the input file for the Fractals demo)
 344 IF(FREEGLUT_BUILD_DEMOS)
 345     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 346     IF(BUILD_SHARED_LIBS)
 347         SET(Frac_target Fractals)
 348     ELSE()
 349         SET(Frac_target Fractals_static)
 350     ENDIF()
 351     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 352     ADD_CUSTOM_COMMAND(
 353         TARGET ${Frac_target}
 354         POST_BUILD
 355         COMMAND ${CMAKE_COMMAND} -E copy
 356         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 357         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 358     )
 359 ENDIF()
 360
 361 # pkg-config support, to install at $(libdir)/pkgconfig
 362 # Define static build dependencies
 363 IF(WIN32)
 364   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32")
 365 ELSEIF(ANDROID)
 366   SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL")
 367 ELSE()
 368   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL")
 369 ENDIF()
 370 # Client applications need to define FreeGLUT GLES version to
 371 # bootstrap headers inclusion in freeglut_std.h:
 372 IF(FREEGLUT_GLES2)
 373   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 374 ELSEIF(FREEGLUT_GLES1)
 375   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 376 ENDIF()
 377 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 378 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig)
 379 # TODO: change the library and .pc name when building for GLES,
 380 # e.g. -lglut-GLES2