git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 SET(FREEGLUT_HEADERS
   5         include/GL/freeglut.h
   6         include/GL/freeglut_ext.h
   7         include/GL/freeglut_std.h
   8         include/GL/glut.h
   9 )
  10 SET(FREEGLUT_SRCS
  11         ${FREEGLUT_HEADERS}
  12         src/Common/freeglut_callbacks.c
  13         src/Common/freeglut_cursor.c
  14         src/Common/freeglut_display.c
  15         src/Common/freeglut_ext.c
  16         src/Common/freeglut_font.c
  17         src/Common/freeglut_font_data.c
  18         src/Common/freeglut_gamemode.c
  19         src/Common/freeglut_geometry.c
  20         src/Common/freeglut_init.c
  21         src/Common/freeglut_internal.h
  22         src/Common/freeglut_input_devices.c
  23         src/Common/freeglut_joystick.c
  24         src/Common/freeglut_main.c
  25         src/Common/freeglut_menu.c
  26         src/Common/freeglut_misc.c
  27         src/Common/freeglut_overlay.c
  28         src/Common/freeglut_spaceball.c
  29         src/Common/freeglut_state.c
  30         src/Common/freeglut_stroke_mono_roman.c
  31         src/Common/freeglut_stroke_roman.c
  32         src/Common/freeglut_structure.c
  33         src/Common/freeglut_teapot.c
  34         src/Common/freeglut_videoresize.c
  35         src/Common/freeglut_window.c
  36 )
  37
  38 IF(WIN32)
  39         LIST(APPEND FREEGLUT_SRCS
  40                 src/mswin/freeglut_cursor_mswin.c
  41                 src/mswin/freeglut_display_mswin.c
  42                 src/mswin/freeglut_ext_mswin.c
  43                 src/mswin/freeglut_gamemode_mswin.c
  44                 src/mswin/freeglut_init_mswin.c
  45                 src/mswin/freeglut_internal_mswin.h
  46                 src/mswin/freeglut_input_devices_mswin.c
  47                 src/mswin/freeglut_joystick_mswin.c
  48                 src/mswin/freeglut_main_mswin.c
  49                 src/mswin/freeglut_menu_mswin.c
  50                 src/mswin/freeglut_spaceball_mswin.c
  51                 src/mswin/freeglut_state_mswin.c
  52                 src/mswin/freeglut_structure_mswin.c
  53                 src/mswin/freeglut_window_mswin.c
  54 )
  55 ELSE()
  56         LIST(APPEND FREEGLUT_SRCS
  57                 src/x11/freeglut_cursor_x11.c
  58                 src/x11/freeglut_display_x11.c
  59                 src/x11/freeglut_ext_x11.c
  60                 src/x11/freeglut_gamemode_x11.c
  61                 src/x11/freeglut_glutfont_definitions_x11.c
  62                 src/x11/freeglut_init_x11.c
  63                 src/x11/freeglut_internal_x11.h
  64                 src/x11/freeglut_input_devices_x11.c
  65                 src/x11/freeglut_joystick_x11.c
  66                 src/x11/freeglut_main_x11.c
  67                 src/x11/freeglut_menu_x11.c
  68                 src/x11/freeglut_spaceball_x11.c
  69                 src/x11/freeglut_state_x11.c
  70                 src/x11/freeglut_structure_x11.c
  71                 src/x11/freeglut_window_x11.c
  72                 src/x11/freeglut_xinput_x11.c
  73 )
  74
  75
  76 ENDIF()
  77
  78 # Neatly organize all of the output files in the build directory
  79 SET(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  80 SET(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/lib)
  81
  82 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  83 # re-declare it here so it will show up in the GUI.
  84 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  85 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  86
  87 FIND_PACKAGE(OpenGL REQUIRED)
  88 INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR}/include ${OPENGL_INCLUDE_DIR})
  89 LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
  90 LIST(APPEND LIBS m)
  91
  92 IF(WIN32)
  93         MESSAGE(WARNING "Insecure CRT warnings hidden (might want to fix these)")
  94         ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
  95 ENDIF()
  96
  97 if(UNIX)
  98         FIND_PACKAGE(X11 REQUIRED)
  99         LIST(APPEND LIBS ${X11_LIBRARIES})
 100         IF(X11_Xrandr_FOUND)
 101                 SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 102                 LIST(APPEND LIBS ${X11_Xrandr_LIB})
 103         ENDIF()
 104         IF(X11_xf86vmode_FOUND)
 105                 SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 106                 # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 107                 IF(NOT "${X11_Xxf86vm_LIB}")
 108                         SET(X11_Xxf86vm_LIB "Xxf86vm")
 109                 ENDIF()
 110                 LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 111         ENDIF()
 112 ENDIF()
 113
 114 INCLUDE(CheckIncludeFiles)
 115 INCLUDE(CheckFunctionExists)
 116 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 117 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 118 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 119 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 120 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 121 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 122 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 123 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 124 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 125 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 126 CHECK_FUNCTION_EXISTS(vfprintf HAVE_VFPRINTF)
 127 CHECK_FUNCTION_EXISTS(_doprnt HAVE_DOPRNT)
 128
 129 # The generated config.h is placed in the project's build directory, just to
 130 # ensure that all CMake-generated files are kept away from the main source tree.
 131 # As a result, the build directory must to be added to the include path list.
 132 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 133 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR})
 134 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 135
 136 # by default, at least on UNIX, we want to build both
 137 IF(BUILD_SHARED_LIBS)
 138         ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 139 ENDIF()
 140 IF(BUILD_STATIC_LIBS)
 141         ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 142 ENDIF()
 143
 144
 145 IF(WIN32)
 146         LIST(APPEND LIBS winmm)
 147         IF(BUILD_SHARED_LIBS)
 148                 LIST(APPEND FREEGLUT_SRCS src/Common/freeglutdll.def freeglut.rc)
 149                 # XXX I assume that if we want both shared and static this one is appropriate
 150                 ADD_DEFINITIONS(-DFREEGLUT_EXPORTS)
 151         ELSE()
 152                 ADD_DEFINITIONS(-DFREEGLUT_STATIC)
 153         ENDIF()
 154 ELSE()
 155         # on UNIX we need to make sure:
 156         # - all shared libraries must have a soname/version
 157         # - the output library should be named glut so it'll be linkable with -lglut
 158         # - the shared library should link to the dependency libraries so that the user
 159         #   won't have to link them explicitly (they shouldn't have to know that we depend
 160         #   on Xrandr or Xxf86vm)
 161         SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 162         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 163 ENDIF()
 164 TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 165 TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 166
 167 IF(BUILD_SHARED_LIBS)
 168         INSTALL(TARGETS freeglut DESTINATION lib)
 169 ENDIF()
 170 IF(BUILD_STATIC_LIBS)
 171         INSTALL(TARGETS freeglut_static DESTINATION lib)
 172 ENDIF()
 173 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 174
 175
 176
 177 # Optionally build demos, on by default.
 178 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 179
 180 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 181 LIST(APPEND DEMO_LIBS m)
 182
 183 MACRO(ADD_DEMO name)
 184         if( FREEGLUT_BUILD_DEMOS )
 185                 ADD_EXECUTABLE(${name} ${ARGN})
 186                 IF(BUILD_SHARED_LIBS)
 187                         TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 188                 ELSE()
 189                         TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut_static)
 190                 ENDIF()
 191         endif()
 192 ENDMACRO()
 193
 194 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 195 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 196 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 197 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 198 ADD_DEMO(One             progs/demos/One/one.c)
 199 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 200 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 201 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 202 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 203                          progs/demos/spaceball/vmath.c
 204                          progs/demos/spaceball/vmath.h)
 205 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 206
 207