git.mutantstargoat.com Git - freeglut/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([freeglut library], [2.4.0], [freeglut-bugs@lists.sourceforge.net], [freeglut])
   4 AM_INIT_AUTOMAKE
   5 AC_PREREQ([2.56])
   6 AC_CONFIG_SRCDIR([AUTHORS])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 # Compatibility hack for older autoconf versions
  10 m4_ifdef([AS_HELP_STRING], [], [AC_DEFUN([AS_HELP_STRING], [AC_HELP_STRING($][@)])])
  11
  12 # Checks for programs.
  13 AC_PROG_CC
  14 AC_C_CONST
  15 AC_EXEEXT
  16 AC_LIBTOOL_DLOPEN
  17 AC_PROG_LIBTOOL
  18 AC_SUBST([LIBTOOL_DEPS])
  19
  20 # Checks for libraries.
  21 AC_PATH_XTRA
  22
  23 if test x"$no_x" = xyes; then
  24   GL_LIBS="-lopengl32 -lglu32 -lgdi32"
  25   LIBXXF86VM=
  26   VERSION_INFO=
  27   EXPORT_FLAGS="-DFREEGLUT_EXPORTS"
  28 else
  29   GL_LIBS="-lGL -lGLU -lXext -lX11"
  30   AC_CHECK_LIB([Xxf86vm], [XF86VidModeSwitchToMode],
  31                [LIBXXF86VM=-lXxf86vm], [LIBXXF86VM=],
  32                [$X_LIBS -lXext -lX11])
  33   VERSION_INFO="-version-info 11:0:8"
  34   EXPORT_FLAGS=
  35 fi
  36 AC_SUBST([GL_LIBS])
  37 AC_SUBST([LIBXXF86VM])
  38 AC_SUBST([VERSION_INFO])
  39 AC_SUBST([EXPORT_FLAGS])
  40
  41 # Checks for header files.
  42 AC_HEADER_STDC
  43 AC_CHECK_HEADERS([GL/gl.h GL/glu.h GL/glx.h fcntl.h limits.h sys/ioctl.h sys/param.h sys/time.h])
  44 AC_HEADER_TIME
  45
  46 save_CFLAGS="$CFLAGS"
  47 CFLAGS="$CFLAGS $X_CFLAGS"
  48 AC_CHECK_HEADERS([X11/extensions/xf86vmode.h], [], [], [#include <X11/Xlib.h>])
  49 CFLAGS="$save_CFLAGS"
  50
  51 # Checks for library functions.
  52 AC_PROG_GCC_TRADITIONAL
  53 AC_FUNC_VPRINTF
  54 AC_CHECK_LIBM
  55 AC_SUBST([LIBM])
  56
  57 # Build time configuration.
  58 AC_ARG_ENABLE([replace-glut],
  59 [AS_HELP_STRING([--enable-replace-glut],
  60                 [be a replacement for GLUT @<:@default=yes@:>@])])
  61 if test "x$enable_replace_glut" != xno; then
  62   LIBRARY=glut
  63   HEADER=glut.h
  64 else
  65   LIBRARY=freeglut
  66   HEADER=
  67 fi
  68 AC_SUBST([LIBRARY])
  69 AC_SUBST([HEADER])
  70
  71 AC_ARG_ENABLE([warnings],
  72 [AS_HELP_STRING([--enable-warnings],
  73                 [use all gcc compiler warnings @<:@default=yes@:>@])])
  74 if test "x$enable_warnings" != xno -a "x$GCC" = xyes; then
  75   CFLAGS="$CFLAGS -Wall -pedantic -Werror"
  76 fi
  77
  78 AC_ARG_ENABLE([debug],
  79 [AS_HELP_STRING([--enable-debug],
  80                 [enable debugging code (for developers) @<:@default=no@:>@])])
  81 if test "x$enable_debug" = xyes; then
  82   AC_DEFINE([_DEBUG], [1], [Define to 1 if you want to include debugging code.])
  83 fi
  84
  85 # Generate output.
  86 AC_CONFIG_FILES([Makefile
  87                  doc/Makefile
  88                  include/GL/Makefile
  89                  include/Makefile
  90                  progs/Makefile
  91                  progs/demos/CallbackMaker/Makefile
  92                  progs/demos/Fractals/Makefile
  93                  progs/demos/Fractals_random/Makefile
  94                  progs/demos/Lorenz/Makefile
  95                  progs/demos/Makefile
  96                  progs/demos/One/Makefile
  97                  progs/demos/shapes/Makefile
  98                  src/Makefile])
  99 AC_OUTPUT