dnl Process this file with autoconf to produce a configure script.
AC_INIT(Makefile.am)

AM_INIT_AUTOMAKE(freeglut,2.2.0)
AM_CONFIG_HEADER(config.h)

dnl Checks for programs.
AC_PROG_CC
AC_C_CONST
AC_EXEEXT
AC_LIBTOOL_DLOPEN
AM_PROG_LIBTOOL
AC_SUBST(LIBTOOL_DEPS)

dnl Checks for libraries.
AC_PATH_XTRA

AC_CHECK_LIB(Xxf86vm,XF86VidModeSwitchToMode,
	LIBXXF86VM=-lXxf86vm,LIBXXF86VM=,$X_LIBS -lXext -lX11)
AC_SUBST(LIBXXF86VM)

dnl Checks for header files.
AC_STDC_HEADERS
AC_HAVE_HEADERS( GL/gl.h GL/glu.h GL/glx.h )

save_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $X_CFLAGS"
AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,,,[#include <X11/Xlib.h>])
CFLAGS="$save_CFLAGS"

dnl Checks for typedefs, structures, and compiler characteristics.

dnl Checks for library functions.

AC_CHECK_LIBM
AC_SUBST(LIBM)

dnl Build time configuration

AC_ARG_ENABLE(replace-glut,
[  --disable-replace-glut  Coexist with existing glut library])
if test "x$enable_replace_glut" != xno
then
 LIBRARY=glut
 HEADER=glut.h
else
 LIBRARY=freeglut
 HEADER=
fi
AC_SUBST(LIBRARY)
AC_SUBST(HEADER)

AC_ARG_ENABLE(warnings,
[  --enable-warnings       Enable gcc compiler warnings],
if test "x$GCC" == xyes
then
 CFLAGS="$CFLAGS -Wall -Wno-parentheses -Werror"
fi)

AC_OUTPUT(\
	Makefile \
	doc/Makefile \
	progs/Makefile \
	progs/demos/Makefile \
	progs/demos/CallbackMaker/Makefile \
	progs/demos/Fractals/Makefile \
	progs/demos/Fractals_random/Makefile \
	progs/demos/Lorenz/Makefile \
	progs/demos/One/Makefile \
	progs/demos/offscreen/Makefile \
	progs/demos/shapes/Makefile \
	src/Makefile \
	include/Makefile \
	include/GL/Makefile \
	)