git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8 FATAL_ERROR)
   2 PROJECT(freeglut)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms.
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  14
  15 # setup version numbers
  16 # TODO: Update these for each release!
  17 set(VERSION_MAJOR 3)
  18 set(VERSION_MINOR 0)
  19 set(VERSION_PATCH 0)
  20
  21
  22 # FREEGLUT_BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  23 # re-declare it here so it will show up in the GUI.
  24 # by default, we want to build both
  25 OPTION(FREEGLUT_BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  26 OPTION(FREEGLUT_BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  27
  28 # option for whether warnings and errors should be printed
  29 OPTION(FREEGLUT_PRINT_ERRORS "Lib prints errors to stderr" ON)
  30 #MARK_AS_ADVANCED(FREEGLUT_PRINT_ERRORS)
  31 OPTION(FREEGLUT_PRINT_WARNINGS "Lib prints warnings to stderr" ON)
  32 #MARK_AS_ADVANCED(FREEGLUT_PRINT_WARNINGS)
  33
  34 # option to also copy .pdb files to install directory when executing
  35 # INSTALL target
  36 IF(MSVC)
  37     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  38 ELSE()
  39     SET(INSTALL_PDB OFF)
  40 ENDIF()
  41
  42 # OpenGL ES support
  43 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  44 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  45
  46
  47
  48 SET(FREEGLUT_HEADERS
  49     include/GL/freeglut.h
  50     include/GL/freeglut_ext.h
  51     include/GL/freeglut_std.h
  52     include/GL/glut.h
  53 )
  54 SET(FREEGLUT_SRCS
  55     ${FREEGLUT_HEADERS}
  56     src/fg_callbacks.c
  57     src/fg_cursor.c
  58     src/fg_display.c
  59     src/fg_ext.c
  60     src/fg_font_data.c
  61     src/fg_gamemode.c
  62     src/fg_geometry.c
  63     src/fg_gl2.c
  64     src/fg_gl2.h
  65     src/fg_init.c
  66     src/fg_init.h
  67     src/fg_internal.h
  68     src/fg_input_devices.c
  69     src/fg_joystick.c
  70     src/fg_main.c
  71     src/fg_misc.c
  72     src/fg_overlay.c
  73     src/fg_spaceball.c
  74     src/fg_state.c
  75     src/fg_stroke_mono_roman.c
  76     src/fg_stroke_roman.c
  77     src/fg_structure.c
  78     src/fg_teapot.c
  79     src/fg_teapot_data.h
  80     src/fg_videoresize.c
  81     src/fg_window.c
  82 )
  83 # TODO: OpenGL ES requires a compatible version of these files:
  84 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  85     LIST(APPEND FREEGLUT_SRCS
  86         src/fg_font.c
  87         src/fg_menu.c
  88     )
  89 ELSE()
  90     LIST(APPEND FREEGLUT_SRCS
  91         src/gles_stubs.c
  92     )
  93 ENDIF()
  94
  95 IF(WIN32)
  96     LIST(APPEND FREEGLUT_SRCS
  97         src/mswin/fg_cursor_mswin.c
  98         src/mswin/fg_display_mswin.c
  99         src/mswin/fg_ext_mswin.c
 100         src/mswin/fg_gamemode_mswin.c
 101         src/mswin/fg_init_mswin.c
 102         src/mswin/fg_internal_mswin.h
 103         src/mswin/fg_input_devices_mswin.c
 104         src/mswin/fg_joystick_mswin.c
 105         src/mswin/fg_main_mswin.c
 106         src/mswin/fg_menu_mswin.c
 107         src/mswin/fg_spaceball_mswin.c
 108         src/mswin/fg_state_mswin.c
 109         src/mswin/fg_structure_mswin.c
 110         src/mswin/fg_window_mswin.c
 111         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 112     )
 113     IF (MSVC AND NOT CMAKE_CL_64)
 114         # .def file only for 32bit Windows builds (TODO: MSVC only right
 115         # now, needed for any other Windows platform?)
 116         LIST(APPEND FREEGLUT_SRCS
 117             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 118         )
 119     ENDIF()
 120
 121 ELSEIF(ANDROID OR BLACKBERRY)
 122     LIST(APPEND FREEGLUT_SRCS
 123         src/android/fg_cursor_android.c
 124         src/android/fg_ext_android.c
 125         src/android/fg_gamemode_android.c
 126         src/android/fg_input_devices_android.c
 127         src/android/fg_joystick_android.c
 128         src/android/fg_spaceball_android.c
 129         src/android/fg_structure_android.c
 130     )
 131     IF(ANDROID)
 132         LIST(APPEND FREEGLUT_SRCS
 133             src/android/native_app_glue/android_native_app_glue.c
 134             src/android/native_app_glue/android_native_app_glue.h
 135             src/android/fg_init_android.c
 136             src/android/fg_internal_android.h
 137             src/android/fg_main_android.c
 138             src/android/fg_main_android.h
 139             src/android/fg_runtime_android.c
 140             src/android/fg_state_android.c
 141             src/android/fg_window_android.c
 142         )
 143     ELSE()
 144         LIST(APPEND FREEGLUT_SRCS
 145             # TODO: Anything similar to Android's app_glue?
 146             src/blackberry/fg_init_blackberry.c
 147             src/blackberry/fg_internal_blackberry.h
 148             # TODO: src/blackberry/fg_main_blackberry.c
 149             src/blackberry/fg_main_blackberry.h
 150             # TODO: Anything similar to fg_spaceball_android.c needed?
 151             src/blackberry/fg_state_blackberry.c
 152             src/blackberry/fg_window_blackberry.c
 153         )
 154     ENDIF()
 155 ELSE()
 156     LIST(APPEND FREEGLUT_SRCS
 157         src/x11/fg_cursor_x11.c
 158         src/x11/fg_ext_x11.c
 159         src/x11/fg_gamemode_x11.c
 160         src/x11/fg_glutfont_definitions_x11.c
 161         src/x11/fg_init_x11.c
 162         src/x11/fg_internal_x11.h
 163         src/x11/fg_input_devices_x11.c
 164         src/x11/fg_joystick_x11.c
 165         src/x11/fg_main_x11.c
 166         src/x11/fg_menu_x11.c
 167         src/x11/fg_spaceball_x11.c
 168         src/x11/fg_state_x11.c
 169         src/x11/fg_structure_x11.c
 170         src/x11/fg_window_x11.c
 171         src/x11/fg_xinput_x11.c
 172     )
 173     IF(NOT(FREEGLUT_GLES2 OR FREEGLUT_GLES1))
 174         LIST(APPEND FREEGLUT_SRCS
 175             src/x11/fg_internal_x11_glx.h
 176             src/x11/fg_display_x11_glx.c
 177             src/x11/fg_state_x11_glx.c
 178             src/x11/fg_state_x11_glx.h
 179             src/x11/fg_window_x11_glx.c
 180             src/x11/fg_window_x11_glx.h
 181         )
 182     ENDIF()
 183 ENDIF()
 184 IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 185     LIST(APPEND FREEGLUT_SRCS
 186         src/egl/fg_internal_egl.h
 187         src/egl/fg_display_egl.c
 188         src/egl/fg_ext_egl.c
 189         src/egl/fg_init_egl.c
 190         src/egl/fg_init_egl.h
 191         src/egl/fg_state_egl.c
 192         src/egl/fg_state_egl.h
 193         src/egl/fg_structure_egl.c
 194         src/egl/fg_structure_egl.h
 195         src/egl/fg_window_egl.c
 196         src/egl/fg_window_egl.h
 197     )
 198 ENDIF()
 199
 200 # For OpenGL ES (GLES):
 201 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 202 #   bootstrap headers inclusion in freeglut_std.h; these constants
 203 #   also need to be defined in client applications (e.g. through
 204 #   pkg-config), but use GLES constants directly for all other needs
 205 # - define GLES version-specific library
 206 IF(FREEGLUT_GLES2)
 207   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 208   LIST(APPEND LIBS GLESv2 EGL)
 209 ELSEIF(FREEGLUT_GLES1)
 210   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 211   LIST(APPEND LIBS GLESv1_CM EGL)
 212 ELSE()
 213   FIND_PACKAGE(OpenGL REQUIRED)
 214   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 215   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 216 ENDIF()
 217
 218 # lib m for math, not needed on windows
 219 IF (NOT WIN32)
 220     # For compilation:
 221     LIST(APPEND LIBS m)
 222     # For CHECK_FUNCTION_EXISTS:
 223     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 224 ENDIF()
 225
 226 IF(WIN32)
 227     # hide insecure CRT warnings, common practice
 228     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 229     IF(MSVC)
 230         SET( CMAKE_DEBUG_POSTFIX "d" )
 231     ENDIF(MSVC)
 232
 233 ENDIF()
 234
 235 IF(CMAKE_COMPILER_IS_GNUCC)
 236   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 237   IF(NOT(ANDROID OR BLACKBERRY))
 238     # not setting -ansi as EGL/KHR headers doesn't support it
 239     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ansi")
 240   ENDIF()
 241 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 242
 243 INCLUDE(CheckIncludeFiles)
 244 IF(UNIX AND NOT(ANDROID OR BLACKBERRY))
 245     FIND_PACKAGE(X11 REQUIRED)
 246     LIST(APPEND LIBS ${X11_LIBRARIES})
 247     IF(X11_Xrandr_FOUND)
 248         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 249         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 250     ENDIF()
 251     IF(X11_xf86vmode_FOUND)
 252         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 253         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 254         IF(NOT "${X11_Xxf86vm_LIB}")
 255             SET(X11_Xxf86vm_LIB "Xxf86vm")
 256         ENDIF()
 257         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 258     ENDIF()
 259     IF(X11_Xinput_FOUND)
 260         # Needed for multi-touch:
 261         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 262         LIST(APPEND LIBS ${X11_Xinput_LIB})
 263     ENDIF()
 264 ENDIF()
 265 IF(ANDROID)
 266     # -landroid for ANativeWindow
 267     # -llog for native Android logging
 268     LIST(APPEND LIBS android log)
 269 ELSEIF(BLACKBERRY)
 270     # -lbps for event loop
 271     # -lslog2 for logging
 272     # -screen for native screen
 273     LIST(APPEND LIBS bps slog2 screen)
 274 ENDIF()
 275
 276 INCLUDE(CheckFunctionExists)
 277 INCLUDE(CheckTypeSize)
 278 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 279 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 280 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 281 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 282 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 283 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 284 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 285 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 286 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 287 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 288 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 289 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 290 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 291 IF (NOT HAVE_XPARSEGEOMETRY)
 292    LIST(APPEND FREEGLUT_SRCS
 293         src/util/xparsegeometry_repl.c
 294         src/util/xparsegeometry_repl.h)
 295    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 296 ENDIF()
 297 # decide on suitable type for internal time keeping, 64-bit if possible
 298 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 299 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 300 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 301     IF (MSVC)
 302         # Some old Microsoft VC releases don't support unsigned long
 303         # long, but all we care about is support for unsigned __int64 on
 304         # MSVC, so test for presence of that type
 305         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 306     ELSEIF()
 307         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 308     ENDIF()
 309 ENDIF()
 310
 311 # The generated config.h is placed in the project's build directory, just to
 312 # ensure that all CMake-generated files are kept away from the main source tree.
 313 # As a result, the build directory must to be added to the include path list.
 314 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 315 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 316 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 317 IF(WIN32)
 318     # we also have to generate freeglut.rc, which contains the version
 319     # number
 320     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 321     IF (MSVC AND NOT CMAKE_CL_64)
 322         # .def file only for 32bit Windows builds with Visual Studio
 323         CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 324     ENDIF()
 325 ENDIF()
 326
 327 IF(FREEGLUT_BUILD_SHARED_LIBS)
 328     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 329 ENDIF()
 330 IF(FREEGLUT_BUILD_STATIC_LIBS)
 331     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 332 ENDIF()
 333
 334
 335 IF(WIN32)
 336     LIST(APPEND LIBS winmm)
 337     IF(FREEGLUT_BUILD_SHARED_LIBS)
 338         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 339     ENDIF()
 340     IF(FREEGLUT_BUILD_STATIC_LIBS)
 341         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 342         # need to set machine:x64 for linker, at least for VC10, and
 343         # doesn't hurt for older compilers:
 344         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 345         IF (CMAKE_CL_64)
 346             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 347         ENDIF()
 348     ENDIF()
 349 ELSE()
 350     # on UNIX we need to make sure:
 351     # - all shared libraries must have a soname/version, see :
 352     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 353     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 354     #   Current: -version-info 12:0:9 -> 3.9.0
 355     #   Note: most platforms now prefer the latter major.minor.revision form
 356     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 357     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 358     #   the lack of support for current:revision:age in CMake should
 359     #   not be a problem.
 360     # - the output library should be named glut so it'll be linkable with -lglut
 361     # - the shared library should link to the dependency libraries so that the user
 362     #   won't have to link them explicitly (they shouldn't have to know that we depend
 363     #   on Xrandr or Xxf86vm)
 364     IF(FREEGLUT_GLES2)
 365       SET(LIBNAME freeglut-gles2)
 366     ELSEIF(FREEGLUT_GLES1)
 367       SET(LIBNAME freeglut-gles1)
 368     ELSE()
 369       SET(LIBNAME glut)
 370     ENDIF()
 371
 372     IF(FREEGLUT_BUILD_SHARED_LIBS)
 373       SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME ${LIBNAME})
 374     ENDIF()
 375     IF(FREEGLUT_BUILD_STATIC_LIBS)
 376       SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 377     ENDIF()
 378     IF(ANDROID)
 379         # Not in CMake toolchain file, because the toolchain
 380         # file is called several times and generally doesn't
 381         # seem to be meant for modifying CFLAGS:
 382         # '-mandroid' is not mandatory but doesn't hurt
 383         # '-O0 -gstabs+' helps the currently buggy GDB port
 384         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 385         # Not using _INIT variables, they seem to be used internally only
 386         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 387         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 388     ENDIF()
 389 ENDIF()
 390 IF(FREEGLUT_BUILD_SHARED_LIBS)
 391     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 392 ENDIF()
 393 IF(FREEGLUT_BUILD_STATIC_LIBS)
 394     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 395 ENDIF()
 396
 397 IF(FREEGLUT_BUILD_SHARED_LIBS)
 398     INSTALL(TARGETS freeglut
 399             RUNTIME DESTINATION bin
 400             LIBRARY DESTINATION lib
 401             ARCHIVE DESTINATION lib
 402     )
 403     IF(INSTALL_PDB)
 404         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Debug/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 405             DESTINATION bin
 406                         CONFIGURATIONS Debug)
 407     ENDIF()
 408 ENDIF()
 409 IF(FREEGLUT_BUILD_STATIC_LIBS)
 410     INSTALL(TARGETS freeglut_static
 411             RUNTIME DESTINATION bin
 412             LIBRARY DESTINATION lib
 413             ARCHIVE DESTINATION lib
 414     )
 415     IF(INSTALL_PDB)
 416         INSTALL(FILES ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/Debug/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 417             DESTINATION lib
 418                         CONFIGURATIONS Debug)
 419     ENDIF()
 420 ENDIF()
 421 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 422
 423
 424
 425 # Optionally build demos, on by default.
 426 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 427
 428 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 429 # lib m for math, not needed on windows
 430 IF (NOT WIN32)
 431     LIST(APPEND DEMO_LIBS m)
 432 ENDIF()
 433
 434 MACRO(ADD_DEMO name)
 435     IF( FREEGLUT_BUILD_DEMOS )
 436         IF(FREEGLUT_BUILD_SHARED_LIBS)
 437             ADD_EXECUTABLE(${name} ${ARGN})
 438             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 439             IF(WIN32 AND MSVC)
 440                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 441             ENDIF()
 442         ENDIF()
 443         IF(FREEGLUT_BUILD_STATIC_LIBS)
 444             ADD_EXECUTABLE(${name}_static ${ARGN})
 445             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 446             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 447             IF(WIN32 AND MSVC)
 448                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 449             ENDIF()
 450         ENDIF()
 451     ENDIF()
 452 ENDMACRO()
 453
 454 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 455 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 456 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 457 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 458 IF (NOT WIN32)
 459     ADD_DEMO(One             progs/demos/One/one.c)
 460 ELSE()
 461     ADD_DEMO(One             progs/demos/One/one.c
 462                              progs/demos/One/one.rc)
 463 ENDIF()
 464 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 465 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 466 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 467                          progs/demos/shapes/glmatrix.h
 468                          progs/demos/shapes/glmatrix.c)
 469 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 470 IF(UNIX)
 471     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 472                              progs/demos/spaceball/vmath.c
 473                              progs/demos/spaceball/vmath.h)
 474 ENDIF()
 475 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 476 ADD_DEMO(timer           progs/demos/timer/timer.c)
 477
 478
 479
 480 # pkg-config support, to install at $(libdir)/pkgconfig
 481 # Define static build dependencies
 482 IF(WIN32)
 483   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 484 ELSEIF(FREEGLUT_GLES2)
 485   IF(ANDROID)
 486     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 487   ELSEIF(BLACKBERRY)
 488     SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lscreen -lGLESv2 -lEGL -lm")
 489   ELSE()
 490     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 491   ENDIF()
 492 ELSEIF(FREEGLUT_GLES1)
 493   IF(ANDROID)
 494     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 495   ELSEIF(BLACKBERRY)
 496     SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lscreen -lGLESv1_CM -lEGL -lm")
 497   ELSE()
 498     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 499   ENDIF()
 500 ELSE()
 501   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 502 ENDIF()
 503 # Client applications need to define FreeGLUT GLES version to
 504 # bootstrap headers inclusion in freeglut_std.h:
 505 SET(PC_LIBNAME "glut")
 506 SET(PC_FILENAME "freeglut.pc")
 507 IF(FREEGLUT_GLES2)
 508   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 509   SET(PC_LIBNAME "freeglut-gles2")
 510   SET(PC_FILENAME "freeglut-gles2.pc")
 511 ELSEIF(FREEGLUT_GLES1)
 512   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 513   SET(PC_LIBNAME "freeglut-gles1")
 514   SET(PC_FILENAME "freeglut-gles1.pc")
 515 ENDIF()
 516 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 517 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 518 # TODO: change the library and .pc name when building for GLES,
 519 # e.g. -lglut-GLES2