git.mutantstargoat.com Git - freeglut/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([freeglut library], [2.2.0], [freeglut-bugs@lists.sourceforge.net], [freeglut])
   4 AM_INIT_AUTOMAKE
   5 AC_PREREQ([2.59])
   6 AC_CONFIG_SRCDIR([AUTHORS])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 # Checks for programs.
  10 AC_PROG_CC
  11 AC_C_CONST
  12 AC_EXEEXT
  13 AC_LIBTOOL_DLOPEN
  14 AC_PROG_LIBTOOL
  15 AC_SUBST([LIBTOOL_DEPS])
  16
  17 # Checks for libraries.
  18 AC_PATH_XTRA
  19 AC_CHECK_LIB([Xxf86vm], [XF86VidModeSwitchToMode],
  20              [LIBXXF86VM=-lXxf86vm], [LIBXXF86VM=],
  21              [$X_LIBS -lXext -lX11])
  22 AC_SUBST([LIBXXF86VM])
  23
  24 # Checks for header files.
  25 AC_HEADER_STDC
  26 AC_CHECK_HEADERS([sys/time.h GL/gl.h GL/glu.h GL/glx.h])
  27 AC_HEADER_TIME
  28
  29 save_CFLAGS="$CFLAGS"
  30 CFLAGS="$CFLAGS $X_CFLAGS"
  31 AC_CHECK_HEADERS([X11/extensions/xf86vmode.h], [], [], [#include <X11/Xlib.h>])
  32 CFLAGS="$save_CFLAGS"
  33
  34 # Checks for library functions.
  35 AC_CHECK_LIBM
  36 AC_SUBST([LIBM])
  37
  38 # Build time configuration.
  39 AC_ARG_ENABLE([replace-glut],
  40 [AS_HELP_STRING([--enable-replace-glut],
  41                 [be a replacement for GLUT @<:@default=yes@:>@])])
  42 if test "x$enable_replace_glut" != xno; then
  43   LIBRARY=glut
  44   HEADER=glut.h
  45 else
  46   LIBRARY=freeglut
  47   HEADER=
  48 fi
  49 AC_SUBST([LIBRARY])
  50 AC_SUBST([HEADER])
  51
  52 AC_ARG_ENABLE([warnings],
  53 [AS_HELP_STRING([--enable-warnings],
  54                 [use all gcc compiler warnings @<:@default=yes@:>@])])
  55 if test "x$enable_warnings" != xno -a "x$GCC" = xyes; then
  56   CFLAGS="$CFLAGS -Wall -pedantic -Werror"
  57 fi
  58
  59 # Generate output.
  60 AC_CONFIG_FILES([Makefile
  61                  doc/Makefile
  62                  include/GL/Makefile
  63                  include/Makefile
  64                  progs/Makefile
  65                  progs/demos/CallbackMaker/Makefile
  66                  progs/demos/Fractals/Makefile
  67                  progs/demos/Fractals_random/Makefile
  68                  progs/demos/Lorenz/Makefile
  69                  progs/demos/Makefile
  70                  progs/demos/One/Makefile
  71                  progs/demos/shapes/Makefile
  72                  src/Makefile])
  73 AC_OUTPUT