struct Material {
	vec3 diffuse, specular;
	float shin;
};

struct HitPoint {
	float dist;
	vec3 pos, norm;
	vec2 surfpos;
	Material mtl;
};

varying vec3 v_rorg, v_rdir;


vec3 shade(in vec3 ro, in vec3 rd, in HitPoint hit);
vec3 backdrop(in vec3 dir);

bool isect_scene(in vec3 ro, in vec3 rd, out HitPoint hit);

bool isect_floor(in vec3 ro, in vec3 rd, in vec2 sz, out HitPoint hit);
bool isect_plane(in vec3 ro, in vec3 rd, in vec4 plane, out HitPoint hit);
bool isect_sphere(in vec3 ro, in vec3 rd, in vec3 pos, float rad, out HitPoint hit);

vec3 tex_chess(in vec3 col1, in vec3 col2, in vec2 spos);

const Material mtl_sph = Material(vec3(1.0, 0.0, 0.0), vec3(1.0, 1.0, 1.0), 80.0);
const Material mtl_floor = Material(vec3(0.5, 0.5, 0.5), vec3(0.0, 0.0, 0.0), 1.0);

const vec3 light_pos = vec3(-10, 50, 30);

void main()
{
	vec3 rdir = normalize(v_rdir);
	gl_FragColor.rgb = backdrop(rdir);

	HitPoint hit;
	if(isect_scene(v_rorg, rdir, hit)) {
		gl_FragColor.rgb = shade(v_rorg, rdir, hit);
	} else {
		gl_FragColor.rgb = backdrop(rdir);
	}
	gl_FragColor.a = 1.0;
}

vec3 shade(in vec3 ro, in vec3 rd, in HitPoint hit)
{
	HitPoint shadow_hit;
	vec3 ldir = light_pos - hit.pos;

	vec3 col = vec3(0.03, 0.03, 0.03);	// ambient

	if(!isect_scene(hit.pos + hit.norm * 0.01, ldir, shadow_hit) || shadow_hit.dist > 1.0) {
		vec3 l = normalize(ldir);
		vec3 v = normalize(-rd);
		vec3 h = normalize(v + l);
		float ndotl = max(dot(hit.norm, l), 0.0);
		float ndoth = max(dot(hit.norm, h), 0.0);

		col += hit.mtl.diffuse * ndotl + hit.mtl.specular * pow(ndoth, hit.mtl.shin);
	}

	return col;
}

#define M_PI	3.1415926
#define M_2PI	(M_PI * 2.0)

vec3 backdrop(in vec3 dir)
{
	return mix(vec3(0.8, 0.3, 0.2), vec3(0.2, 0.3, 0.8), smoothstep(-0.1, 0.1, dir.y));
}

#define FLOOR_OFFS	vec3(3.0, 0.0, 0.0)
#define FLOOR_SIZE	vec2(5.5, 15.0)

bool isect_scene(in vec3 ro, in vec3 rd, out HitPoint hit_res)
{
	HitPoint hit, nearest;

	nearest.dist = 10000.0;

	if(isect_sphere(ro, rd, vec3(1.0, 0.0, 0.0), 1.0, hit)) {
		nearest = hit;
		nearest.mtl = mtl_sph;
	}

	if(isect_floor(ro, rd, FLOOR_SIZE, hit) && hit.dist < nearest.dist) {
		nearest = hit;
		nearest.mtl = mtl_floor;
		nearest.mtl.diffuse = tex_chess(vec3(1.0, 0.0, 0.0), vec3(1.0, 1.0, 0.0), hit.surfpos);
	}

	if(nearest.dist >= 10000.0) {
		return false;
	}

	hit_res = nearest;
	return true;
}

bool isect_floor(in vec3 ro, in vec3 rd, in vec2 sz, out HitPoint hit)
{
	if(!isect_plane(ro - FLOOR_OFFS, rd, vec4(0.0, 1.0, 0.0, -1.8), hit)) {
		return false;
	}

	if(abs(hit.pos.x) >= sz.x || abs(hit.pos.z) >= sz.y) {
		return false;
	}

	hit.pos += FLOOR_OFFS;
	hit.surfpos /= sz * 2.0;
	return true;
}

bool isect_plane(in vec3 ro, in vec3 rd, in vec4 plane, out HitPoint hit)
{
	float ndotrd = dot(rd, plane.xyz);

	if(abs(ndotrd) < 1e-6) {
		return false;
	}

	vec3 pp = plane.xyz * plane.w;
	vec3 pdir = pp - ro;
	float t = dot(pdir, plane.xyz) / ndotrd;

	if(t < 1e-6) {
		return false;
	}

	hit.dist = t;
	hit.pos = ro + rd * t;
	hit.norm = plane.xyz;
	hit.surfpos = hit.pos.xz;	/* XXX */
	return true;
}

bool isect_sphere(in vec3 ro, in vec3 rd, in vec3 pos, float rad, out HitPoint hit)
{
	float a = dot(rd, rd);
	float b = dot(rd * 2.0, (ro - pos));
	float c = dot(ro, ro) + dot(pos, pos) - 2.0 * dot(ro, pos) - rad * rad;

	float d = b * b - 4.0 * a * c;
	if(d < 1e-6) {
		return false;
	}

	float t0 = (-b + sqrt(d)) / (2.0 * a);
	float t1 = (-b - sqrt(d)) / (2.0 * a);

	if(t0 < 0.0) t0 = t1;
	if(t1 < 0.0) t1 = t0;
	float t = min(t0, t1);

	if(t < 1e-6) {
		return false;
	}

	hit.dist = t;
	hit.pos = ro + rd * t;
	hit.norm = normalize(hit.pos - pos);
	hit.surfpos.x = atan(hit.norm.z, hit.norm.x);
	hit.surfpos.y = acos(hit.norm.y);
	return true;
}

vec3 tex_chess(in vec3 col1, in vec3 col2, in vec2 spos)
{
	float foo = step(0.5, mod(spos.x * 8.0, 1.0)) * 2.0 - 1.0;
	float bar = step(0.5, mod(spos.y * 24.0, 1.0)) * 2.0 - 1.0;

	float xor = (foo * bar) * 0.5 + 0.5;

	return mix(col1, col2, xor);
}