git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # OpenGL ES support
  28 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  29 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  30
  31
  32 SET(FREEGLUT_HEADERS
  33     include/GL/freeglut.h
  34     include/GL/freeglut_ext.h
  35     include/GL/freeglut_std.h
  36     include/GL/glut.h
  37 )
  38 SET(FREEGLUT_SRCS
  39     ${FREEGLUT_HEADERS}
  40     src/fg_callbacks.c
  41     src/fg_cursor.c
  42     src/fg_display.c
  43     src/fg_ext.c
  44     src/fg_font_data.c
  45     src/fg_gamemode.c
  46     src/fg_gl2.c
  47     src/fg_gl2.h
  48     src/fg_init.c
  49     src/fg_init.h
  50     src/fg_internal.h
  51     src/fg_input_devices.c
  52     src/fg_joystick.c
  53     src/fg_main.c
  54     src/fg_main.h
  55     src/fg_misc.c
  56     src/fg_overlay.c
  57     src/fg_spaceball.c
  58     src/fg_state.c
  59     src/fg_stroke_mono_roman.c
  60     src/fg_stroke_roman.c
  61     src/fg_structure.c
  62     src/fg_videoresize.c
  63     src/fg_window.c
  64 )
  65 # TODO: OpenGL ES requires a compatible version of these files:
  66 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  67     LIST(APPEND FREEGLUT_SRCS
  68         src/fg_font.c
  69         src/fg_menu.c
  70         src/fg_teapot.c
  71         src/fg_teapot_data.h
  72         src/fg_geometry.c
  73     )
  74 ELSE()
  75     LIST(APPEND FREEGLUT_SRCS
  76         src/fg_geometry.c
  77         src/gles_stubs.c
  78     )
  79 ENDIF()
  80
  81 IF(WIN32)
  82     LIST(APPEND FREEGLUT_SRCS
  83         src/mswin/fg_cursor_mswin.c
  84         src/mswin/fg_display_mswin.c
  85         src/mswin/fg_ext_mswin.c
  86         src/mswin/fg_gamemode_mswin.c
  87         src/mswin/fg_init_mswin.c
  88         src/mswin/fg_internal_mswin.h
  89         src/mswin/fg_input_devices_mswin.c
  90         src/mswin/fg_joystick_mswin.c
  91         src/mswin/fg_main_mswin.c
  92         src/mswin/fg_menu_mswin.c
  93         src/mswin/fg_spaceball_mswin.c
  94         src/mswin/fg_state_mswin.c
  95         src/mswin/fg_structure_mswin.c
  96         src/mswin/fg_window_mswin.c
  97         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  98     )
  99     IF (MSVC AND NOT CMAKE_CL_64)
 100         # .def file only for 32bit Windows builds
 101         LIST(APPEND FREEGLUT_SRCS
 102             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 103         )
 104     ENDIF()
 105
 106 ELSEIF(ANDROID)
 107     LIST(APPEND FREEGLUT_SRCS
 108         src/android/native_app_glue/android_native_app_glue.c
 109         src/android/native_app_glue/android_native_app_glue.h
 110         src/android/fg_internal_android.h
 111         src/android/fg_cursor_android.c
 112         src/android/fg_ext_android.c
 113         src/android/fg_gamemode_android.c
 114         src/android/fg_init_android.c
 115         src/android/fg_input_devices_android.c
 116         src/android/fg_joystick_android.c
 117         src/android/fg_main_android.c
 118         src/android/fg_main_android.h
 119         src/android/fg_runtime_android.c
 120         src/android/fg_spaceball_android.c
 121         src/android/fg_state_android.c
 122         src/android/fg_structure_android.c
 123         src/android/fg_window_android.c
 124     )
 125 ELSE()
 126     LIST(APPEND FREEGLUT_SRCS
 127         src/x11/fg_cursor_x11.c
 128         src/x11/fg_ext_x11.c
 129         src/x11/fg_gamemode_x11.c
 130         src/x11/fg_glutfont_definitions_x11.c
 131         src/x11/fg_init_x11.c
 132         src/x11/fg_internal_x11.h
 133         src/x11/fg_input_devices_x11.c
 134         src/x11/fg_joystick_x11.c
 135         src/x11/fg_main_x11.c
 136         src/x11/fg_menu_x11.c
 137         src/x11/fg_spaceball_x11.c
 138         src/x11/fg_state_x11.c
 139         src/x11/fg_structure_x11.c
 140         src/x11/fg_window_x11.c
 141         src/x11/fg_xinput_x11.c
 142     )
 143     IF(NOT(FREEGLUT_GLES2 OR FREEGLUT_GLES1))
 144         LIST(APPEND FREEGLUT_SRCS
 145             src/x11/fg_internal_x11_glx.h
 146             src/x11/fg_display_x11_glx.c
 147             src/x11/fg_state_x11_glx.c
 148             src/x11/fg_window_x11_glx.c
 149             src/x11/fg_window_x11_glx.h
 150         )
 151     ENDIF()
 152 ENDIF()
 153 IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 154     LIST(APPEND FREEGLUT_SRCS
 155         src/egl/fg_internal_egl.h
 156         src/egl/fg_display_egl.c
 157         src/egl/fg_ext_egl.c
 158         src/egl/fg_init_egl.c
 159         src/egl/fg_init_egl.h
 160         src/egl/fg_state_egl.c
 161         src/egl/fg_state_egl.h
 162         src/egl/fg_structure_egl.c
 163         src/egl/fg_structure_egl.h
 164         src/egl/fg_window_egl.c
 165         src/egl/fg_window_egl.h
 166     )
 167 ENDIF()
 168
 169 # For OpenGL ES (GLES):
 170 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 171 #   bootstrap headers inclusion in freeglut_std.h; these constants
 172 #   also need to be defined in client applications (e.g through
 173 #   pkg-config), but use GLES constants directly for all other needs
 174 # - define GLES version-specific library
 175 IF(FREEGLUT_GLES2)
 176   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 177   LIST(APPEND LIBS GLESv2 EGL)
 178 ELSEIF(FREEGLUT_GLES1)
 179   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 180   LIST(APPEND LIBS GLESv1_CM EGL)
 181 ELSE()
 182   FIND_PACKAGE(OpenGL REQUIRED)
 183   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 184   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 185 ENDIF()
 186
 187 # lib m for math, not needed on windows
 188 IF (NOT WIN32)
 189     LIST(APPEND LIBS m)
 190 ENDIF()
 191
 192 IF(WIN32)
 193     # hide insecure CRT warnings, common practice
 194     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 195 ENDIF()
 196
 197 IF(CMAKE_COMPILER_IS_GNUCC)
 198   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 199   IF(!ANDROID)
 200     # not setting -ansi as EGL/KHR headers doesn't support it
 201     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ansi")
 202   ENDIF()
 203 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 204
 205 if(UNIX AND NOT ANDROID)
 206     FIND_PACKAGE(X11 REQUIRED)
 207     LIST(APPEND LIBS ${X11_LIBRARIES})
 208     IF(X11_Xrandr_FOUND)
 209         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 210         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 211     ENDIF()
 212     IF(X11_xf86vmode_FOUND)
 213         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 214         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 215         IF(NOT "${X11_Xxf86vm_LIB}")
 216             SET(X11_Xxf86vm_LIB "Xxf86vm")
 217         ENDIF()
 218         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 219     ENDIF()
 220 ENDIF()
 221
 222 INCLUDE(CheckIncludeFiles)
 223 INCLUDE(CheckFunctionExists)
 224 INCLUDE(CheckTypeSize)
 225 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 226 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 227 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 228 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 229 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 230 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 231 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 232 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 233 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 234 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 235 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 236 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 237 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 238 IF (NOT HAVE_XPARSEGEOMETRY)
 239    LIST(APPEND FREEGLUT_SRCS
 240         src/util/xparsegeometry_repl.c
 241         src/util/xparsegeometry_repl.h)
 242    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 243 ENDIF()
 244 # decide on suitable type for internal time keeping, 64-bit if possible
 245 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 246 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 247 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 248     IF (MSVC)
 249         # Some old Microsoft VC don't support unsigned long long, but all we
 250         # care about support unsigned __int64, so test for presence of that
 251         # type
 252         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 253     ELSEIF()
 254         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 255     ENDIF()
 256 ENDIF()
 257
 258
 259 # The generated config.h is placed in the project's build directory, just to
 260 # ensure that all CMake-generated files are kept away from the main source tree.
 261 # As a result, the build directory must to be added to the include path list.
 262 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 263 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 264 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 265 IF(WIN32)
 266     # we also have to generate freeglut.rc, which contains the version
 267     # number
 268     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 269     IF (MSVC AND NOT CMAKE_CL_64)
 270         # .def file only for 32bit Windows builds with Visual Studio
 271         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 272     ENDIF()
 273 ENDIF()
 274
 275 IF(BUILD_SHARED_LIBS)
 276     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 277 ENDIF()
 278 IF(BUILD_STATIC_LIBS)
 279     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 280 ENDIF()
 281
 282
 283 IF(WIN32)
 284     LIST(APPEND LIBS winmm)
 285     IF(BUILD_SHARED_LIBS)
 286         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 287     ENDIF()
 288     IF(BUILD_STATIC_LIBS)
 289         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 290         # need to set machine:x64 for linker, at least for VC10, and
 291         # doesn't hurt for older compilers:
 292         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 293         IF (CMAKE_CL_64)
 294             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 295         ENDIF()
 296     ENDIF()
 297 ELSE()
 298     # on UNIX we need to make sure:
 299     # - all shared libraries must have a soname/version, see :
 300     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 301     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 302     #   Current: -version-info 12:0:9 -> 3.9.0
 303     # - the output library should be named glut so it'll be linkable with -lglut
 304     # - the shared library should link to the dependency libraries so that the user
 305     #   won't have to link them explicitly (they shouldn't have to know that we depend
 306     #   on Xrandr or Xxf86vm)
 307     IF(FREEGLUT_GLES2)
 308       SET(LIBNAME freeglut-gles2)
 309     ELSEIF(FREEGLUT_GLES1)
 310       SET(LIBNAME freeglut-gles1)
 311     ELSE()
 312       SET(LIBNAME glut)
 313     ENDIF()
 314
 315     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME ${LIBNAME})
 316     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 317     IF(ANDROID)
 318         # Not in CMake toolchain file, because the toolchain
 319         # file is called several times and generally doesn't
 320         # seem to be meant for modifying CFLAGS:
 321         # '-mandroid' is not mandatory but doesn't hurt
 322         # '-O0 -gstabs+' helps the currently buggy GDB port
 323         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 324         # Not using _INIT variables, they seem to be used internally only
 325         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 326         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 327     ENDIF()
 328 ENDIF()
 329 IF(BUILD_SHARED_LIBS)
 330     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 331 ENDIF()
 332 IF(BUILD_STATIC_LIBS)
 333     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 334 ENDIF()
 335
 336 IF(BUILD_SHARED_LIBS)
 337     INSTALL(TARGETS freeglut DESTINATION lib)
 338 ENDIF()
 339 IF(BUILD_STATIC_LIBS)
 340     INSTALL(TARGETS freeglut_static DESTINATION lib)
 341 ENDIF()
 342 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 343
 344
 345
 346 # Optionally build demos, on by default.
 347 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 348
 349 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 350 # lib m for math, not needed on windows
 351 IF (NOT WIN32)
 352     LIST(APPEND DEMO_LIBS m)
 353 ENDIF()
 354
 355 MACRO(ADD_DEMO name)
 356     IF( FREEGLUT_BUILD_DEMOS )
 357         IF(BUILD_SHARED_LIBS)
 358             ADD_EXECUTABLE(${name} ${ARGN})
 359             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 360         ENDIF()
 361         IF(BUILD_STATIC_LIBS)
 362             ADD_EXECUTABLE(${name}_static ${ARGN})
 363             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 364             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 365         ENDIF()
 366     ENDIF()
 367 ENDMACRO()
 368
 369 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 370 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 371 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 372 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 373 ADD_DEMO(One             progs/demos/One/one.c)
 374 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 375 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 376 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 377 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 378                          progs/demos/spaceball/vmath.c
 379                          progs/demos/spaceball/vmath.h)
 380 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 381 ADD_DEMO(timer           progs/demos/timer/timer.c)
 382
 383 # finally, if any demos are built, copy needed files to output directory
 384 # (currently, thats just the input file for the Fractals demo)
 385 IF(FREEGLUT_BUILD_DEMOS)
 386     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 387     IF(BUILD_SHARED_LIBS)
 388         SET(Frac_target Fractals)
 389     ELSE()
 390         SET(Frac_target Fractals_static)
 391     ENDIF()
 392     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 393     ADD_CUSTOM_COMMAND(
 394         TARGET ${Frac_target}
 395         POST_BUILD
 396         COMMAND ${CMAKE_COMMAND} -E copy
 397         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 398         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 399     )
 400 ENDIF()
 401
 402 # pkg-config support, to install at $(libdir)/pkgconfig
 403 # Define static build dependencies
 404 IF(WIN32)
 405   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 406 ELSEIF(FREEGLUT_GLES2)
 407   IF(ANDROID)
 408     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 409   ELSE()
 410     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 411   ENDIF()
 412 ELSEIF(FREEGLUT_GLES1)
 413   IF(ANDROID)
 414     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 415   ELSE()
 416     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 417   ENDIF()
 418 ELSE()
 419   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 420 ENDIF()
 421 # Client applications need to define FreeGLUT GLES version to
 422 # bootstrap headers inclusion in freeglut_std.h:
 423 SET(PC_LIBNAME "glut")
 424 SET(PC_FILENAME "freeglut.pc")
 425 IF(FREEGLUT_GLES2)
 426   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 427   SET(PC_LIBNAME "freeglut-gles2")
 428   SET(PC_FILENAME "freeglut-gles2.pc")
 429 ELSEIF(FREEGLUT_GLES1)
 430   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 431   SET(PC_LIBNAME "freeglut-gles1")
 432   SET(PC_FILENAME "freeglut-gles1.pc")
 433 ENDIF()
 434 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 435 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 436 # TODO: change the library and .pc name when building for GLES,
 437 # e.g. -lglut-GLES2