.text

#include "hwregs.h"

	.globl vdp_init
vdp_init:
	movea.l #def_reg_tab, %a0
	moveq #14, %d1
0:	move.w (%a0)+, %d0
	or.w #0x8000, %d0
	move.w %d0, VDP_CTL_PORT	| VDP_CTL = 0x8000 | (reg << 8) | val
	dbra %d1, 0b

	| clear vram
	movea.l #VDP_DATA_PORT, %a0
	moveq #0, %d0
	move.l #VDP_VRAM, %d1
	bsr setup_addr
	moveq #0, %d0
	move.l #0x7fff, %d1	| 64k / 2 - 1
0:	move.w %d0, (%a0)
	dbra %d1, 0b

	| clear colormaps
	move.l #VDP_CRAM, %d1
	bsr setup_addr
	moveq #0, %d0
	move.l #63, %d1		| 4 palettes * 16 col * 2 bytes / 2 - 1
0:	move.w %d0, (%a0)
	dbra %d1, 0b

	| clear vscroll
	move.l #VDP_VSRAM, %d1
	bsr setup_addr
	moveq #0, %d0
	move.l #39, %d1		| 80 bytes / 2 - 1
0:	move.w %d0, (%a0)
	dbra %d1, 0b
	rts

	| address in d0, type in d1
setup_addr:
	lsl.l #2, %d0
	lsr.w #2, %d0
	swap %d0
	or.l %d1, %d0
	move.l %d0, VDP_CTL_PORT
	rts

	.globl vdp_setcolor
vdp_setcolor:
	move.l 4(%sp), %d0	| palette number
	lsl.l #4, %d0
	add.l 8(%sp), %d0	| add index
	lsl.l #1, %d0
	move.l #VDP_CRAM, %d1
	bsr setup_addr
	move.w 22(%sp), %d0	| blue
	lsl.w #4, %d0
	or.w 18(%sp), %d0	| green
	lsl.w #4, %d0
	or.w 14(%sp), %d0	| red
	and.w #0x0eee, %d0
	move.w %d0, VDP_DATA_PORT
	rts

	.section .rodata
def_reg_tab:
	.byte VDP_REG_MODE1, VDP_M1_INIT		| 0: mode 1
	.byte VDP_REG_MODE2, VDP_M2_INIT + VDP_M2_DISP	| 1: mode 2
	.byte VDP_REG_NAMEA, VDP_NA_ADDR(0xc000)	| 2: scroll A nametable addr.
	.byte VDP_REG_NAMEW, 0				| 3: window nametable addr.
	.byte VDP_REG_NAMEB, VDP_NB_ADDR(0xe000)	| 4: scroll B nametable addr.
	.byte VDP_REG_SPR, VDP_SPRTAB_ADDR(0xd000)	| 5: sprite table addr.
	.byte VDP_REG_BGCOL, 0				| 7: bg color
	.byte VDP_REG_HINTR, 0				| 10: horiz. interrupt interval
	.byte VDP_REG_MODE3, 0				| 11: mode 3
	.byte VDP_REG_MODE4, VDP_M4_H40			| 12: mode 4
	.byte VDP_REG_HSCROLL, VDP_HSTAB_ADDR(0xf000)	| 13: hscroll table addr.
	.byte VDP_REG_AUTOINC, 2			| 15: autoincrement 2 bytes
	.byte VDP_REG_SCROLLSZ, VDP_SCR_H64		| 16: scroll size (64x32)
	.byte VDP_REG_WINX, 0, VDP_REG_WINY, 0		| 17,18: win x/y pos
	| zeroing the DMA registers at this point causes the real machine to
	| hang, so skip them.
	|.byte VDP_REG_DMACNTL, 0, VDP_REG_DMACNTH, 0	| 19-23: DMA regs
	|.byte VDP_REG_DMASRCL, 0, VDP_REG_DMASRCM, 0, VDP_REG_DMASRCH, 0	

	
| vi:ft=gas68k: