git.mutantstargoat.com Git - faros-demo/blob - glsl-noise/simplex/4d.glsl

   1 //
   2 // Description : Array and textureless GLSL 2D/3D/4D simplex
   3 //               noise functions.
   4 //      Author : Ian McEwan, Ashima Arts.
   5 //  Maintainer : ijm
   6 //     Lastmod : 20110822 (ijm)
   7 //     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
   8 //               Distributed under the MIT License. See LICENSE file.
   9 //               https://github.com/ashima/webgl-noise
  10 //
  11
  12 vec4 mod289(vec4 x) {
  13   return x - floor(x * (1.0 / 289.0)) * 289.0; }
  14
  15 float mod289(float x) {
  16   return x - floor(x * (1.0 / 289.0)) * 289.0; }
  17
  18 vec4 permute(vec4 x) {
  19      return mod289(((x*34.0)+1.0)*x);
  20 }
  21
  22 float permute(float x) {
  23      return mod289(((x*34.0)+1.0)*x);
  24 }
  25
  26 vec4 taylorInvSqrt(vec4 r)
  27 {
  28   return 1.79284291400159 - 0.85373472095314 * r;
  29 }
  30
  31 float taylorInvSqrt(float r)
  32 {
  33   return 1.79284291400159 - 0.85373472095314 * r;
  34 }
  35
  36 vec4 grad4(float j, vec4 ip)
  37   {
  38   const vec4 ones = vec4(1.0, 1.0, 1.0, -1.0);
  39   vec4 p,s;
  40
  41   p.xyz = floor( fract (vec3(j) * ip.xyz) * 7.0) * ip.z - 1.0;
  42   p.w = 1.5 - dot(abs(p.xyz), ones.xyz);
  43   s = vec4(lessThan(p, vec4(0.0)));
  44   p.xyz = p.xyz + (s.xyz*2.0 - 1.0) * s.www;
  45
  46   return p;
  47   }
  48
  49 // (sqrt(5) - 1)/4 = F4, used once below
  50 #define F4 0.309016994374947451
  51
  52 float snoise(vec4 v)
  53   {
  54   const vec4  C = vec4( 0.138196601125011,  // (5 - sqrt(5))/20  G4
  55                         0.276393202250021,  // 2 * G4
  56                         0.414589803375032,  // 3 * G4
  57                        -0.447213595499958); // -1 + 4 * G4
  58
  59 // First corner
  60   vec4 i  = floor(v + dot(v, vec4(F4)) );
  61   vec4 x0 = v -   i + dot(i, C.xxxx);
  62
  63 // Other corners
  64
  65 // Rank sorting originally contributed by Bill Licea-Kane, AMD (formerly ATI)
  66   vec4 i0;
  67   vec3 isX = step( x0.yzw, x0.xxx );
  68   vec3 isYZ = step( x0.zww, x0.yyz );
  69 //  i0.x = dot( isX, vec3( 1.0 ) );
  70   i0.x = isX.x + isX.y + isX.z;
  71   i0.yzw = 1.0 - isX;
  72 //  i0.y += dot( isYZ.xy, vec2( 1.0 ) );
  73   i0.y += isYZ.x + isYZ.y;
  74   i0.zw += 1.0 - isYZ.xy;
  75   i0.z += isYZ.z;
  76   i0.w += 1.0 - isYZ.z;
  77
  78   // i0 now contains the unique values 0,1,2,3 in each channel
  79   vec4 i3 = clamp( i0, 0.0, 1.0 );
  80   vec4 i2 = clamp( i0-1.0, 0.0, 1.0 );
  81   vec4 i1 = clamp( i0-2.0, 0.0, 1.0 );
  82
  83   //  x0 = x0 - 0.0 + 0.0 * C.xxxx
  84   //  x1 = x0 - i1  + 1.0 * C.xxxx
  85   //  x2 = x0 - i2  + 2.0 * C.xxxx
  86   //  x3 = x0 - i3  + 3.0 * C.xxxx
  87   //  x4 = x0 - 1.0 + 4.0 * C.xxxx
  88   vec4 x1 = x0 - i1 + C.xxxx;
  89   vec4 x2 = x0 - i2 + C.yyyy;
  90   vec4 x3 = x0 - i3 + C.zzzz;
  91   vec4 x4 = x0 + C.wwww;
  92
  93 // Permutations
  94   i = mod289(i);
  95   float j0 = permute( permute( permute( permute(i.w) + i.z) + i.y) + i.x);
  96   vec4 j1 = permute( permute( permute( permute (
  97              i.w + vec4(i1.w, i2.w, i3.w, 1.0 ))
  98            + i.z + vec4(i1.z, i2.z, i3.z, 1.0 ))
  99            + i.y + vec4(i1.y, i2.y, i3.y, 1.0 ))
 100            + i.x + vec4(i1.x, i2.x, i3.x, 1.0 ));
 101
 102 // Gradients: 7x7x6 points over a cube, mapped onto a 4-cross polytope
 103 // 7*7*6 = 294, which is close to the ring size 17*17 = 289.
 104   vec4 ip = vec4(1.0/294.0, 1.0/49.0, 1.0/7.0, 0.0) ;
 105
 106   vec4 p0 = grad4(j0,   ip);
 107   vec4 p1 = grad4(j1.x, ip);
 108   vec4 p2 = grad4(j1.y, ip);
 109   vec4 p3 = grad4(j1.z, ip);
 110   vec4 p4 = grad4(j1.w, ip);
 111
 112 // Normalise gradients
 113   vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
 114   p0 *= norm.x;
 115   p1 *= norm.y;
 116   p2 *= norm.z;
 117   p3 *= norm.w;
 118   p4 *= taylorInvSqrt(dot(p4,p4));
 119
 120 // Mix contributions from the five corners
 121   vec3 m0 = max(0.6 - vec3(dot(x0,x0), dot(x1,x1), dot(x2,x2)), 0.0);
 122   vec2 m1 = max(0.6 - vec2(dot(x3,x3), dot(x4,x4)            ), 0.0);
 123   m0 = m0 * m0;
 124   m1 = m1 * m1;
 125   return 49.0 * ( dot(m0*m0, vec3( dot( p0, x0 ), dot( p1, x1 ), dot( p2, x2 )))
 126                + dot(m1*m1, vec2( dot( p3, x3 ), dot( p4, x4 ) ) ) ) ;
 127
 128   }
 129
 130 #pragma glslify: export(snoise)