git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8.8 FATAL_ERROR)
   2 PROJECT(freeglut)
   3
   4 # for multiarch LIBDIR support (requires cmake>=2.8.8)
   5 INCLUDE(GNUInstallDirs)
   6
   7 # NOTE: On Windows and Cygwin, the dll's are placed in the
   8 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   9 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
  10 # platforms, such as Linux, the shared libraries are put in
  11 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
  12 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  13 # platforms.
  14 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  15 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  16 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  17
  18 # setup version numbers
  19 # TODO: Update these for each release!
  20 set(VERSION_MAJOR 3)
  21 set(VERSION_MINOR 0)
  22 set(VERSION_PATCH 0)
  23
  24 # Update fg_version.h to match the versions number here in cmake
  25 CONFIGURE_FILE(src/fg_version.h.in src/fg_version.h)
  26
  27 # shared lib version numbers (change before release)
  28 set(SO_MAJOR 3)         # increment on backwards incompatible API/ABI changes
  29 set(SO_MINOR 10)        # increment on backwards compatible or internal changes
  30 set(SO_REV 0)           # if nothing else changed increment this
  31
  32 # FREEGLUT_BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  33 # re-declare it here so it will show up in the GUI.
  34 # by default, we want to build both
  35 OPTION(FREEGLUT_BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  36 OPTION(FREEGLUT_BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  37
  38 # option for whether warnings and errors should be printed
  39 OPTION(FREEGLUT_PRINT_ERRORS "Lib prints errors to stderr" ON)
  40 #MARK_AS_ADVANCED(FREEGLUT_PRINT_ERRORS)
  41 OPTION(FREEGLUT_PRINT_WARNINGS "Lib prints warnings to stderr" ON)
  42 #MARK_AS_ADVANCED(FREEGLUT_PRINT_WARNINGS)
  43
  44 # option to also copy .pdb files to install directory when executing
  45 # INSTALL target
  46 IF(MSVC)
  47     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  48 ELSE()
  49     SET(INSTALL_PDB OFF)
  50 ENDIF()
  51
  52 # OpenGL ES support
  53 OPTION(FREEGLUT_GLES "Use OpenGL ES (requires EGL)" OFF)
  54
  55 IF(NOT WIN32)
  56     # Wayland support
  57     OPTION(FREEGLUT_WAYLAND "Use Wayland (no X11)" OFF)
  58     # option to build either as "glut" (ON) or "freeglut" (OFF)
  59     OPTION(FREEGLUT_REPLACE_GLUT "Be a replacement for GLUT" ON)
  60 ENDIF()
  61
  62
  63 SET(FREEGLUT_HEADERS
  64     include/GL/freeglut.h
  65     include/GL/freeglut_ext.h
  66     include/GL/freeglut_std.h
  67     include/GL/glut.h
  68 )
  69 SET(FREEGLUT_SRCS
  70     ${FREEGLUT_HEADERS}
  71     src/fg_callbacks.c
  72     src/fg_cursor.c
  73     src/fg_display.c
  74     src/fg_ext.c
  75     src/fg_font_data.c
  76     src/fg_gamemode.c
  77     src/fg_geometry.c
  78     src/fg_gl2.c
  79     src/fg_gl2.h
  80     src/fg_init.c
  81     src/fg_init.h
  82     src/fg_internal.h
  83     src/fg_input_devices.c
  84     src/fg_joystick.c
  85     src/fg_main.c
  86     src/fg_misc.c
  87     src/fg_overlay.c
  88     src/fg_spaceball.c
  89     src/fg_state.c
  90     src/fg_stroke_mono_roman.c
  91     src/fg_stroke_roman.c
  92     src/fg_structure.c
  93     src/fg_teapot.c
  94     src/fg_teapot_data.h
  95     src/fg_videoresize.c
  96     src/fg_window.c
  97 )
  98 # TODO: OpenGL ES requires a compatible version of these files:
  99 IF(NOT FREEGLUT_GLES)
 100     LIST(APPEND FREEGLUT_SRCS
 101         src/fg_font.c
 102         src/fg_menu.c
 103     )
 104 ELSE()
 105     LIST(APPEND FREEGLUT_SRCS
 106         src/gles_stubs.c
 107     )
 108 ENDIF()
 109
 110 IF(WIN32)
 111     LIST(APPEND FREEGLUT_SRCS
 112         src/mswin/fg_cursor_mswin.c
 113         src/mswin/fg_display_mswin.c
 114         src/mswin/fg_ext_mswin.c
 115         src/mswin/fg_gamemode_mswin.c
 116         src/mswin/fg_init_mswin.c
 117         src/mswin/fg_internal_mswin.h
 118         src/mswin/fg_input_devices_mswin.c
 119         src/mswin/fg_joystick_mswin.c
 120         src/mswin/fg_main_mswin.c
 121         src/mswin/fg_menu_mswin.c
 122         src/mswin/fg_spaceball_mswin.c
 123         src/mswin/fg_state_mswin.c
 124         src/mswin/fg_structure_mswin.c
 125         src/mswin/fg_window_mswin.c
 126         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 127     )
 128     IF (MSVC AND NOT CMAKE_CL_64)
 129         # .def file only for 32bit Windows builds (TODO: MSVC only right
 130         # now, needed for any other Windows platform?)
 131         LIST(APPEND FREEGLUT_SRCS
 132             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 133         )
 134     ENDIF()
 135
 136 ELSEIF(ANDROID OR BLACKBERRY)
 137     # BlackBerry and Android share some similar design concepts and ideas, as with many mobile devices.
 138     # As such, some classes can be shared between the two. XXX: Possibly rename shareable classes to
 139     # a more generic name. *_stub? *_mobile?
 140     LIST(APPEND FREEGLUT_SRCS
 141         src/android/fg_cursor_android.c
 142         src/android/fg_ext_android.c
 143         src/android/fg_gamemode_android.c
 144         src/android/fg_joystick_android.c
 145         src/android/fg_spaceball_android.c
 146     )
 147     IF(ANDROID)
 148         LIST(APPEND FREEGLUT_SRCS
 149             src/android/native_app_glue/android_native_app_glue.c
 150             src/android/native_app_glue/android_native_app_glue.h
 151             src/android/fg_internal_android.h
 152             src/android/fg_init_android.c
 153             src/android/fg_input_devices_android.c
 154             src/android/fg_main_android.c
 155             src/android/fg_main_android.h
 156             src/android/fg_runtime_android.c
 157             src/android/fg_state_android.c
 158             src/android/fg_structure_android.c
 159             src/android/fg_window_android.c
 160         )
 161     ELSE()
 162         LIST(APPEND FREEGLUT_SRCS
 163             src/blackberry/fg_internal_blackberry.h
 164             src/blackberry/fg_init_blackberry.c
 165             src/x11/fg_input_devices_x11.c
 166             src/blackberry/fg_main_blackberry.c
 167             src/blackberry/fg_state_blackberry.c
 168             src/blackberry/fg_structure_blackberry.c
 169             src/blackberry/fg_window_blackberry.c
 170         )
 171     ENDIF()
 172
 173 ELSE()
 174     # UNIX (Wayland)
 175     IF(FREEGLUT_WAYLAND)
 176         LIST(APPEND FREEGLUT_SRCS
 177             src/wayland/fg_cursor_wl.c
 178             src/wayland/fg_ext_wl.c
 179             src/wayland/fg_gamemode_wl.c
 180             src/wayland/fg_init_wl.c
 181             src/wayland/fg_internal_wl.h
 182             src/wayland/fg_input_devices_wl.c
 183             src/wayland/fg_main_wl.c
 184             src/wayland/fg_state_wl.c
 185             src/wayland/fg_structure_wl.c
 186             src/wayland/fg_window_wl.c
 187             # font, serial port & joystick code are agnostic
 188             src/x11/fg_glutfont_definitions_x11.c
 189             src/x11/fg_input_devices_x11.c
 190             src/x11/fg_joystick_x11.c
 191         )
 192     # UNIX (X11)
 193     ELSE()
 194         LIST(APPEND FREEGLUT_SRCS
 195             src/x11/fg_cursor_x11.c
 196             src/x11/fg_ext_x11.c
 197             src/x11/fg_gamemode_x11.c
 198             src/x11/fg_glutfont_definitions_x11.c
 199             src/x11/fg_init_x11.c
 200             src/x11/fg_internal_x11.h
 201             src/x11/fg_input_devices_x11.c
 202             src/x11/fg_joystick_x11.c
 203             src/x11/fg_main_x11.c
 204             src/x11/fg_menu_x11.c
 205             src/x11/fg_spaceball_x11.c
 206             src/x11/fg_state_x11.c
 207             src/x11/fg_structure_x11.c
 208             src/x11/fg_window_x11.c
 209             src/x11/fg_xinput_x11.c
 210         )
 211         IF(NOT(FREEGLUT_GLES))
 212             LIST(APPEND FREEGLUT_SRCS
 213                 src/x11/fg_internal_x11_glx.h
 214                 src/x11/fg_display_x11_glx.c
 215                 src/x11/fg_state_x11_glx.c
 216                 src/x11/fg_state_x11_glx.h
 217                 src/x11/fg_window_x11_glx.c
 218                 src/x11/fg_window_x11_glx.h
 219             )
 220         ENDIF()
 221     ENDIF()
 222 ENDIF()
 223
 224 # OpenGL ES requires EGL, and so does Wayland
 225 IF(FREEGLUT_GLES OR FREEGLUT_WAYLAND)
 226     LIST(APPEND FREEGLUT_SRCS
 227         src/egl/fg_internal_egl.h
 228         src/egl/fg_display_egl.c
 229         src/egl/fg_ext_egl.c
 230         src/egl/fg_init_egl.c
 231         src/egl/fg_init_egl.h
 232         src/egl/fg_state_egl.c
 233         src/egl/fg_state_egl.h
 234         src/egl/fg_structure_egl.c
 235         src/egl/fg_structure_egl.h
 236         src/egl/fg_window_egl.c
 237         src/egl/fg_window_egl.h
 238     )
 239 ENDIF()
 240
 241 # For OpenGL ES (GLES): compile with -DFREEGLUT_GLES to cleanly
 242 # bootstrap headers inclusion in freeglut_std.h; this constant also
 243 # need to be defined in client applications (e.g. through pkg-config),
 244 # but do use GLES constants directly for all other needs
 245 # GLES1 and GLES2 libraries are compatible and can be co-linked.
 246 IF(FREEGLUT_GLES)
 247   ADD_DEFINITIONS(-DFREEGLUT_GLES)
 248   LIST(APPEND LIBS GLESv2 GLESv1_CM EGL)
 249 ELSE()
 250   FIND_PACKAGE(OpenGL REQUIRED)
 251   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 252   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 253 ENDIF()
 254
 255 # For Wayland: compile with -DFREEGLUT_WAYLAND and pull EGL
 256 IF(FREEGLUT_WAYLAND)
 257   ADD_DEFINITIONS(-DFREEGLUT_WAYLAND)
 258   LIST(APPEND LIBS wayland-client wayland-cursor wayland-egl EGL xkbcommon)
 259 ENDIF()
 260
 261 # lib m for math, not needed on windows
 262 IF (NOT WIN32)
 263     # For compilation:
 264     LIST(APPEND LIBS m)
 265     # For CHECK_FUNCTION_EXISTS:
 266     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 267 ENDIF()
 268
 269 IF(WIN32)
 270     # hide insecure CRT warnings, common practice
 271     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 272     IF(MSVC)
 273         SET( CMAKE_DEBUG_POSTFIX "d" )
 274     ENDIF(MSVC)
 275
 276     IF(NOT(MSVC_VERSION LESS "1600"))
 277     # minimum requirement for WM_TOUCH device
 278         ADD_DEFINITIONS(-D_WIN32_WINNT=0x0601)
 279         ADD_DEFINITIONS(-DWINVER=0x0601)
 280     ELSEIF(NOT(MSVC_VERSION LESS "1300"))
 281     # minimum requirement for spaceball device
 282         ADD_DEFINITIONS(-D_WIN32_WINNT=0x0501)
 283         ADD_DEFINITIONS(-DWINVER=0x0501)
 284     ELSE()
 285     # enable the use of Win2000 APIs (needed for really old compilers like MSVC6)
 286         ADD_DEFINITIONS(-D_WIN32_WINNT=0x0500)
 287         ADD_DEFINITIONS(-DWINVER=0x0500)
 288     ENDIF()
 289
 290 ENDIF()
 291
 292 IF(CMAKE_COMPILER_IS_GNUCC)
 293   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 294   IF(NOT(ANDROID OR BLACKBERRY OR FREEGLUT_WAYLAND))
 295     # not setting -ansi as EGL/KHR headers doesn't support it
 296     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pedantic")
 297   ENDIF()
 298 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 299
 300 INCLUDE(CheckIncludeFiles)
 301 IF(UNIX AND NOT(ANDROID OR BLACKBERRY OR FREEGLUT_WAYLAND))
 302     FIND_PACKAGE(X11 REQUIRED)
 303     INCLUDE_DIRECTORIES(${X11_INCLUDE_DIR})
 304     LIST(APPEND LIBS ${X11_LIBRARIES})
 305     IF(X11_Xrandr_FOUND)
 306         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 307         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 308     ENDIF()
 309     IF(X11_xf86vmode_FOUND)
 310         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 311         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 312     ENDIF()
 313     IF(X11_Xinput_FOUND)
 314         # Needed for multi-touch:
 315         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 316         LIST(APPEND LIBS ${X11_Xinput_LIB})
 317     ENDIF()
 318 ENDIF()
 319 IF(ANDROID)
 320     # -landroid for ANativeWindow
 321     # -llog for native Android logging
 322     LIST(APPEND LIBS android log)
 323 ELSEIF(BLACKBERRY)
 324     # -lbps for event loop
 325     # -screen for native screen
 326     LIST(APPEND LIBS bps screen)
 327
 328     if(NOT PLAYBOOK)
 329         # -lslog2 for logging
 330         # -pps for low-level screen manipulation
 331         LIST(APPEND LIBS slog2 pps)
 332     ENDIF()
 333 ENDIF()
 334
 335 INCLUDE(CheckFunctionExists)
 336 INCLUDE(CheckTypeSize)
 337 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 338 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 339 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 340 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 341 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 342 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 343 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 344 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 345 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 346 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 347 IF (NOT HAVE_XPARSEGEOMETRY)
 348    LIST(APPEND FREEGLUT_SRCS
 349         src/util/xparsegeometry_repl.c
 350         src/util/xparsegeometry_repl.h)
 351    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 352 ENDIF()
 353 # decide on suitable type for internal time keeping, 64-bit if possible
 354 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 355 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 356 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 357     IF (MSVC)
 358         # Some old Microsoft VC releases don't support unsigned long
 359         # long, but all we care about is support for unsigned __int64 on
 360         # MSVC, so test for presence of that type
 361         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 362     ELSEIF()
 363         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 364     ENDIF()
 365 ENDIF()
 366
 367 # The generated config.h is placed in the project's build directory, just to
 368 # ensure that all CMake-generated files are kept away from the main source tree.
 369 # As a result, the build directory must to be added to the include path list.
 370 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 371 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 372 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 373 IF(WIN32)
 374     # we also have to generate freeglut.rc, which contains the version
 375     # number
 376     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 377     IF (MSVC AND NOT CMAKE_CL_64)
 378         # .def file only for 32bit Windows builds with Visual Studio
 379         CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 380     ENDIF()
 381 ENDIF()
 382
 383 IF(FREEGLUT_BUILD_SHARED_LIBS)
 384     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 385 ENDIF()
 386 IF(FREEGLUT_BUILD_STATIC_LIBS)
 387     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 388 ENDIF()
 389
 390
 391 IF(WIN32)
 392     LIST(APPEND LIBS winmm)
 393     IF(FREEGLUT_BUILD_SHARED_LIBS)
 394         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 395     ENDIF()
 396     IF(FREEGLUT_BUILD_STATIC_LIBS)
 397         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 398         # need to set machine:x64 for linker, at least for VC10, and
 399         # doesn't hurt for older compilers:
 400         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 401         IF (CMAKE_CL_64)
 402             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 403         ENDIF()
 404     ENDIF()
 405 ELSE()
 406     # on UNIX we need to make sure:
 407     # - all shared libraries must have a soname/version, see :
 408     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 409     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 410     #   Current: -version-info 12:0:9 -> 3.9.0
 411     #   Note: most platforms now prefer the latter major.minor.revision form
 412     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 413     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 414     #   the lack of support for current:revision:age in CMake should
 415     #   not be a problem.
 416         # - the output library should be named glut so it'll be linkable with -lglut
 417         #   (unless FREEGLUT_REPLACE_GLUT is false).
 418     # - the shared library should link to the dependency libraries so that the user
 419     #   won't have to link them explicitly (they shouldn't have to know that we depend
 420     #   on Xrandr or Xxf86vm)
 421     IF(FREEGLUT_GLES)
 422                 SET(LIBNAME freeglut-gles)
 423     ELSE()
 424                 IF(FREEGLUT_REPLACE_GLUT)
 425                         SET(LIBNAME glut)
 426                 ELSE()
 427                         SET(LIBNAME freeglut)
 428                 ENDIF()
 429         ENDIF()
 430
 431     IF(FREEGLUT_BUILD_SHARED_LIBS)
 432       SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION ${SO_MAJOR}.${SO_MINOR}.${SO_REV} SOVERSION ${SO_MAJOR} OUTPUT_NAME ${LIBNAME})
 433     ENDIF()
 434     IF(FREEGLUT_BUILD_STATIC_LIBS)
 435       SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 436     ENDIF()
 437     IF(ANDROID)
 438         # Not in CMake toolchain file, because the toolchain
 439         # file is called several times and generally doesn't
 440         # seem to be meant for modifying CFLAGS:
 441         # '-mandroid' is not mandatory but doesn't hurt
 442         # '-O0 -gstabs+' helps the currently buggy GDB port
 443         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 444         # Not using _INIT variables, they seem to be used internally only
 445         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 446         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 447     ENDIF()
 448 ENDIF()
 449 IF(FREEGLUT_BUILD_SHARED_LIBS)
 450     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 451 ENDIF()
 452 IF(FREEGLUT_BUILD_STATIC_LIBS)
 453     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 454 ENDIF()
 455
 456 IF(FREEGLUT_BUILD_SHARED_LIBS)
 457     INSTALL(TARGETS freeglut
 458             RUNTIME DESTINATION bin
 459             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 460             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 461     )
 462     IF(INSTALL_PDB)
 463         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Debug/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 464             DESTINATION bin
 465                         CONFIGURATIONS Debug)
 466     ENDIF()
 467 ENDIF()
 468 IF(FREEGLUT_BUILD_STATIC_LIBS)
 469     INSTALL(TARGETS freeglut_static
 470             RUNTIME DESTINATION bin
 471             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 472             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 473     )
 474     IF(INSTALL_PDB)
 475         INSTALL(FILES ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/Debug/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 476             DESTINATION lib
 477                         CONFIGURATIONS Debug)
 478     ENDIF()
 479 ENDIF()
 480 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 481
 482
 483
 484 # Optionally build demos, on by default.
 485 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 486
 487 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 488 # lib m for math, not needed on windows
 489 IF (NOT WIN32)
 490     LIST(APPEND DEMO_LIBS m)
 491 ENDIF()
 492
 493 MACRO(ADD_DEMO name)
 494     IF( FREEGLUT_BUILD_DEMOS )
 495         IF(FREEGLUT_BUILD_SHARED_LIBS)
 496             ADD_EXECUTABLE(${name} ${ARGN})
 497             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 498             IF(WIN32 AND MSVC)
 499                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 500             ENDIF()
 501         ENDIF()
 502         IF(FREEGLUT_BUILD_STATIC_LIBS)
 503             ADD_EXECUTABLE(${name}_static ${ARGN})
 504             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 505             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 506             IF(WIN32 AND MSVC)
 507                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 508             ENDIF()
 509         ENDIF()
 510     ENDIF()
 511 ENDMACRO()
 512
 513 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 514 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 515 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 516 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 517 IF (NOT WIN32)
 518     ADD_DEMO(One             progs/demos/One/one.c)
 519 ELSE()
 520     ADD_DEMO(One             progs/demos/One/one.c
 521                              progs/demos/One/one.rc)
 522 ENDIF()
 523 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 524 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 525 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 526                          progs/demos/shapes/glmatrix.h
 527                          progs/demos/shapes/glmatrix.c)
 528 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 529 IF(UNIX)
 530     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 531                              progs/demos/spaceball/vmath.c
 532                              progs/demos/spaceball/vmath.h)
 533 ENDIF()
 534 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 535 ADD_DEMO(timer           progs/demos/timer/timer.c)
 536
 537
 538
 539 # pkg-config support, to install at $(libdir)/pkgconfig
 540 # Define static build dependencies
 541 IF(WIN32)
 542   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 543 ELSEIF(FREEGLUT_GLES)
 544   IF(ANDROID)
 545     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lGLESv1_CM -lEGL -lm")
 546   ELSEIF(BLACKBERRY)
 547     IF(PLAYBOOK)
 548       SET(PC_LIBS_PRIVATE "-lbps -lscreen -lGLESv2 -lGLESv1_CM -lEGL -lm")
 549     ELSE()
 550       SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lscreen -lGLESv2 -lGLESv1_CM -lEGL -lm")
 551     ENDIF()
 552   ELSEIF(FREEGLUT_WAYLAND)
 553     SET(PC_LIBS_PRIVATE "-lwayland-client -lwayland-cursor -lwayland-egl -lGLESv2 -lGLESv1_CM -lEGL -lxkbcommon -lm")
 554   ELSE()
 555     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lGLESv1_CM -lEGL -lm")
 556   ENDIF()
 557 ELSE()
 558   IF(FREEGLUT_WAYLAND)
 559     SET(PC_LIBS_PRIVATE "-lwayland-client -lwayland-cursor -lwayland-egl -lGL -lxkbcommon -lm")
 560   ELSE()
 561     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 562   ENDIF()
 563 ENDIF()
 564 # Client applications need to define FreeGLUT GLES version to
 565 # bootstrap headers inclusion in freeglut_std.h:
 566 SET(PC_LIBNAME "glut")
 567 SET(PC_FILENAME "freeglut.pc")
 568 IF(FREEGLUT_GLES)
 569   SET(PC_CFLAGS "-DFREEGLUT_GLES")
 570   SET(PC_LIBNAME "freeglut-gles")
 571   SET(PC_FILENAME "freeglut-gles.pc")
 572 ENDIF()
 573 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 574 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/ RENAME ${PC_FILENAME})
 575 # TODO: change the library and .pc name when building for GLES,
 576 # e.g. -lglut-GLES