git.mutantstargoat.com Git - freeglut/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([freeglut library], [2.6.0], [freeglut-bugs@lists.sourceforge.net], [freeglut])
   4 AM_INIT_AUTOMAKE
   5 AC_PREREQ([2.56])
   6 AC_CONFIG_SRCDIR([AUTHORS])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 # Compatibility hack for older autoconf versions
  10 m4_ifdef([AS_HELP_STRING], [], [AC_DEFUN([AS_HELP_STRING], [AC_HELP_STRING($][@)])])
  11
  12 # Checks for programs.
  13 AC_PROG_CC
  14 AC_C_CONST
  15 AC_EXEEXT
  16 AC_LIBTOOL_DLOPEN
  17 AC_PROG_LIBTOOL
  18 AC_SUBST([LIBTOOL_DEPS])
  19
  20 # Checks for libraries.
  21 AC_PATH_XTRA
  22
  23 if test x"$no_x" = xyes; then
  24   GL_LIBS="-lopengl32 -lglu32 -lgdi32"
  25   LIBXXF86VM=
  26   LIBXI=
  27   VERSION_INFO=
  28   EXPORT_FLAGS="-DFREEGLUT_EXPORTS"
  29 else
  30   GL_LIBS="-lGL -lGLU -lXext -lX11"
  31   AC_CHECK_LIB([Xxf86vm], [XF86VidModeSwitchToMode],
  32                [LIBXXF86VM=-lXxf86vm], [LIBXXF86VM=],
  33                [$X_LIBS -lXext -lX11])
  34   LIBXI=-lXi
  35   VERSION_INFO="-version-info 11:0:8"
  36   EXPORT_FLAGS=
  37 fi
  38 AC_SUBST([GL_LIBS])
  39 AC_SUBST([LIBXXF86VM])
  40 AC_SUBST([LIBXI])
  41 AC_SUBST([VERSION_INFO])
  42 AC_SUBST([EXPORT_FLAGS])
  43
  44 # Checks for header files.
  45 AC_HEADER_STDC
  46 save_CPPFLAGS="$CPPFLAGS"
  47 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
  48 AC_CHECK_HEADERS([GL/gl.h GL/glu.h GL/glx.h fcntl.h limits.h sys/ioctl.h sys/param.h sys/time.h])
  49 AC_HEADER_TIME
  50 AC_CHECK_HEADERS([X11/extensions/xf86vmode.h], [], [], [#include <X11/Xlib.h>])
  51 AC_CHECK_HEADERS([X11/extensions/XI.h X11/extensions/XInput.h])
  52 CPPFLAGS="$save_CPPFLAGS"
  53
  54 # Checks for library functions.
  55 AC_PROG_GCC_TRADITIONAL
  56 AC_FUNC_VPRINTF
  57 AC_CHECK_LIBM
  58 AC_SUBST([LIBM])
  59
  60 # Build time configuration.
  61 AC_ARG_ENABLE([replace-glut],
  62 [AS_HELP_STRING([--enable-replace-glut],
  63                 [be a replacement for GLUT @<:@default=yes@:>@])])
  64 if test "x$enable_replace_glut" != xno; then
  65   LIBRARY=glut
  66   HEADER=glut.h
  67 else
  68   LIBRARY=freeglut
  69   HEADER=
  70 fi
  71 AC_SUBST([LIBRARY])
  72 AC_SUBST([HEADER])
  73
  74 AC_ARG_ENABLE([warnings],
  75 [AS_HELP_STRING([--enable-warnings],
  76                 [use all gcc compiler warnings @<:@default=yes@:>@])])
  77 if test "x$enable_warnings" != xno -a "x$GCC" = xyes; then
  78   CFLAGS="$CFLAGS -Wall -pedantic -Werror"
  79 fi
  80
  81 AC_ARG_ENABLE([debug],
  82 [AS_HELP_STRING([--enable-debug],
  83                 [enable debugging code (for developers) @<:@default=no@:>@])])
  84 if test "x$enable_debug" = xyes; then
  85   AC_DEFINE([_DEBUG], [1], [Define to 1 if you want to include debugging code.])
  86 fi
  87
  88 # Generate output.
  89 AC_CONFIG_FILES([Makefile
  90                  doc/Makefile
  91                  include/GL/Makefile
  92                  include/Makefile
  93                  progs/Makefile
  94                  progs/demos/CallbackMaker/Makefile
  95                  progs/demos/Fractals/Makefile
  96                  progs/demos/Fractals_random/Makefile
  97                  progs/demos/Lorenz/Makefile
  98                  progs/demos/Makefile
  99                  progs/demos/One/Makefile
 100                  progs/demos/shapes/Makefile
 101                  src/Makefile])
 102 AC_OUTPUT