git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8 FATAL_ERROR)
   2 PROJECT(freeglut)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms.
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  14
  15 # setup version numbers
  16 # TODO: Update these for each release!
  17 set(VERSION_MAJOR 3)
  18 set(VERSION_MINOR 0)
  19 set(VERSION_PATCH 0)
  20
  21
  22 # FREEGLUT_BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  23 # re-declare it here so it will show up in the GUI.
  24 # by default, we want to build both
  25 OPTION(FREEGLUT_BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  26 OPTION(FREEGLUT_BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  27
  28 # option for whether warnings and errors should be printed
  29 OPTION(FREEGLUT_PRINT_ERRORS "Lib prints errors to stderr" ON)
  30 #MARK_AS_ADVANCED(FREEGLUT_PRINT_ERRORS)
  31 OPTION(FREEGLUT_PRINT_WARNINGS "Lib prints warnings to stderr" ON)
  32 #MARK_AS_ADVANCED(FREEGLUT_PRINT_WARNINGS)
  33
  34 # option to also copy .pdb files to install directory when executing
  35 # INSTALL target
  36 IF(MSVC)
  37     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  38 ELSE()
  39     SET(INSTALL_PDB OFF)
  40 ENDIF()
  41
  42 # OpenGL ES support
  43 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  44 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  45
  46
  47
  48 SET(FREEGLUT_HEADERS
  49     include/GL/freeglut.h
  50     include/GL/freeglut_ext.h
  51     include/GL/freeglut_std.h
  52     include/GL/glut.h
  53 )
  54 SET(FREEGLUT_SRCS
  55     ${FREEGLUT_HEADERS}
  56     src/fg_callbacks.c
  57     src/fg_cursor.c
  58     src/fg_display.c
  59     src/fg_ext.c
  60     src/fg_font_data.c
  61     src/fg_gamemode.c
  62     src/fg_geometry.c
  63     src/fg_gl2.c
  64     src/fg_gl2.h
  65     src/fg_init.c
  66     src/fg_init.h
  67     src/fg_internal.h
  68     src/fg_input_devices.c
  69     src/fg_joystick.c
  70     src/fg_main.c
  71     src/fg_misc.c
  72     src/fg_overlay.c
  73     src/fg_spaceball.c
  74     src/fg_state.c
  75     src/fg_stroke_mono_roman.c
  76     src/fg_stroke_roman.c
  77     src/fg_structure.c
  78     src/fg_teapot.c
  79     src/fg_teapot_data.h
  80     src/fg_videoresize.c
  81     src/fg_window.c
  82 )
  83 # TODO: OpenGL ES requires a compatible version of these files:
  84 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  85     LIST(APPEND FREEGLUT_SRCS
  86         src/fg_font.c
  87         src/fg_menu.c
  88     )
  89 ELSE()
  90     LIST(APPEND FREEGLUT_SRCS
  91         src/gles_stubs.c
  92     )
  93 ENDIF()
  94
  95 IF(WIN32)
  96     LIST(APPEND FREEGLUT_SRCS
  97         src/mswin/fg_cursor_mswin.c
  98         src/mswin/fg_display_mswin.c
  99         src/mswin/fg_ext_mswin.c
 100         src/mswin/fg_gamemode_mswin.c
 101         src/mswin/fg_init_mswin.c
 102         src/mswin/fg_internal_mswin.h
 103         src/mswin/fg_input_devices_mswin.c
 104         src/mswin/fg_joystick_mswin.c
 105         src/mswin/fg_main_mswin.c
 106         src/mswin/fg_menu_mswin.c
 107         src/mswin/fg_spaceball_mswin.c
 108         src/mswin/fg_state_mswin.c
 109         src/mswin/fg_structure_mswin.c
 110         src/mswin/fg_window_mswin.c
 111         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 112     )
 113     IF (MSVC AND NOT CMAKE_CL_64)
 114         # .def file only for 32bit Windows builds (TODO: MSVC only right
 115         # now, needed for any other Windows platform?)
 116         LIST(APPEND FREEGLUT_SRCS
 117             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 118         )
 119     ENDIF()
 120
 121 ELSEIF(ANDROID OR BLACKBERRY)
 122     # BlackBerry and Android share some similar design concepts and ideas, as with many mobile devices.
 123     # As such, some classes can be shared between the two. XXX: Possibly rename shareable classes to
 124     # a more generic name. *_stub? *_mobile?
 125     LIST(APPEND FREEGLUT_SRCS
 126         src/android/fg_cursor_android.c
 127         src/android/fg_ext_android.c
 128         src/android/fg_gamemode_android.c
 129         src/android/fg_joystick_android.c
 130         src/android/fg_spaceball_android.c
 131         src/android/fg_structure_android.c
 132     )
 133     IF(ANDROID)
 134         LIST(APPEND FREEGLUT_SRCS
 135             src/android/native_app_glue/android_native_app_glue.c
 136             src/android/native_app_glue/android_native_app_glue.h
 137             src/android/fg_internal_android.h
 138             src/android/fg_init_android.c
 139             src/android/fg_input_devices_android.c
 140             src/android/fg_main_android.c
 141             src/android/fg_main_android.h
 142             src/android/fg_runtime_android.c
 143             src/android/fg_state_android.c
 144             src/android/fg_window_android.c
 145         )
 146     ELSE()
 147         LIST(APPEND FREEGLUT_SRCS
 148             src/blackberry/fg_internal_blackberry.h
 149             src/blackberry/fg_init_blackberry.c
 150             src/x11/fg_input_devices_x11.c
 151             src/blackberry/fg_main_blackberry.c
 152             src/blackberry/fg_state_blackberry.c
 153             src/blackberry/fg_window_blackberry.c
 154         )
 155     ENDIF()
 156 ELSE()
 157     LIST(APPEND FREEGLUT_SRCS
 158         src/x11/fg_cursor_x11.c
 159         src/x11/fg_ext_x11.c
 160         src/x11/fg_gamemode_x11.c
 161         src/x11/fg_glutfont_definitions_x11.c
 162         src/x11/fg_init_x11.c
 163         src/x11/fg_internal_x11.h
 164         src/x11/fg_input_devices_x11.c
 165         src/x11/fg_joystick_x11.c
 166         src/x11/fg_main_x11.c
 167         src/x11/fg_menu_x11.c
 168         src/x11/fg_spaceball_x11.c
 169         src/x11/fg_state_x11.c
 170         src/x11/fg_structure_x11.c
 171         src/x11/fg_window_x11.c
 172         src/x11/fg_xinput_x11.c
 173     )
 174     IF(NOT(FREEGLUT_GLES2 OR FREEGLUT_GLES1))
 175         LIST(APPEND FREEGLUT_SRCS
 176             src/x11/fg_internal_x11_glx.h
 177             src/x11/fg_display_x11_glx.c
 178             src/x11/fg_state_x11_glx.c
 179             src/x11/fg_state_x11_glx.h
 180             src/x11/fg_window_x11_glx.c
 181             src/x11/fg_window_x11_glx.h
 182         )
 183     ENDIF()
 184 ENDIF()
 185 IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 186     LIST(APPEND FREEGLUT_SRCS
 187         src/egl/fg_internal_egl.h
 188         src/egl/fg_display_egl.c
 189         src/egl/fg_ext_egl.c
 190         src/egl/fg_init_egl.c
 191         src/egl/fg_init_egl.h
 192         src/egl/fg_state_egl.c
 193         src/egl/fg_state_egl.h
 194         src/egl/fg_structure_egl.c
 195         src/egl/fg_structure_egl.h
 196         src/egl/fg_window_egl.c
 197         src/egl/fg_window_egl.h
 198     )
 199 ENDIF()
 200
 201 # For OpenGL ES (GLES):
 202 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 203 #   bootstrap headers inclusion in freeglut_std.h; these constants
 204 #   also need to be defined in client applications (e.g. through
 205 #   pkg-config), but use GLES constants directly for all other needs
 206 # - define GLES version-specific library
 207 IF(FREEGLUT_GLES2)
 208   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 209   LIST(APPEND LIBS GLESv2 EGL)
 210 ELSEIF(FREEGLUT_GLES1)
 211   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 212   LIST(APPEND LIBS GLESv1_CM EGL)
 213 ELSE()
 214   FIND_PACKAGE(OpenGL REQUIRED)
 215   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 216   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 217 ENDIF()
 218
 219 # lib m for math, not needed on windows
 220 IF (NOT WIN32)
 221     # For compilation:
 222     LIST(APPEND LIBS m)
 223     # For CHECK_FUNCTION_EXISTS:
 224     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 225 ENDIF()
 226
 227 IF(WIN32)
 228     # hide insecure CRT warnings, common practice
 229     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 230     IF(MSVC)
 231         SET( CMAKE_DEBUG_POSTFIX "d" )
 232     ENDIF(MSVC)
 233
 234 ENDIF()
 235
 236 IF(CMAKE_COMPILER_IS_GNUCC)
 237   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 238   IF(NOT(ANDROID OR BLACKBERRY))
 239     # not setting -ansi as EGL/KHR headers doesn't support it
 240     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ansi")
 241   ENDIF()
 242 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 243
 244 INCLUDE(CheckIncludeFiles)
 245 IF(UNIX AND NOT(ANDROID OR BLACKBERRY))
 246     FIND_PACKAGE(X11 REQUIRED)
 247     LIST(APPEND LIBS ${X11_LIBRARIES})
 248     IF(X11_Xrandr_FOUND)
 249         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 250         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 251     ENDIF()
 252     IF(X11_xf86vmode_FOUND)
 253         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 254         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 255         IF(NOT "${X11_Xxf86vm_LIB}")
 256             SET(X11_Xxf86vm_LIB "Xxf86vm")
 257         ENDIF()
 258         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 259     ENDIF()
 260     IF(X11_Xinput_FOUND)
 261         # Needed for multi-touch:
 262         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 263         LIST(APPEND LIBS ${X11_Xinput_LIB})
 264     ENDIF()
 265 ENDIF()
 266 IF(ANDROID)
 267     # -landroid for ANativeWindow
 268     # -llog for native Android logging
 269     LIST(APPEND LIBS android log)
 270 ELSEIF(BLACKBERRY)
 271     # -lbps for event loop
 272     # -lslog2 for logging
 273     # -screen for native screen
 274     LIST(APPEND LIBS bps slog2 screen)
 275 ENDIF()
 276
 277 INCLUDE(CheckFunctionExists)
 278 INCLUDE(CheckTypeSize)
 279 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 280 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 281 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 282 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 283 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 284 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 285 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 286 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 287 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 288 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 289 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 290 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 291 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 292 IF (NOT HAVE_XPARSEGEOMETRY)
 293    LIST(APPEND FREEGLUT_SRCS
 294         src/util/xparsegeometry_repl.c
 295         src/util/xparsegeometry_repl.h)
 296    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 297 ENDIF()
 298 # decide on suitable type for internal time keeping, 64-bit if possible
 299 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 300 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 301 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 302     IF (MSVC)
 303         # Some old Microsoft VC releases don't support unsigned long
 304         # long, but all we care about is support for unsigned __int64 on
 305         # MSVC, so test for presence of that type
 306         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 307     ELSEIF()
 308         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 309     ENDIF()
 310 ENDIF()
 311
 312 # The generated config.h is placed in the project's build directory, just to
 313 # ensure that all CMake-generated files are kept away from the main source tree.
 314 # As a result, the build directory must to be added to the include path list.
 315 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 316 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 317 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 318 IF(WIN32)
 319     # we also have to generate freeglut.rc, which contains the version
 320     # number
 321     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 322     IF (MSVC AND NOT CMAKE_CL_64)
 323         # .def file only for 32bit Windows builds with Visual Studio
 324         CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 325     ENDIF()
 326 ENDIF()
 327
 328 IF(FREEGLUT_BUILD_SHARED_LIBS)
 329     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 330 ENDIF()
 331 IF(FREEGLUT_BUILD_STATIC_LIBS)
 332     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 333 ENDIF()
 334
 335
 336 IF(WIN32)
 337     LIST(APPEND LIBS winmm)
 338     IF(FREEGLUT_BUILD_SHARED_LIBS)
 339         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 340     ENDIF()
 341     IF(FREEGLUT_BUILD_STATIC_LIBS)
 342         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 343         # need to set machine:x64 for linker, at least for VC10, and
 344         # doesn't hurt for older compilers:
 345         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 346         IF (CMAKE_CL_64)
 347             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 348         ENDIF()
 349     ENDIF()
 350 ELSE()
 351     # on UNIX we need to make sure:
 352     # - all shared libraries must have a soname/version, see :
 353     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 354     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 355     #   Current: -version-info 12:0:9 -> 3.9.0
 356     #   Note: most platforms now prefer the latter major.minor.revision form
 357     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 358     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 359     #   the lack of support for current:revision:age in CMake should
 360     #   not be a problem.
 361     # - the output library should be named glut so it'll be linkable with -lglut
 362     # - the shared library should link to the dependency libraries so that the user
 363     #   won't have to link them explicitly (they shouldn't have to know that we depend
 364     #   on Xrandr or Xxf86vm)
 365     IF(FREEGLUT_GLES2)
 366       SET(LIBNAME freeglut-gles2)
 367     ELSEIF(FREEGLUT_GLES1)
 368       SET(LIBNAME freeglut-gles1)
 369     ELSE()
 370       SET(LIBNAME glut)
 371     ENDIF()
 372
 373     IF(FREEGLUT_BUILD_SHARED_LIBS)
 374       SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME ${LIBNAME})
 375     ENDIF()
 376     IF(FREEGLUT_BUILD_STATIC_LIBS)
 377       SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 378     ENDIF()
 379     IF(ANDROID)
 380         # Not in CMake toolchain file, because the toolchain
 381         # file is called several times and generally doesn't
 382         # seem to be meant for modifying CFLAGS:
 383         # '-mandroid' is not mandatory but doesn't hurt
 384         # '-O0 -gstabs+' helps the currently buggy GDB port
 385         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 386         # Not using _INIT variables, they seem to be used internally only
 387         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 388         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 389     ENDIF()
 390 ENDIF()
 391 IF(FREEGLUT_BUILD_SHARED_LIBS)
 392     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 393 ENDIF()
 394 IF(FREEGLUT_BUILD_STATIC_LIBS)
 395     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 396 ENDIF()
 397
 398 IF(FREEGLUT_BUILD_SHARED_LIBS)
 399     INSTALL(TARGETS freeglut
 400             RUNTIME DESTINATION bin
 401             LIBRARY DESTINATION lib
 402             ARCHIVE DESTINATION lib
 403     )
 404     IF(INSTALL_PDB)
 405         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Debug/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 406             DESTINATION bin
 407                         CONFIGURATIONS Debug)
 408     ENDIF()
 409 ENDIF()
 410 IF(FREEGLUT_BUILD_STATIC_LIBS)
 411     INSTALL(TARGETS freeglut_static
 412             RUNTIME DESTINATION bin
 413             LIBRARY DESTINATION lib
 414             ARCHIVE DESTINATION lib
 415     )
 416     IF(INSTALL_PDB)
 417         INSTALL(FILES ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/Debug/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 418             DESTINATION lib
 419                         CONFIGURATIONS Debug)
 420     ENDIF()
 421 ENDIF()
 422 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 423
 424
 425
 426 # Optionally build demos, on by default.
 427 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 428
 429 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 430 # lib m for math, not needed on windows
 431 IF (NOT WIN32)
 432     LIST(APPEND DEMO_LIBS m)
 433 ENDIF()
 434
 435 MACRO(ADD_DEMO name)
 436     IF( FREEGLUT_BUILD_DEMOS )
 437         IF(FREEGLUT_BUILD_SHARED_LIBS)
 438             ADD_EXECUTABLE(${name} ${ARGN})
 439             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 440             IF(WIN32 AND MSVC)
 441                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 442             ENDIF()
 443         ENDIF()
 444         IF(FREEGLUT_BUILD_STATIC_LIBS)
 445             ADD_EXECUTABLE(${name}_static ${ARGN})
 446             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 447             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 448             IF(WIN32 AND MSVC)
 449                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 450             ENDIF()
 451         ENDIF()
 452     ENDIF()
 453 ENDMACRO()
 454
 455 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 456 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 457 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 458 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 459 IF (NOT WIN32)
 460     ADD_DEMO(One             progs/demos/One/one.c)
 461 ELSE()
 462     ADD_DEMO(One             progs/demos/One/one.c
 463                              progs/demos/One/one.rc)
 464 ENDIF()
 465 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 466 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 467 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 468                          progs/demos/shapes/glmatrix.h
 469                          progs/demos/shapes/glmatrix.c)
 470 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 471 IF(UNIX)
 472     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 473                              progs/demos/spaceball/vmath.c
 474                              progs/demos/spaceball/vmath.h)
 475 ENDIF()
 476 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 477 ADD_DEMO(timer           progs/demos/timer/timer.c)
 478
 479
 480
 481 # pkg-config support, to install at $(libdir)/pkgconfig
 482 # Define static build dependencies
 483 IF(WIN32)
 484   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 485 ELSEIF(FREEGLUT_GLES2)
 486   IF(ANDROID)
 487     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 488   ELSEIF(BLACKBERRY)
 489     SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lscreen -lGLESv2 -lEGL -lm")
 490   ELSE()
 491     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 492   ENDIF()
 493 ELSEIF(FREEGLUT_GLES1)
 494   IF(ANDROID)
 495     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 496   ELSEIF(BLACKBERRY)
 497     SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lscreen -lGLESv1_CM -lEGL -lm")
 498   ELSE()
 499     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 500   ENDIF()
 501 ELSE()
 502   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 503 ENDIF()
 504 # Client applications need to define FreeGLUT GLES version to
 505 # bootstrap headers inclusion in freeglut_std.h:
 506 SET(PC_LIBNAME "glut")
 507 SET(PC_FILENAME "freeglut.pc")
 508 IF(FREEGLUT_GLES2)
 509   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 510   SET(PC_LIBNAME "freeglut-gles2")
 511   SET(PC_FILENAME "freeglut-gles2.pc")
 512 ELSEIF(FREEGLUT_GLES1)
 513   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 514   SET(PC_LIBNAME "freeglut-gles1")
 515   SET(PC_FILENAME "freeglut-gles1.pc")
 516 ENDIF()
 517 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 518 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 519 # TODO: change the library and .pc name when building for GLES,
 520 # e.g. -lglut-GLES2