git.mutantstargoat.com Git - freeglut/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([freeglut library], [2.6.0], [freeglut-bugs@lists.sourceforge.net], [freeglut])
   4 AM_INIT_AUTOMAKE
   5 AC_PREREQ([2.56])
   6 AC_CONFIG_SRCDIR([AUTHORS])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 # Compatibility hack for older autoconf versions
  10 m4_ifdef([AS_HELP_STRING], [], [AC_DEFUN([AS_HELP_STRING], [AC_HELP_STRING($][@)])])
  11
  12 # Checks for programs.
  13 AC_PROG_CC
  14 AM_PROG_CC_C_O
  15 AC_C_CONST
  16 AC_EXEEXT
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 AC_SUBST([LIBTOOL_DEPS])
  20
  21 # Checks for libraries.
  22 AC_PATH_XTRA
  23
  24 if test x"$no_x" = xyes; then
  25   GL_LIBS="-lopengl32 -lglu32 -lgdi32"
  26   LIBXXF86VM=
  27   LIBXI=
  28   VERSION_INFO=
  29   EXPORT_FLAGS="-DFREEGLUT_EXPORTS"
  30 else
  31   GL_LIBS="-lGL -lGLU -lXext -lX11"
  32   AC_CHECK_LIB([Xxf86vm], [XF86VidModeSwitchToMode],
  33                [LIBXXF86VM=-lXxf86vm], [LIBXXF86VM=],
  34                [$X_LIBS -lXext -lX11])
  35   LIBXI=-lXi
  36   VERSION_INFO="-version-info 11:0:8"
  37   EXPORT_FLAGS=
  38 fi
  39 AC_SUBST([GL_LIBS])
  40 AC_SUBST([LIBXXF86VM])
  41 AC_SUBST([LIBXI])
  42 AC_SUBST([VERSION_INFO])
  43 AC_SUBST([EXPORT_FLAGS])
  44
  45 # Checks for header files.
  46 AC_HEADER_STDC
  47 save_CPPFLAGS="$CPPFLAGS"
  48 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
  49 AC_CHECK_HEADERS([GL/gl.h GL/glu.h GL/glx.h fcntl.h limits.h sys/ioctl.h sys/param.h sys/time.h])
  50 AC_HEADER_TIME
  51 AC_CHECK_HEADERS([X11/extensions/xf86vmode.h], [], [], [#include <X11/Xlib.h>])
  52 AC_CHECK_HEADERS([X11/extensions/XI.h X11/extensions/XInput.h])
  53 CPPFLAGS="$save_CPPFLAGS"
  54
  55 # Checks for library functions.
  56 AC_PROG_GCC_TRADITIONAL
  57 AC_FUNC_VPRINTF
  58 AC_CHECK_LIBM
  59 AC_SUBST([LIBM])
  60
  61 # Build time configuration.
  62 AC_ARG_ENABLE([replace-glut],
  63 [AS_HELP_STRING([--enable-replace-glut],
  64                 [be a replacement for GLUT @<:@default=yes@:>@])])
  65 if test "x$enable_replace_glut" != xno; then
  66   LIBRARY=glut
  67   HEADER=glut.h
  68 else
  69   LIBRARY=freeglut
  70   HEADER=
  71 fi
  72 AC_SUBST([LIBRARY])
  73 AC_SUBST([HEADER])
  74
  75 AC_ARG_ENABLE([warnings],
  76 [AS_HELP_STRING([--enable-warnings],
  77                 [use all gcc compiler warnings @<:@default=yes@:>@])])
  78 if test "x$enable_warnings" != xno -a "x$GCC" = xyes; then
  79   CFLAGS="$CFLAGS -Wall -pedantic -Werror"
  80 fi
  81
  82 AC_ARG_ENABLE([debug],
  83 [AS_HELP_STRING([--enable-debug],
  84                 [enable debugging code (for developers) @<:@default=no@:>@])])
  85 if test "x$enable_debug" = xyes; then
  86   AC_DEFINE([_DEBUG], [1], [Define to 1 if you want to include debugging code.])
  87 fi
  88
  89 # Generate output.
  90 AC_CONFIG_FILES([Makefile
  91                  doc/Makefile
  92                  include/GL/Makefile
  93                  include/Makefile
  94                  progs/Makefile
  95                  progs/demos/CallbackMaker/Makefile
  96                  progs/demos/Fractals/Makefile
  97                  progs/demos/Fractals_random/Makefile
  98                  progs/demos/Lorenz/Makefile
  99                  progs/demos/Makefile
 100                  progs/demos/One/Makefile
 101                  progs/demos/shapes/Makefile
 102                  src/Makefile])
 103 AC_OUTPUT