git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8 FATAL_ERROR)
   2 PROJECT(freeglut)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms.
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  14
  15 # setup version numbers
  16 # TODO: Update these for each release!
  17 set(VERSION_MAJOR 3)
  18 set(VERSION_MINOR 0)
  19 set(VERSION_PATCH 0)
  20
  21 # Update fg_version.h to match the versions number here in cmake
  22 CONFIGURE_FILE(src/fg_version.h.in src/fg_version.h)
  23
  24 # shared lib version numbers (change before release)
  25 set(SO_MAJOR 3)         # increment on backwards incompatible API/ABI changes
  26 set(SO_MINOR 10)        # increment on backwards compatible or internal changes
  27 set(SO_REV 0)           # if nothing else changed increment this
  28
  29 # FREEGLUT_BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  30 # re-declare it here so it will show up in the GUI.
  31 # by default, we want to build both
  32 OPTION(FREEGLUT_BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  33 OPTION(FREEGLUT_BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  34
  35 # option for whether warnings and errors should be printed
  36 OPTION(FREEGLUT_PRINT_ERRORS "Lib prints errors to stderr" ON)
  37 #MARK_AS_ADVANCED(FREEGLUT_PRINT_ERRORS)
  38 OPTION(FREEGLUT_PRINT_WARNINGS "Lib prints warnings to stderr" ON)
  39 #MARK_AS_ADVANCED(FREEGLUT_PRINT_WARNINGS)
  40
  41 # option to also copy .pdb files to install directory when executing
  42 # INSTALL target
  43 IF(MSVC)
  44     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  45 ELSE()
  46     SET(INSTALL_PDB OFF)
  47 ENDIF()
  48
  49 # OpenGL ES support
  50 OPTION(FREEGLUT_GLES "Use OpenGL ES (requires EGL)" OFF)
  51
  52 # option to build either as "glut" (ON) or "freeglut" (OFF)
  53 OPTION(FREEGLUT_REPLACE_GLUT "Be a replacement for GLUT" ON)
  54
  55
  56 SET(FREEGLUT_HEADERS
  57     include/GL/freeglut.h
  58     include/GL/freeglut_ext.h
  59     include/GL/freeglut_std.h
  60     include/GL/glut.h
  61 )
  62 SET(FREEGLUT_SRCS
  63     ${FREEGLUT_HEADERS}
  64     src/fg_callbacks.c
  65     src/fg_cursor.c
  66     src/fg_display.c
  67     src/fg_ext.c
  68     src/fg_font_data.c
  69     src/fg_gamemode.c
  70     src/fg_geometry.c
  71     src/fg_gl2.c
  72     src/fg_gl2.h
  73     src/fg_init.c
  74     src/fg_init.h
  75     src/fg_internal.h
  76     src/fg_input_devices.c
  77     src/fg_joystick.c
  78     src/fg_main.c
  79     src/fg_misc.c
  80     src/fg_overlay.c
  81     src/fg_spaceball.c
  82     src/fg_state.c
  83     src/fg_stroke_mono_roman.c
  84     src/fg_stroke_roman.c
  85     src/fg_structure.c
  86     src/fg_teapot.c
  87     src/fg_teapot_data.h
  88     src/fg_videoresize.c
  89     src/fg_window.c
  90 )
  91 # TODO: OpenGL ES requires a compatible version of these files:
  92 IF(NOT FREEGLUT_GLES)
  93     LIST(APPEND FREEGLUT_SRCS
  94         src/fg_font.c
  95         src/fg_menu.c
  96     )
  97 ELSE()
  98     LIST(APPEND FREEGLUT_SRCS
  99         src/gles_stubs.c
 100     )
 101 ENDIF()
 102
 103 IF(WIN32)
 104     LIST(APPEND FREEGLUT_SRCS
 105         src/mswin/fg_cursor_mswin.c
 106         src/mswin/fg_display_mswin.c
 107         src/mswin/fg_ext_mswin.c
 108         src/mswin/fg_gamemode_mswin.c
 109         src/mswin/fg_init_mswin.c
 110         src/mswin/fg_internal_mswin.h
 111         src/mswin/fg_input_devices_mswin.c
 112         src/mswin/fg_joystick_mswin.c
 113         src/mswin/fg_main_mswin.c
 114         src/mswin/fg_menu_mswin.c
 115         src/mswin/fg_spaceball_mswin.c
 116         src/mswin/fg_state_mswin.c
 117         src/mswin/fg_structure_mswin.c
 118         src/mswin/fg_window_mswin.c
 119         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 120     )
 121     IF (MSVC AND NOT CMAKE_CL_64)
 122         # .def file only for 32bit Windows builds (TODO: MSVC only right
 123         # now, needed for any other Windows platform?)
 124         LIST(APPEND FREEGLUT_SRCS
 125             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 126         )
 127     ENDIF()
 128
 129 ELSEIF(ANDROID OR BLACKBERRY)
 130     # BlackBerry and Android share some similar design concepts and ideas, as with many mobile devices.
 131     # As such, some classes can be shared between the two. XXX: Possibly rename shareable classes to
 132     # a more generic name. *_stub? *_mobile?
 133     LIST(APPEND FREEGLUT_SRCS
 134         src/android/fg_cursor_android.c
 135         src/android/fg_ext_android.c
 136         src/android/fg_gamemode_android.c
 137         src/android/fg_joystick_android.c
 138         src/android/fg_spaceball_android.c
 139     )
 140     IF(ANDROID)
 141         LIST(APPEND FREEGLUT_SRCS
 142             src/android/native_app_glue/android_native_app_glue.c
 143             src/android/native_app_glue/android_native_app_glue.h
 144             src/android/fg_internal_android.h
 145             src/android/fg_init_android.c
 146             src/android/fg_input_devices_android.c
 147             src/android/fg_main_android.c
 148             src/android/fg_main_android.h
 149             src/android/fg_runtime_android.c
 150             src/android/fg_state_android.c
 151             src/android/fg_structure_android.c
 152             src/android/fg_window_android.c
 153         )
 154     ELSE()
 155         LIST(APPEND FREEGLUT_SRCS
 156             src/blackberry/fg_internal_blackberry.h
 157             src/blackberry/fg_init_blackberry.c
 158             src/x11/fg_input_devices_x11.c
 159             src/blackberry/fg_main_blackberry.c
 160             src/blackberry/fg_state_blackberry.c
 161             src/blackberry/fg_structure_blackberry.c
 162             src/blackberry/fg_window_blackberry.c
 163         )
 164     ENDIF()
 165 ELSE()
 166     LIST(APPEND FREEGLUT_SRCS
 167         src/x11/fg_cursor_x11.c
 168         src/x11/fg_ext_x11.c
 169         src/x11/fg_gamemode_x11.c
 170         src/x11/fg_glutfont_definitions_x11.c
 171         src/x11/fg_init_x11.c
 172         src/x11/fg_internal_x11.h
 173         src/x11/fg_input_devices_x11.c
 174         src/x11/fg_joystick_x11.c
 175         src/x11/fg_main_x11.c
 176         src/x11/fg_menu_x11.c
 177         src/x11/fg_spaceball_x11.c
 178         src/x11/fg_state_x11.c
 179         src/x11/fg_structure_x11.c
 180         src/x11/fg_window_x11.c
 181         src/x11/fg_xinput_x11.c
 182     )
 183     IF(NOT(FREEGLUT_GLES))
 184         LIST(APPEND FREEGLUT_SRCS
 185             src/x11/fg_internal_x11_glx.h
 186             src/x11/fg_display_x11_glx.c
 187             src/x11/fg_state_x11_glx.c
 188             src/x11/fg_state_x11_glx.h
 189             src/x11/fg_window_x11_glx.c
 190             src/x11/fg_window_x11_glx.h
 191         )
 192     ENDIF()
 193 ENDIF()
 194 IF(FREEGLUT_GLES)
 195     LIST(APPEND FREEGLUT_SRCS
 196         src/egl/fg_internal_egl.h
 197         src/egl/fg_display_egl.c
 198         src/egl/fg_ext_egl.c
 199         src/egl/fg_init_egl.c
 200         src/egl/fg_init_egl.h
 201         src/egl/fg_state_egl.c
 202         src/egl/fg_state_egl.h
 203         src/egl/fg_structure_egl.c
 204         src/egl/fg_structure_egl.h
 205         src/egl/fg_window_egl.c
 206         src/egl/fg_window_egl.h
 207     )
 208 ENDIF()
 209
 210 # For OpenGL ES (GLES): compile with -DFREEGLUT_GLES to cleanly
 211 # bootstrap headers inclusion in freeglut_std.h; this constant also
 212 # need to be defined in client applications (e.g. through pkg-config),
 213 # but do use GLES constants directly for all other needs
 214 # GLES1 and GLES2 libraries are compatible and can be co-linked.
 215 IF(FREEGLUT_GLES)
 216   ADD_DEFINITIONS(-DFREEGLUT_GLES)
 217   LIST(APPEND LIBS GLESv2 GLESv1_CM EGL)
 218 ELSE()
 219   FIND_PACKAGE(OpenGL REQUIRED)
 220   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 221   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 222 ENDIF()
 223
 224 # lib m for math, not needed on windows
 225 IF (NOT WIN32)
 226     # For compilation:
 227     LIST(APPEND LIBS m)
 228     # For CHECK_FUNCTION_EXISTS:
 229     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 230 ENDIF()
 231
 232 IF(WIN32)
 233     # hide insecure CRT warnings, common practice
 234     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 235     IF(MSVC)
 236         SET( CMAKE_DEBUG_POSTFIX "d" )
 237     ENDIF(MSVC)
 238
 239     # enable the use of Win2000 APIs (needed for really old compilers like MSVC6)
 240     ADD_DEFINITIONS(-D_WIN32_WINNT=0x0500)
 241     ADD_DEFINITIONS(-DWINVER=0x0500)
 242 ENDIF()
 243
 244 IF(CMAKE_COMPILER_IS_GNUCC)
 245   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 246   IF(NOT(ANDROID OR BLACKBERRY))
 247     # not setting -ansi as EGL/KHR headers doesn't support it
 248     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pedantic")
 249   ENDIF()
 250 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 251
 252 INCLUDE(CheckIncludeFiles)
 253 IF(UNIX AND NOT(ANDROID OR BLACKBERRY))
 254     FIND_PACKAGE(X11 REQUIRED)
 255     LIST(APPEND LIBS ${X11_LIBRARIES})
 256     IF(X11_Xrandr_FOUND)
 257         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 258         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 259     ENDIF()
 260     IF(X11_xf86vmode_FOUND)
 261         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 262         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 263         IF(NOT "${X11_Xxf86vm_LIB}")
 264             SET(X11_Xxf86vm_LIB "Xxf86vm")
 265         ENDIF()
 266         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 267     ENDIF()
 268     IF(X11_Xinput_FOUND)
 269         # Needed for multi-touch:
 270         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 271         LIST(APPEND LIBS ${X11_Xinput_LIB})
 272     ENDIF()
 273 ENDIF()
 274 IF(ANDROID)
 275     # -landroid for ANativeWindow
 276     # -llog for native Android logging
 277     LIST(APPEND LIBS android log)
 278 ELSEIF(BLACKBERRY)
 279     # -lbps for event loop
 280     # -screen for native screen
 281     LIST(APPEND LIBS bps screen)
 282
 283     if(NOT PLAYBOOK)
 284         # -lslog2 for logging
 285         # -pps for low-level screen manipulation
 286         LIST(APPEND LIBS slog2 pps)
 287     ENDIF()
 288 ENDIF()
 289
 290 INCLUDE(CheckFunctionExists)
 291 INCLUDE(CheckTypeSize)
 292 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 293 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 294 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 295 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 296 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 297 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 298 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 299 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 300 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 301 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 302 IF (NOT HAVE_XPARSEGEOMETRY)
 303    LIST(APPEND FREEGLUT_SRCS
 304         src/util/xparsegeometry_repl.c
 305         src/util/xparsegeometry_repl.h)
 306    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 307 ENDIF()
 308 # decide on suitable type for internal time keeping, 64-bit if possible
 309 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 310 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 311 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 312     IF (MSVC)
 313         # Some old Microsoft VC releases don't support unsigned long
 314         # long, but all we care about is support for unsigned __int64 on
 315         # MSVC, so test for presence of that type
 316         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 317     ELSEIF()
 318         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 319     ENDIF()
 320 ENDIF()
 321
 322 # The generated config.h is placed in the project's build directory, just to
 323 # ensure that all CMake-generated files are kept away from the main source tree.
 324 # As a result, the build directory must to be added to the include path list.
 325 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 326 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 327 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 328 IF(WIN32)
 329     # we also have to generate freeglut.rc, which contains the version
 330     # number
 331     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 332     IF (MSVC AND NOT CMAKE_CL_64)
 333         # .def file only for 32bit Windows builds with Visual Studio
 334         CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 335     ENDIF()
 336 ENDIF()
 337
 338 IF(FREEGLUT_BUILD_SHARED_LIBS)
 339     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 340 ENDIF()
 341 IF(FREEGLUT_BUILD_STATIC_LIBS)
 342     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 343 ENDIF()
 344
 345
 346 IF(WIN32)
 347     LIST(APPEND LIBS winmm)
 348     IF(FREEGLUT_BUILD_SHARED_LIBS)
 349         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 350     ENDIF()
 351     IF(FREEGLUT_BUILD_STATIC_LIBS)
 352         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 353         # need to set machine:x64 for linker, at least for VC10, and
 354         # doesn't hurt for older compilers:
 355         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 356         IF (CMAKE_CL_64)
 357             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 358         ENDIF()
 359     ENDIF()
 360 ELSE()
 361     # on UNIX we need to make sure:
 362     # - all shared libraries must have a soname/version, see :
 363     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 364     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 365     #   Current: -version-info 12:0:9 -> 3.9.0
 366     #   Note: most platforms now prefer the latter major.minor.revision form
 367     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 368     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 369     #   the lack of support for current:revision:age in CMake should
 370     #   not be a problem.
 371         # - the output library should be named glut so it'll be linkable with -lglut
 372         #   (unless FREEGLUT_REPLACE_GLUT is false).
 373     # - the shared library should link to the dependency libraries so that the user
 374     #   won't have to link them explicitly (they shouldn't have to know that we depend
 375     #   on Xrandr or Xxf86vm)
 376     IF(FREEGLUT_GLES)
 377                 SET(LIBNAME freeglut-gles)
 378     ELSE()
 379                 IF(FREEGLUT_REPLACE_GLUT)
 380                         SET(LIBNAME glut)
 381                 ELSE()
 382                         SET(LIBNAME freeglut)
 383                 ENDIF()
 384         ENDIF()
 385
 386     IF(FREEGLUT_BUILD_SHARED_LIBS)
 387       SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION ${SO_MAJOR}.${SO_MINOR}.${SO_REV} SOVERSION ${SO_MAJOR} OUTPUT_NAME ${LIBNAME})
 388     ENDIF()
 389     IF(FREEGLUT_BUILD_STATIC_LIBS)
 390       SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 391     ENDIF()
 392     IF(ANDROID)
 393         # Not in CMake toolchain file, because the toolchain
 394         # file is called several times and generally doesn't
 395         # seem to be meant for modifying CFLAGS:
 396         # '-mandroid' is not mandatory but doesn't hurt
 397         # '-O0 -gstabs+' helps the currently buggy GDB port
 398         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 399         # Not using _INIT variables, they seem to be used internally only
 400         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 401         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 402     ENDIF()
 403 ENDIF()
 404 IF(FREEGLUT_BUILD_SHARED_LIBS)
 405     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 406 ENDIF()
 407 IF(FREEGLUT_BUILD_STATIC_LIBS)
 408     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 409 ENDIF()
 410
 411 IF(FREEGLUT_BUILD_SHARED_LIBS)
 412     INSTALL(TARGETS freeglut
 413             RUNTIME DESTINATION bin
 414             LIBRARY DESTINATION lib
 415             ARCHIVE DESTINATION lib
 416     )
 417     IF(INSTALL_PDB)
 418         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Debug/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 419             DESTINATION bin
 420                         CONFIGURATIONS Debug)
 421     ENDIF()
 422 ENDIF()
 423 IF(FREEGLUT_BUILD_STATIC_LIBS)
 424     INSTALL(TARGETS freeglut_static
 425             RUNTIME DESTINATION bin
 426             LIBRARY DESTINATION lib
 427             ARCHIVE DESTINATION lib
 428     )
 429     IF(INSTALL_PDB)
 430         INSTALL(FILES ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/Debug/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 431             DESTINATION lib
 432                         CONFIGURATIONS Debug)
 433     ENDIF()
 434 ENDIF()
 435 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 436
 437
 438
 439 # Optionally build demos, on by default.
 440 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 441
 442 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 443 # lib m for math, not needed on windows
 444 IF (NOT WIN32)
 445     LIST(APPEND DEMO_LIBS m)
 446 ENDIF()
 447
 448 MACRO(ADD_DEMO name)
 449     IF( FREEGLUT_BUILD_DEMOS )
 450         IF(FREEGLUT_BUILD_SHARED_LIBS)
 451             ADD_EXECUTABLE(${name} ${ARGN})
 452             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 453             IF(WIN32 AND MSVC)
 454                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 455             ENDIF()
 456         ENDIF()
 457         IF(FREEGLUT_BUILD_STATIC_LIBS)
 458             ADD_EXECUTABLE(${name}_static ${ARGN})
 459             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 460             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 461             IF(WIN32 AND MSVC)
 462                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 463             ENDIF()
 464         ENDIF()
 465     ENDIF()
 466 ENDMACRO()
 467
 468 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 469 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 470 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 471 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 472 IF (NOT WIN32)
 473     ADD_DEMO(One             progs/demos/One/one.c)
 474 ELSE()
 475     ADD_DEMO(One             progs/demos/One/one.c
 476                              progs/demos/One/one.rc)
 477 ENDIF()
 478 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 479 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 480 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 481                          progs/demos/shapes/glmatrix.h
 482                          progs/demos/shapes/glmatrix.c)
 483 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 484 IF(UNIX)
 485     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 486                              progs/demos/spaceball/vmath.c
 487                              progs/demos/spaceball/vmath.h)
 488 ENDIF()
 489 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 490 ADD_DEMO(timer           progs/demos/timer/timer.c)
 491
 492
 493
 494 # pkg-config support, to install at $(libdir)/pkgconfig
 495 # Define static build dependencies
 496 IF(WIN32)
 497   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 498 ELSEIF(FREEGLUT_GLES)
 499   IF(ANDROID)
 500     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lGLESv1_CM -lEGL -lm")
 501   ELSEIF(BLACKBERRY)
 502     IF(PLAYBOOK)
 503       SET(PC_LIBS_PRIVATE "-lbps -lscreen -lGLESv2 -lGLESv1_CM -lEGL -lm")
 504     ELSE()
 505       SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lscreen -lGLESv2 -lGLESv1_CM -lEGL -lm")
 506     ENDIF()
 507   ELSE()
 508     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lGLESv1_CM -lEGL -lm")
 509   ENDIF()
 510 ELSE()
 511   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 512 ENDIF()
 513 # Client applications need to define FreeGLUT GLES version to
 514 # bootstrap headers inclusion in freeglut_std.h:
 515 SET(PC_LIBNAME "glut")
 516 SET(PC_FILENAME "freeglut.pc")
 517 IF(FREEGLUT_GLES)
 518   SET(PC_CFLAGS "-DFREEGLUT_GLES")
 519   SET(PC_LIBNAME "freeglut-gles")
 520   SET(PC_FILENAME "freeglut-gles.pc")
 521 ENDIF()
 522 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 523 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 524 # TODO: change the library and .pc name when building for GLES,
 525 # e.g. -lglut-GLES