git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 SET(FREEGLUT_HEADERS
  22     include/GL/freeglut.h
  23     include/GL/freeglut_ext.h
  24     include/GL/freeglut_std.h
  25     include/GL/glut.h
  26 )
  27 SET(FREEGLUT_SRCS
  28     ${FREEGLUT_HEADERS}
  29     src/fg_callbacks.c
  30     src/fg_cursor.c
  31     src/fg_display.c
  32     src/fg_ext.c
  33     src/fg_font_data.c
  34     src/fg_gamemode.c
  35     src/fg_init.c
  36     src/fg_internal.h
  37     src/fg_input_devices.c
  38     src/fg_joystick.c
  39     src/fg_main.c
  40     src/fg_misc.c
  41     src/fg_overlay.c
  42     src/fg_spaceball.c
  43     src/fg_state.c
  44     src/fg_stroke_mono_roman.c
  45     src/fg_stroke_roman.c
  46     src/fg_structure.c
  47     src/fg_videoresize.c
  48     src/fg_window.c
  49 )
  50 # Android port requires adding a version of these compatible with
  51 # OpenGL ES (TODO):
  52 IF(NOT ANDROID)
  53     LIST(APPEND FREEGLUT_SRCS
  54         src/fg_font.c
  55         src/fg_geometry.c
  56         src/fg_menu.c
  57         src/fg_teapot.c
  58     )
  59 ENDIF()
  60
  61 IF(WIN32)
  62     LIST(APPEND FREEGLUT_SRCS
  63         src/mswin/fg_cursor_mswin.c
  64         src/mswin/fg_display_mswin.c
  65         src/mswin/fg_ext_mswin.c
  66         src/mswin/fg_gamemode_mswin.c
  67         src/mswin/fg_init_mswin.c
  68         src/mswin/fg_internal_mswin.h
  69         src/mswin/fg_input_devices_mswin.c
  70         src/mswin/fg_joystick_mswin.c
  71         src/mswin/fg_main_mswin.c
  72         src/mswin/fg_menu_mswin.c
  73         src/mswin/fg_spaceball_mswin.c
  74         src/mswin/fg_state_mswin.c
  75         src/mswin/fg_structure_mswin.c
  76         src/mswin/fg_window_mswin.c
  77         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  78     )
  79     IF (MSVC AND NOT CMAKE_CL_64)
  80         # .def file only for 32bit Windows builds
  81         LIST(APPEND FREEGLUT_SRCS
  82             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
  83         )
  84     ENDIF()
  85
  86 ELSEIF(ANDROID)
  87     LIST(APPEND FREEGLUT_SRCS
  88         src/egl/fg_internal_egl.h
  89         src/egl/fg_display_egl.c
  90         src/egl/fg_init_egl.c
  91         src/egl/fg_structure_egl.c
  92         src/egl/fg_window_egl.c
  93         src/android/native_app_glue/android_native_app_glue.c
  94         src/android/native_app_glue/android_native_app_glue.h
  95         src/android/fg_runtime_android.c
  96         src/android/fg_gamemode_android.c
  97         src/android/fg_input_devices_android.c
  98         src/android/fg_joystick_android.c
  99         src/android/fg_main_android.c
 100         src/android/fg_spaceball_android.c
 101         src/android/fg_state_android.c
 102         src/android/fg_window_android.c
 103         src/android/opengles_stubs.c
 104         src/android/fg_internal_android.h
 105     )
 106 ELSE()
 107     LIST(APPEND FREEGLUT_SRCS
 108         src/x11/fg_cursor_x11.c
 109         src/x11/fg_display_x11.c
 110         src/x11/fg_ext_x11.c
 111         src/x11/fg_gamemode_x11.c
 112         src/x11/fg_glutfont_definitions_x11.c
 113         src/x11/fg_init_x11.c
 114         src/x11/fg_internal_x11.h
 115         src/x11/fg_input_devices_x11.c
 116         src/x11/fg_joystick_x11.c
 117         src/x11/fg_main_x11.c
 118         src/x11/fg_menu_x11.c
 119         src/x11/fg_spaceball_x11.c
 120         src/x11/fg_state_x11.c
 121         src/x11/fg_structure_x11.c
 122         src/x11/fg_window_x11.c
 123         src/x11/fg_xinput_x11.c
 124     )
 125 ENDIF()
 126
 127 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
 128 # re-declare it here so it will show up in the GUI.
 129 # by default, we want to build both
 130 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
 131 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
 132
 133 # OpenGL ES support
 134 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
 135 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
 136
 137 # For OpenGL ES (GLES):
 138 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 139 #   bootstrap headers inclusion in freeglut_std.h; these constants
 140 #   also need to be defined in client applications (e.g through
 141 #   pkg-config), but use GLES constants directly for all other needs
 142 # - define GLES version-specific library
 143 IF(FREEGLUT_GLES2)
 144   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 145   LIST(APPEND LIBS GLESv2 EGL)
 146 ELSEIF(FREEGLUT_GLES1)
 147   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 148   LIST(APPEND LIBS GLESv1 EGL)
 149 ELSE()
 150   FIND_PACKAGE(OpenGL REQUIRED)
 151   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 152   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 153 ENDIF()
 154
 155 # lib m for math, not needed on windows
 156 IF (NOT WIN32)
 157     LIST(APPEND LIBS m)
 158 ENDIF()
 159
 160 IF(WIN32)
 161     # hide insecure CRT warnings, common practice
 162     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 163 ENDIF()
 164
 165 if(UNIX AND NOT ANDROID)
 166     FIND_PACKAGE(X11 REQUIRED)
 167     LIST(APPEND LIBS ${X11_LIBRARIES})
 168     IF(X11_Xrandr_FOUND)
 169         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 170         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 171     ENDIF()
 172     IF(X11_xf86vmode_FOUND)
 173         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 174         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 175         IF(NOT "${X11_Xxf86vm_LIB}")
 176             SET(X11_Xxf86vm_LIB "Xxf86vm")
 177         ENDIF()
 178         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 179     ENDIF()
 180 ENDIF()
 181
 182 INCLUDE(CheckIncludeFiles)
 183 INCLUDE(CheckFunctionExists)
 184 INCLUDE(CheckTypeSize)
 185 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 186 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 187 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 188 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 189 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 190 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 191 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 192 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 193 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 194 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 195 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 196 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 197 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 198 IF (NOT HAVE_XPARSEGEOMETRY)
 199    LIST(APPEND FREEGLUT_SRCS
 200         src/util/xparsegeometry_repl.c
 201         src/util/xparsegeometry_repl.h)
 202    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 203 ENDIF()
 204 # decide on suitable type for internal time keeping, 64-bit if possible
 205 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 206 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 207 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 208     IF (MSVC)
 209         # Some old Microsoft VC don't support unsigned long long, but all we
 210         # care about support unsigned __int64, so test for presence of that
 211         # type
 212         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 213     ELSEIF()
 214         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 215     ENDIF()
 216 ENDIF()
 217
 218
 219 # The generated config.h is placed in the project's build directory, just to
 220 # ensure that all CMake-generated files are kept away from the main source tree.
 221 # As a result, the build directory must to be added to the include path list.
 222 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 223 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 224 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 225 IF(WIN32)
 226     # we also have to generate freeglut.rc, which contains the version
 227     # number
 228     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 229     IF (MSVC AND NOT CMAKE_CL_64)
 230         # .def file only for 32bit Windows builds with Visual Studio
 231         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 232     ENDIF()
 233 ENDIF()
 234
 235 IF(BUILD_SHARED_LIBS)
 236     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 237 ENDIF()
 238 IF(BUILD_STATIC_LIBS)
 239     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 240 ENDIF()
 241
 242
 243 IF(WIN32)
 244     LIST(APPEND LIBS winmm)
 245     IF(BUILD_SHARED_LIBS)
 246         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 247     ENDIF()
 248     IF(BUILD_STATIC_LIBS)
 249         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 250         # need to set machine:x64 for linker, at least for VC10, and
 251         # doesn't hurt for older compilers:
 252         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 253         IF (CMAKE_CL_64)
 254             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 255         ENDIF()
 256     ENDIF()
 257 ELSE()
 258     # on UNIX we need to make sure:
 259     # - all shared libraries must have a soname/version, see :
 260     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 261     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 262     #   Current: -version-info 12:0:9 -> 3.9.0
 263     # - the output library should be named glut so it'll be linkable with -lglut
 264     # - the shared library should link to the dependency libraries so that the user
 265     #   won't have to link them explicitly (they shouldn't have to know that we depend
 266     #   on Xrandr or Xxf86vm)
 267     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 268     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 269     IF(ANDROID)
 270         # Not in CMake toolchain file, because the toolchain
 271         # file is called several times and generally doesn't
 272         # seem to be meant for modifying CFLAGS:
 273         # '-mandroid' is not mandatory but doesn't hurt
 274         # '-O0 -gstabs+' helps the currently buggy GDB port
 275         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 276         # Not using _INIT variables, they seem to be used internally only
 277         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 278         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 279     ENDIF()
 280 ENDIF()
 281 IF(BUILD_SHARED_LIBS)
 282     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 283 ENDIF()
 284 IF(BUILD_STATIC_LIBS)
 285     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 286 ENDIF()
 287
 288 IF(BUILD_SHARED_LIBS)
 289     INSTALL(TARGETS freeglut DESTINATION lib)
 290 ENDIF()
 291 IF(BUILD_STATIC_LIBS)
 292     INSTALL(TARGETS freeglut_static DESTINATION lib)
 293 ENDIF()
 294 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 295
 296
 297
 298 # Optionally build demos, on by default.
 299 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 300
 301 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 302 # lib m for math, not needed on windows
 303 IF (NOT WIN32)
 304     LIST(APPEND DEMO_LIBS m)
 305 ENDIF()
 306
 307 MACRO(ADD_DEMO name)
 308     IF( FREEGLUT_BUILD_DEMOS )
 309         IF(BUILD_SHARED_LIBS)
 310             ADD_EXECUTABLE(${name} ${ARGN})
 311             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 312         ENDIF()
 313         IF(BUILD_STATIC_LIBS)
 314             ADD_EXECUTABLE(${name}_static ${ARGN})
 315             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 316             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 317         ENDIF()
 318     ENDIF()
 319 ENDMACRO()
 320
 321 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 322 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 323 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 324 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 325 ADD_DEMO(One             progs/demos/One/one.c)
 326 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 327 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 328 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 329 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 330                          progs/demos/spaceball/vmath.c
 331                          progs/demos/spaceball/vmath.h)
 332 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 333 ADD_DEMO(timer           progs/demos/timer/timer.c)
 334
 335 # finally, if any demos are built, copy needed files to output directory
 336 # (currently, thats just the input file for the Fractals demo)
 337 IF(FREEGLUT_BUILD_DEMOS)
 338     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 339     IF(BUILD_SHARED_LIBS)
 340         SET(Frac_target Fractals)
 341     ELSE()
 342         SET(Frac_target Fractals_static)
 343     ENDIF()
 344     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 345     ADD_CUSTOM_COMMAND(
 346         TARGET ${Frac_target}
 347         POST_BUILD
 348         COMMAND ${CMAKE_COMMAND} -E copy
 349         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 350         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 351     )
 352 ENDIF()
 353
 354 # pkg-config support, to install at $(libdir)/pkgconfig
 355 # Define static build dependencies
 356 IF(WIN32)
 357   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32")
 358 ELSEIF(ANDROID)
 359   SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL")
 360 ELSE()
 361   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL")
 362 ENDIF()
 363 # Client applications need to define FreeGLUT GLES version to
 364 # bootstrap headers inclusion in freeglut_std.h:
 365 IF(FREEGLUT_GLES2)
 366   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 367 ELSEIF(FREEGLUT_GLES1)
 368   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 369 ENDIF()
 370 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 371 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig)
 372 # TODO: change the library and .pc name when building for GLES,
 373 # e.g. -lglut-GLES2