git.mutantstargoat.com Git - freeglut/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([freeglut library], [2.2.0], [freeglut-bugs@lists.sourceforge.net], [freeglut])
   4 AM_INIT_AUTOMAKE
   5 AC_PREREQ([2.59])
   6 AC_CONFIG_SRCDIR([AUTHORS])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 # Checks for programs.
  10 AC_PROG_CC
  11 AC_C_CONST
  12 AC_EXEEXT
  13 AC_LIBTOOL_DLOPEN
  14 AC_PROG_LIBTOOL
  15 AC_SUBST([LIBTOOL_DEPS])
  16
  17 # Checks for libraries.
  18 AC_PATH_XTRA
  19 AC_CHECK_LIB([Xxf86vm], [XF86VidModeSwitchToMode],
  20              [LIBXXF86VM=-lXxf86vm], [LIBXXF86VM=],
  21              [$X_LIBS -lXext -lX11])
  22 AC_SUBST([LIBXXF86VM])
  23
  24 # Checks for header files.
  25 AC_HEADER_STDC
  26 AC_CHECK_HEADERS([GL/gl.h GL/glu.h GL/glx.h])
  27
  28 save_CFLAGS="$CFLAGS"
  29 CFLAGS="$CFLAGS $X_CFLAGS"
  30 AC_CHECK_HEADERS([X11/extensions/xf86vmode.h], [], [], [#include <X11/Xlib.h>])
  31 CFLAGS="$save_CFLAGS"
  32
  33 # Checks for library functions.
  34 AC_CHECK_LIBM
  35 AC_SUBST([LIBM])
  36
  37 # Build time configuration.
  38 AC_ARG_ENABLE([replace-glut],
  39 [AS_HELP_STRING([--enable-replace-glut],
  40                 [be a replacement for GLUT @<:@default=yes@:>@])])
  41 if test "x$enable_replace_glut" != xno; then
  42   LIBRARY=glut
  43   HEADER=glut.h
  44 else
  45   LIBRARY=freeglut
  46   HEADER=
  47 fi
  48 AC_SUBST([LIBRARY])
  49 AC_SUBST([HEADER])
  50
  51 AC_ARG_ENABLE([warnings],
  52 [AS_HELP_STRING([--enable-warnings],
  53                 [use all gcc compiler warnings @<:@default=yes@:>@])])
  54 if test "x$enable_warnings" != xno -a "x$GCC" = xyes; then
  55   CFLAGS="$CFLAGS -Wall -pedantic -Werror"
  56 fi
  57
  58 # Generate output.
  59 AC_CONFIG_FILES([Makefile
  60                  doc/Makefile
  61                  include/GL/Makefile
  62                  include/Makefile
  63                  progs/Makefile
  64                  progs/demos/CallbackMaker/Makefile
  65                  progs/demos/Fractals/Makefile
  66                  progs/demos/Fractals_random/Makefile
  67                  progs/demos/Lorenz/Makefile
  68                  progs/demos/Makefile
  69                  progs/demos/One/Makefile
  70                  progs/demos/shapes/Makefile
  71                  src/Makefile])
  72 AC_OUTPUT