git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # OpenGL ES support
  28 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  29 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  30
  31
  32 SET(FREEGLUT_HEADERS
  33     include/GL/freeglut.h
  34     include/GL/freeglut_ext.h
  35     include/GL/freeglut_std.h
  36     include/GL/glut.h
  37 )
  38 SET(FREEGLUT_SRCS
  39     ${FREEGLUT_HEADERS}
  40     src/fg_callbacks.c
  41     src/fg_cursor.c
  42     src/fg_display.c
  43     src/fg_ext.c
  44     src/fg_font_data.c
  45     src/fg_gamemode.c
  46     src/fg_gl2.c
  47     src/fg_gl2.h
  48     src/fg_init.c
  49     src/fg_internal.h
  50     src/fg_input_devices.c
  51     src/fg_joystick.c
  52     src/fg_main.c
  53     src/fg_misc.c
  54     src/fg_overlay.c
  55     src/fg_spaceball.c
  56     src/fg_state.c
  57     src/fg_stroke_mono_roman.c
  58     src/fg_stroke_roman.c
  59     src/fg_structure.c
  60     src/fg_videoresize.c
  61     src/fg_window.c
  62 )
  63 # TODO: OpenGL ES requires a compatible version of these files:
  64 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  65     LIST(APPEND FREEGLUT_SRCS
  66         src/fg_font.c
  67         src/fg_menu.c
  68         src/fg_teapot.c
  69         src/fg_teapot_data.h
  70         src/fg_geometry.c
  71     )
  72 ELSE()
  73     LIST(APPEND FREEGLUT_SRCS
  74         src/fg_geometry.c
  75         src/gles_stubs.c
  76     )
  77 ENDIF()
  78
  79 IF(WIN32)
  80     LIST(APPEND FREEGLUT_SRCS
  81         src/mswin/fg_cursor_mswin.c
  82         src/mswin/fg_display_mswin.c
  83         src/mswin/fg_ext_mswin.c
  84         src/mswin/fg_gamemode_mswin.c
  85         src/mswin/fg_init_mswin.c
  86         src/mswin/fg_internal_mswin.h
  87         src/mswin/fg_input_devices_mswin.c
  88         src/mswin/fg_joystick_mswin.c
  89         src/mswin/fg_main_mswin.c
  90         src/mswin/fg_menu_mswin.c
  91         src/mswin/fg_spaceball_mswin.c
  92         src/mswin/fg_state_mswin.c
  93         src/mswin/fg_structure_mswin.c
  94         src/mswin/fg_window_mswin.c
  95         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  96     )
  97     IF (MSVC AND NOT CMAKE_CL_64)
  98         # .def file only for 32bit Windows builds
  99         LIST(APPEND FREEGLUT_SRCS
 100             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 101         )
 102     ENDIF()
 103
 104 ELSEIF(ANDROID)
 105     LIST(APPEND FREEGLUT_SRCS
 106         src/egl/fg_internal_egl.h
 107         src/egl/fg_display_egl.c
 108         src/egl/fg_ext_egl.c
 109         src/egl/fg_init_egl.c
 110         src/egl/fg_state_egl.c
 111         src/egl/fg_structure_egl.c
 112         src/egl/fg_structure_egl.h
 113         src/egl/fg_window_egl.c
 114         src/egl/fg_window_egl.h
 115         src/android/native_app_glue/android_native_app_glue.c
 116         src/android/native_app_glue/android_native_app_glue.h
 117         src/android/fg_internal_android.h
 118         src/android/fg_cursor_android.c
 119         src/android/fg_ext_android.c
 120         src/android/fg_gamemode_android.c
 121         src/android/fg_init_android.c
 122         src/android/fg_input_devices_android.c
 123         src/android/fg_joystick_android.c
 124         src/android/fg_main_android.c
 125         src/android/fg_runtime_android.c
 126         src/android/fg_spaceball_android.c
 127         src/android/fg_state_android.c
 128         src/android/fg_structure_android.c
 129         src/android/fg_window_android.c
 130     )
 131 ELSE()
 132     LIST(APPEND FREEGLUT_SRCS
 133         src/x11/fg_cursor_x11.c
 134         src/x11/fg_ext_x11.c
 135         src/x11/fg_gamemode_x11.c
 136         src/x11/fg_glutfont_definitions_x11.c
 137         src/x11/fg_init_x11.c
 138         src/x11/fg_internal_x11.h
 139         src/x11/fg_input_devices_x11.c
 140         src/x11/fg_joystick_x11.c
 141         src/x11/fg_main_x11.c
 142         src/x11/fg_menu_x11.c
 143         src/x11/fg_spaceball_x11.c
 144         src/x11/fg_state_x11.c
 145         src/x11/fg_structure_x11.c
 146         src/x11/fg_window_x11.c
 147         src/x11/fg_xinput_x11.c
 148     )
 149     IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 150         LIST(APPEND FREEGLUT_SRCS
 151             src/egl/fg_internal_egl.h
 152             src/egl/fg_display_egl.c
 153             src/egl/fg_ext_egl.c
 154             src/egl/fg_init_egl.c
 155             src/egl/fg_state_egl.c
 156             src/egl/fg_structure_egl.c
 157             src/egl/fg_window_egl.c
 158         )
 159     ELSE()
 160         LIST(APPEND FREEGLUT_SRCS
 161             src/x11/fg_internal_x11_glx.h
 162             src/x11/fg_display_x11_glx.c
 163             src/x11/fg_state_x11_glx.c
 164             src/x11/fg_window_x11_glx.c
 165             src/x11/fg_window_x11_glx.h
 166         )
 167     ENDIF()
 168 ENDIF()
 169
 170 # For OpenGL ES (GLES):
 171 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 172 #   bootstrap headers inclusion in freeglut_std.h; these constants
 173 #   also need to be defined in client applications (e.g through
 174 #   pkg-config), but use GLES constants directly for all other needs
 175 # - define GLES version-specific library
 176 IF(FREEGLUT_GLES2)
 177   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 178   LIST(APPEND LIBS GLESv2 EGL)
 179 ELSEIF(FREEGLUT_GLES1)
 180   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 181   LIST(APPEND LIBS GLESv1_CM EGL)
 182 ELSE()
 183   FIND_PACKAGE(OpenGL REQUIRED)
 184   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 185   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 186 ENDIF()
 187
 188 # lib m for math, not needed on windows
 189 IF (NOT WIN32)
 190     LIST(APPEND LIBS m)
 191 ENDIF()
 192
 193 IF(WIN32)
 194     # hide insecure CRT warnings, common practice
 195     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 196 ENDIF()
 197
 198 IF(CMAKE_COMPILER_IS_GNUCC)
 199   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -pedantic")
 200   IF(!ANDROID)
 201     # not setting -ansi as EGL/KHR headers doesn't support it
 202     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ansi")
 203   ENDIF()
 204 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 205
 206 if(UNIX AND NOT ANDROID)
 207     FIND_PACKAGE(X11 REQUIRED)
 208     LIST(APPEND LIBS ${X11_LIBRARIES})
 209     IF(X11_Xrandr_FOUND)
 210         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 211         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 212     ENDIF()
 213     IF(X11_xf86vmode_FOUND)
 214         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 215         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 216         IF(NOT "${X11_Xxf86vm_LIB}")
 217             SET(X11_Xxf86vm_LIB "Xxf86vm")
 218         ENDIF()
 219         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 220     ENDIF()
 221 ENDIF()
 222
 223 INCLUDE(CheckIncludeFiles)
 224 INCLUDE(CheckFunctionExists)
 225 INCLUDE(CheckTypeSize)
 226 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 227 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 228 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 229 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 230 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 231 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 232 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 233 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 234 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 235 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 236 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 237 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 238 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 239 IF (NOT HAVE_XPARSEGEOMETRY)
 240    LIST(APPEND FREEGLUT_SRCS
 241         src/util/xparsegeometry_repl.c
 242         src/util/xparsegeometry_repl.h)
 243    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 244 ENDIF()
 245 # decide on suitable type for internal time keeping, 64-bit if possible
 246 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 247 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 248 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 249     IF (MSVC)
 250         # Some old Microsoft VC don't support unsigned long long, but all we
 251         # care about support unsigned __int64, so test for presence of that
 252         # type
 253         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 254     ELSEIF()
 255         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 256     ENDIF()
 257 ENDIF()
 258
 259
 260 # The generated config.h is placed in the project's build directory, just to
 261 # ensure that all CMake-generated files are kept away from the main source tree.
 262 # As a result, the build directory must to be added to the include path list.
 263 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 264 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 265 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 266 IF(WIN32)
 267     # we also have to generate freeglut.rc, which contains the version
 268     # number
 269     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 270     IF (MSVC AND NOT CMAKE_CL_64)
 271         # .def file only for 32bit Windows builds with Visual Studio
 272         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 273     ENDIF()
 274 ENDIF()
 275
 276 IF(BUILD_SHARED_LIBS)
 277     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 278 ENDIF()
 279 IF(BUILD_STATIC_LIBS)
 280     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 281 ENDIF()
 282
 283
 284 IF(WIN32)
 285     LIST(APPEND LIBS winmm)
 286     IF(BUILD_SHARED_LIBS)
 287         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 288     ENDIF()
 289     IF(BUILD_STATIC_LIBS)
 290         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 291         # need to set machine:x64 for linker, at least for VC10, and
 292         # doesn't hurt for older compilers:
 293         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 294         IF (CMAKE_CL_64)
 295             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 296         ENDIF()
 297     ENDIF()
 298 ELSE()
 299     # on UNIX we need to make sure:
 300     # - all shared libraries must have a soname/version, see :
 301     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 302     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 303     #   Current: -version-info 12:0:9 -> 3.9.0
 304     # - the output library should be named glut so it'll be linkable with -lglut
 305     # - the shared library should link to the dependency libraries so that the user
 306     #   won't have to link them explicitly (they shouldn't have to know that we depend
 307     #   on Xrandr or Xxf86vm)
 308     IF(FREEGLUT_GLES2)
 309       SET(LIBNAME freeglut-gles2)
 310     ELSEIF(FREEGLUT_GLES1)
 311       SET(LIBNAME freeglut-gles1)
 312     ELSE()
 313       SET(LIBNAME glut)
 314     ENDIF()
 315
 316     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME ${LIBNAME})
 317     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 318     IF(ANDROID)
 319         # Not in CMake toolchain file, because the toolchain
 320         # file is called several times and generally doesn't
 321         # seem to be meant for modifying CFLAGS:
 322         # '-mandroid' is not mandatory but doesn't hurt
 323         # '-O0 -gstabs+' helps the currently buggy GDB port
 324         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 325         # Not using _INIT variables, they seem to be used internally only
 326         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 327         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 328     ENDIF()
 329 ENDIF()
 330 IF(BUILD_SHARED_LIBS)
 331     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 332 ENDIF()
 333 IF(BUILD_STATIC_LIBS)
 334     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 335 ENDIF()
 336
 337 IF(BUILD_SHARED_LIBS)
 338     INSTALL(TARGETS freeglut DESTINATION lib)
 339 ENDIF()
 340 IF(BUILD_STATIC_LIBS)
 341     INSTALL(TARGETS freeglut_static DESTINATION lib)
 342 ENDIF()
 343 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 344
 345
 346
 347 # Optionally build demos, on by default.
 348 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 349
 350 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 351 # lib m for math, not needed on windows
 352 IF (NOT WIN32)
 353     LIST(APPEND DEMO_LIBS m)
 354 ENDIF()
 355
 356 MACRO(ADD_DEMO name)
 357     IF( FREEGLUT_BUILD_DEMOS )
 358         IF(BUILD_SHARED_LIBS)
 359             ADD_EXECUTABLE(${name} ${ARGN})
 360             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 361         ENDIF()
 362         IF(BUILD_STATIC_LIBS)
 363             ADD_EXECUTABLE(${name}_static ${ARGN})
 364             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 365             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 366         ENDIF()
 367     ENDIF()
 368 ENDMACRO()
 369
 370 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 371 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 372 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 373 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 374 ADD_DEMO(One             progs/demos/One/one.c)
 375 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 376 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 377 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 378 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 379                          progs/demos/spaceball/vmath.c
 380                          progs/demos/spaceball/vmath.h)
 381 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 382 ADD_DEMO(timer           progs/demos/timer/timer.c)
 383
 384 # finally, if any demos are built, copy needed files to output directory
 385 # (currently, thats just the input file for the Fractals demo)
 386 IF(FREEGLUT_BUILD_DEMOS)
 387     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 388     IF(BUILD_SHARED_LIBS)
 389         SET(Frac_target Fractals)
 390     ELSE()
 391         SET(Frac_target Fractals_static)
 392     ENDIF()
 393     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 394     ADD_CUSTOM_COMMAND(
 395         TARGET ${Frac_target}
 396         POST_BUILD
 397         COMMAND ${CMAKE_COMMAND} -E copy
 398         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 399         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 400     )
 401 ENDIF()
 402
 403 # pkg-config support, to install at $(libdir)/pkgconfig
 404 # Define static build dependencies
 405 IF(WIN32)
 406   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 407 ELSEIF(FREEGLUT_GLES2)
 408   IF(ANDROID)
 409     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 410   ELSE()
 411     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 412   ENDIF()
 413 ELSEIF(FREEGLUT_GLES1)
 414   IF(ANDROID)
 415     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 416   ELSE()
 417     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 418   ENDIF()
 419 ELSE()
 420   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 421 ENDIF()
 422 # Client applications need to define FreeGLUT GLES version to
 423 # bootstrap headers inclusion in freeglut_std.h:
 424 SET(PC_LIBNAME "glut")
 425 SET(PC_FILENAME "freeglut.pc")
 426 IF(FREEGLUT_GLES2)
 427   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 428   SET(PC_LIBNAME "freeglut-gles2")
 429   SET(PC_FILENAME "freeglut-gles2.pc")
 430 ELSEIF(FREEGLUT_GLES1)
 431   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 432   SET(PC_LIBNAME "freeglut-gles1")
 433   SET(PC_FILENAME "freeglut-gles1.pc")
 434 ENDIF()
 435 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 436 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 437 # TODO: change the library and .pc name when building for GLES,
 438 # e.g. -lglut-GLES2