git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 SET(FREEGLUT_HEADERS
   5         include/GL/freeglut.h
   6         include/GL/freeglut_ext.h
   7         include/GL/freeglut_std.h
   8         include/GL/glut.h
   9 )
  10 SET(FREEGLUT_SRCS
  11         ${FREEGLUT_HEADERS}
  12         src/Common/freeglut_callbacks.c
  13         src/Common/freeglut_cursor.c
  14         src/Common/freeglut_display.c
  15         src/Common/freeglut_ext.c
  16         src/Common/freeglut_font.c
  17         src/Common/freeglut_font_data.c
  18         src/Common/freeglut_gamemode.c
  19         src/Common/freeglut_geometry.c
  20         src/Common/freeglut_init.c
  21         src/Common/freeglut_internal.h
  22         src/Common/freeglut_input_devices.c
  23         src/Common/freeglut_joystick.c
  24         src/Common/freeglut_main.c
  25         src/Common/freeglut_menu.c
  26         src/Common/freeglut_misc.c
  27         src/Common/freeglut_overlay.c
  28         src/Common/freeglut_spaceball.c
  29         src/Common/freeglut_state.c
  30         src/Common/freeglut_stroke_mono_roman.c
  31         src/Common/freeglut_stroke_roman.c
  32         src/Common/freeglut_structure.c
  33         src/Common/freeglut_teapot.c
  34         src/Common/freeglut_videoresize.c
  35         src/Common/freeglut_window.c
  36 )
  37
  38 IF(WIN32)
  39         LIST(APPEND FREEGLUT_SRCS
  40                 src/mswin/freeglut_cursor_mswin.c
  41                 src/mswin/freeglut_display_mswin.c
  42                 src/mswin/freeglut_ext_mswin.c
  43                 src/mswin/freeglut_gamemode_mswin.c
  44                 src/mswin/freeglut_init_mswin.c
  45                 src/mswin/freeglut_internal_mswin.h
  46                 src/mswin/freeglut_input_devices_mswin.c
  47                 src/mswin/freeglut_joystick_mswin.c
  48                 src/mswin/freeglut_main_mswin.c
  49                 src/mswin/freeglut_menu_mswin.c
  50                 src/mswin/freeglut_spaceball_mswin.c
  51                 src/mswin/freeglut_state_mswin.c
  52                 src/mswin/freeglut_structure_mswin.c
  53                 src/mswin/freeglut_window_mswin.c
  54 )
  55 ELSE()
  56         LIST(APPEND FREEGLUT_SRCS
  57                 src/x11/freeglut_cursor_x11.c
  58                 src/x11/freeglut_display_x11.c
  59                 src/x11/freeglut_ext_x11.c
  60                 src/x11/freeglut_gamemode_x11.c
  61                 src/x11/freeglut_glutfont_definitions_x11.c
  62                 src/x11/freeglut_init_x11.c
  63                 src/x11/freeglut_internal_x11.h
  64                 src/x11/freeglut_input_devices_x11.c
  65                 src/x11/freeglut_joystick_x11.c
  66                 src/x11/freeglut_main_x11.c
  67                 src/x11/freeglut_menu_x11.c
  68                 src/x11/freeglut_spaceball_x11.c
  69                 src/x11/freeglut_state_x11.c
  70                 src/x11/freeglut_structure_x11.c
  71                 src/x11/freeglut_window_x11.c
  72                 src/x11/freeglut_xinput_x11.c
  73 )
  74
  75
  76 ENDIF()
  77
  78 # Neatly organize all of the output files in the build directory
  79 SET(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  80 SET(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/lib)
  81
  82 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  83 # re-declare it here so it will show up in the GUI.
  84 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  85 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  86
  87 FIND_PACKAGE(OpenGL REQUIRED)
  88 INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR}/include ${OPENGL_INCLUDE_DIR})
  89 LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
  90 LIST(APPEND LIBS m)
  91
  92 IF(WIN32)
  93         MESSAGE(WARNING "Insecure CRT warnings hidden (might want to fix these)")
  94         ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
  95 ENDIF()
  96
  97 if(UNIX)
  98         FIND_PACKAGE(X11 REQUIRED)
  99         LIST(APPEND LIBS ${X11_LIBRARIES})
 100         IF(X11_Xrandr_FOUND)
 101                 SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 102                 LIST(APPEND LIBS ${X11_Xrandr_LIB})
 103         ENDIF()
 104         IF(X11_xf86vmode_FOUND)
 105                 SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 106                 # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 107                 IF(NOT "${X11_Xxf86vm_LIB}")
 108                         SET(X11_Xxf86vm_LIB "Xxf86vm")
 109                 ENDIF()
 110                 LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 111         ENDIF()
 112 ENDIF()
 113
 114 INCLUDE(CheckIncludeFiles)
 115 INCLUDE(CheckFunctionExists)
 116 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 117 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 118 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 119 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 120 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 121 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 122 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 123 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 124 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 125 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 126
 127 # The generated config.h is placed in the project's build directory, just to
 128 # ensure that all CMake-generated files are kept away from the main source tree.
 129 # As a result, the build directory must to be added to the include path list.
 130 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 131 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR})
 132 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 133
 134 # by default, at least on UNIX, we want to build both
 135 IF(BUILD_SHARED_LIBS)
 136         ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 137 ENDIF()
 138 IF(BUILD_STATIC_LIBS)
 139         ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 140 ENDIF()
 141
 142
 143 IF(WIN32)
 144         IF(BUILD_SHARED_LIBS)
 145                 LIST(APPEND FREEGLUT_SRCS src/Common/freeglutdll.def freeglut.rc)
 146                 # XXX I assume that if we want both shared and static this one is appropriate
 147                 ADD_DEFINITIONS(-DFREEGLUT_EXPORTS)
 148         ELSE()
 149                 ADD_DEFINITIONS(-DFREEGLUT_STATIC)
 150         ENDIF()
 151 ELSE()
 152         # on UNIX we need to make sure:
 153         # - all shared libraries must have a soname/version
 154         # - the output library should be named glut so it'll be linkable with -lglut
 155         # - the shared library should link to the dependency libraries so that the user
 156         #   won't have to link them explicitly (they shouldn't have to know that we depend
 157         #   on Xrandr or Xxf86vm)
 158         SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 159         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 160         TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 161 ENDIF()
 162
 163 IF(BUILD_SHARED_LIBS)
 164         INSTALL(TARGETS freeglut DESTINATION lib)
 165 ENDIF()
 166 IF(BUILD_STATIC_LIBS)
 167         INSTALL(TARGETS freeglut_static DESTINATION lib)
 168 ENDIF()
 169 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 170
 171
 172
 173 # Optionally build demos, on by default.
 174 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 175
 176 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 177 LIST(APPEND DEMO_LIBS m)
 178
 179 MACRO(ADD_DEMO name)
 180         if( FREEGLUT_BUILD_DEMOS )
 181                 ADD_EXECUTABLE(${name} ${ARGN})
 182                 IF(BUILD_SHARED_LIBS)
 183                         TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 184                 ELSE()
 185                         TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut_static)
 186                 ENDIF()
 187         endif()
 188 ENDMACRO()
 189
 190 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 191 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 192 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 193 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 194 ADD_DEMO(One             progs/demos/One/one.c)
 195 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 196 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 197 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 198 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 199                          progs/demos/spaceball/vmath.c
 200                          progs/demos/spaceball/vmath.h)
 201 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 202
 203