git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8.8 FATAL_ERROR)
   2 PROJECT(freeglut)
   3
   4 # for multiarch LIBDIR support (requires cmake>=2.8.8)
   5 INCLUDE(GNUInstallDirs)
   6
   7 # NOTE: On Windows and Cygwin, the dll's are placed in the
   8 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   9 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
  10 # platforms, such as Linux, the shared libraries are put in
  11 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
  12 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  13 # platforms.
  14 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  15 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  16 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  17
  18 # setup version numbers
  19 # TODO: Update these for each release!
  20 set(VERSION_MAJOR 3)
  21 set(VERSION_MINOR 0)
  22 set(VERSION_PATCH 0)
  23
  24 # Update fg_version.h to match the versions number here in cmake
  25 CONFIGURE_FILE(src/fg_version.h.in src/fg_version.h)
  26
  27 # shared lib version numbers (change before release)
  28 set(SO_MAJOR 3)         # increment on backwards incompatible API/ABI changes
  29 set(SO_MINOR 10)        # increment on backwards compatible or internal changes
  30 set(SO_REV 0)           # if nothing else changed increment this
  31
  32 # FREEGLUT_BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  33 # re-declare it here so it will show up in the GUI.
  34 # by default, we want to build both
  35 OPTION(FREEGLUT_BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  36 OPTION(FREEGLUT_BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  37
  38 # option for whether warnings and errors should be printed
  39 OPTION(FREEGLUT_PRINT_ERRORS "Lib prints errors to stderr" ON)
  40 #MARK_AS_ADVANCED(FREEGLUT_PRINT_ERRORS)
  41 OPTION(FREEGLUT_PRINT_WARNINGS "Lib prints warnings to stderr" ON)
  42 #MARK_AS_ADVANCED(FREEGLUT_PRINT_WARNINGS)
  43
  44 # option to also copy .pdb files to install directory when executing
  45 # INSTALL target
  46 IF(MSVC)
  47     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  48 ELSE()
  49     SET(INSTALL_PDB OFF)
  50 ENDIF()
  51
  52 # OpenGL ES support
  53 OPTION(FREEGLUT_GLES "Use OpenGL ES (requires EGL)" OFF)
  54
  55 # option to build either as "glut" (ON) or "freeglut" (OFF)
  56 IF(NOT WIN32)
  57     OPTION(FREEGLUT_REPLACE_GLUT "Be a replacement for GLUT" ON)
  58 ENDIF()
  59
  60
  61 SET(FREEGLUT_HEADERS
  62     include/GL/freeglut.h
  63     include/GL/freeglut_ext.h
  64     include/GL/freeglut_std.h
  65     include/GL/glut.h
  66 )
  67 SET(FREEGLUT_SRCS
  68     ${FREEGLUT_HEADERS}
  69     src/fg_callbacks.c
  70     src/fg_cursor.c
  71     src/fg_display.c
  72     src/fg_ext.c
  73     src/fg_font_data.c
  74     src/fg_gamemode.c
  75     src/fg_geometry.c
  76     src/fg_gl2.c
  77     src/fg_gl2.h
  78     src/fg_init.c
  79     src/fg_init.h
  80     src/fg_internal.h
  81     src/fg_input_devices.c
  82     src/fg_joystick.c
  83     src/fg_main.c
  84     src/fg_misc.c
  85     src/fg_overlay.c
  86     src/fg_spaceball.c
  87     src/fg_state.c
  88     src/fg_stroke_mono_roman.c
  89     src/fg_stroke_roman.c
  90     src/fg_structure.c
  91     src/fg_teapot.c
  92     src/fg_teapot_data.h
  93     src/fg_videoresize.c
  94     src/fg_window.c
  95 )
  96 # TODO: OpenGL ES requires a compatible version of these files:
  97 IF(NOT FREEGLUT_GLES)
  98     LIST(APPEND FREEGLUT_SRCS
  99         src/fg_font.c
 100         src/fg_menu.c
 101     )
 102 ELSE()
 103     LIST(APPEND FREEGLUT_SRCS
 104         src/gles_stubs.c
 105     )
 106 ENDIF()
 107
 108 IF(WIN32)
 109     LIST(APPEND FREEGLUT_SRCS
 110         src/mswin/fg_cursor_mswin.c
 111         src/mswin/fg_display_mswin.c
 112         src/mswin/fg_ext_mswin.c
 113         src/mswin/fg_gamemode_mswin.c
 114         src/mswin/fg_init_mswin.c
 115         src/mswin/fg_internal_mswin.h
 116         src/mswin/fg_input_devices_mswin.c
 117         src/mswin/fg_joystick_mswin.c
 118         src/mswin/fg_main_mswin.c
 119         src/mswin/fg_menu_mswin.c
 120         src/mswin/fg_spaceball_mswin.c
 121         src/mswin/fg_state_mswin.c
 122         src/mswin/fg_structure_mswin.c
 123         src/mswin/fg_window_mswin.c
 124         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 125     )
 126     IF (MSVC AND NOT CMAKE_CL_64)
 127         # .def file only for 32bit Windows builds (TODO: MSVC only right
 128         # now, needed for any other Windows platform?)
 129         LIST(APPEND FREEGLUT_SRCS
 130             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 131         )
 132     ENDIF()
 133
 134 ELSEIF(ANDROID OR BLACKBERRY)
 135     # BlackBerry and Android share some similar design concepts and ideas, as with many mobile devices.
 136     # As such, some classes can be shared between the two. XXX: Possibly rename shareable classes to
 137     # a more generic name. *_stub? *_mobile?
 138     LIST(APPEND FREEGLUT_SRCS
 139         src/android/fg_cursor_android.c
 140         src/android/fg_ext_android.c
 141         src/android/fg_gamemode_android.c
 142         src/android/fg_joystick_android.c
 143         src/android/fg_spaceball_android.c
 144     )
 145     IF(ANDROID)
 146         LIST(APPEND FREEGLUT_SRCS
 147             src/android/native_app_glue/android_native_app_glue.c
 148             src/android/native_app_glue/android_native_app_glue.h
 149             src/android/fg_internal_android.h
 150             src/android/fg_init_android.c
 151             src/android/fg_input_devices_android.c
 152             src/android/fg_main_android.c
 153             src/android/fg_main_android.h
 154             src/android/fg_runtime_android.c
 155             src/android/fg_state_android.c
 156             src/android/fg_structure_android.c
 157             src/android/fg_window_android.c
 158         )
 159     ELSE()
 160         LIST(APPEND FREEGLUT_SRCS
 161             src/blackberry/fg_internal_blackberry.h
 162             src/blackberry/fg_init_blackberry.c
 163             src/x11/fg_input_devices_x11.c
 164             src/blackberry/fg_main_blackberry.c
 165             src/blackberry/fg_state_blackberry.c
 166             src/blackberry/fg_structure_blackberry.c
 167             src/blackberry/fg_window_blackberry.c
 168         )
 169     ENDIF()
 170 ELSE()
 171     LIST(APPEND FREEGLUT_SRCS
 172         src/x11/fg_cursor_x11.c
 173         src/x11/fg_ext_x11.c
 174         src/x11/fg_gamemode_x11.c
 175         src/x11/fg_glutfont_definitions_x11.c
 176         src/x11/fg_init_x11.c
 177         src/x11/fg_internal_x11.h
 178         src/x11/fg_input_devices_x11.c
 179         src/x11/fg_joystick_x11.c
 180         src/x11/fg_main_x11.c
 181         src/x11/fg_menu_x11.c
 182         src/x11/fg_spaceball_x11.c
 183         src/x11/fg_state_x11.c
 184         src/x11/fg_structure_x11.c
 185         src/x11/fg_window_x11.c
 186         src/x11/fg_xinput_x11.c
 187     )
 188     IF(NOT(FREEGLUT_GLES))
 189         LIST(APPEND FREEGLUT_SRCS
 190             src/x11/fg_internal_x11_glx.h
 191             src/x11/fg_display_x11_glx.c
 192             src/x11/fg_state_x11_glx.c
 193             src/x11/fg_state_x11_glx.h
 194             src/x11/fg_window_x11_glx.c
 195             src/x11/fg_window_x11_glx.h
 196         )
 197     ENDIF()
 198 ENDIF()
 199 IF(FREEGLUT_GLES)
 200     LIST(APPEND FREEGLUT_SRCS
 201         src/egl/fg_internal_egl.h
 202         src/egl/fg_display_egl.c
 203         src/egl/fg_ext_egl.c
 204         src/egl/fg_init_egl.c
 205         src/egl/fg_init_egl.h
 206         src/egl/fg_state_egl.c
 207         src/egl/fg_state_egl.h
 208         src/egl/fg_structure_egl.c
 209         src/egl/fg_structure_egl.h
 210         src/egl/fg_window_egl.c
 211         src/egl/fg_window_egl.h
 212     )
 213 ENDIF()
 214
 215 # For OpenGL ES (GLES): compile with -DFREEGLUT_GLES to cleanly
 216 # bootstrap headers inclusion in freeglut_std.h; this constant also
 217 # need to be defined in client applications (e.g. through pkg-config),
 218 # but do use GLES constants directly for all other needs
 219 # GLES1 and GLES2 libraries are compatible and can be co-linked.
 220 IF(FREEGLUT_GLES)
 221   ADD_DEFINITIONS(-DFREEGLUT_GLES)
 222   LIST(APPEND LIBS GLESv2 GLESv1_CM EGL)
 223 ELSE()
 224   FIND_PACKAGE(OpenGL REQUIRED)
 225   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 226   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 227 ENDIF()
 228
 229 # lib m for math, not needed on windows
 230 IF (NOT WIN32)
 231     # For compilation:
 232     LIST(APPEND LIBS m)
 233     # For CHECK_FUNCTION_EXISTS:
 234     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 235 ENDIF()
 236
 237 IF(WIN32)
 238     # hide insecure CRT warnings, common practice
 239     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 240     IF(MSVC)
 241         SET( CMAKE_DEBUG_POSTFIX "d" )
 242     ENDIF(MSVC)
 243
 244     # enable the use of Win2000 APIs (needed for really old compilers like MSVC6)
 245     ADD_DEFINITIONS(-D_WIN32_WINNT=0x0500)
 246     ADD_DEFINITIONS(-DWINVER=0x0500)
 247 ENDIF()
 248
 249 IF(CMAKE_COMPILER_IS_GNUCC)
 250   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 251   IF(NOT(ANDROID OR BLACKBERRY))
 252     # not setting -ansi as EGL/KHR headers doesn't support it
 253     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pedantic")
 254   ENDIF()
 255 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 256
 257 INCLUDE(CheckIncludeFiles)
 258 IF(UNIX AND NOT(ANDROID OR BLACKBERRY))
 259     FIND_PACKAGE(X11 REQUIRED)
 260     INCLUDE_DIRECTORIES(${X11_INCLUDE_DIR})
 261     LIST(APPEND LIBS ${X11_LIBRARIES})
 262     IF(X11_Xrandr_FOUND)
 263         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 264         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 265     ENDIF()
 266     IF(X11_xf86vmode_FOUND)
 267         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 268         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 269         IF(NOT "${X11_Xxf86vm_LIB}")
 270             SET(X11_Xxf86vm_LIB "Xxf86vm")
 271         ENDIF()
 272         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 273     ENDIF()
 274     IF(X11_Xinput_FOUND)
 275         # Needed for multi-touch:
 276         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 277         LIST(APPEND LIBS ${X11_Xinput_LIB})
 278     ENDIF()
 279 ENDIF()
 280 IF(ANDROID)
 281     # -landroid for ANativeWindow
 282     # -llog for native Android logging
 283     LIST(APPEND LIBS android log)
 284 ELSEIF(BLACKBERRY)
 285     # -lbps for event loop
 286     # -screen for native screen
 287     LIST(APPEND LIBS bps screen)
 288
 289     if(NOT PLAYBOOK)
 290         # -lslog2 for logging
 291         # -pps for low-level screen manipulation
 292         LIST(APPEND LIBS slog2 pps)
 293     ENDIF()
 294 ENDIF()
 295
 296 INCLUDE(CheckFunctionExists)
 297 INCLUDE(CheckTypeSize)
 298 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 299 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 300 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 301 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 302 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 303 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 304 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 305 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 306 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 307 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 308 IF (NOT HAVE_XPARSEGEOMETRY)
 309    LIST(APPEND FREEGLUT_SRCS
 310         src/util/xparsegeometry_repl.c
 311         src/util/xparsegeometry_repl.h)
 312    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 313 ENDIF()
 314 # decide on suitable type for internal time keeping, 64-bit if possible
 315 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 316 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 317 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 318     IF (MSVC)
 319         # Some old Microsoft VC releases don't support unsigned long
 320         # long, but all we care about is support for unsigned __int64 on
 321         # MSVC, so test for presence of that type
 322         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 323     ELSEIF()
 324         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 325     ENDIF()
 326 ENDIF()
 327
 328 # The generated config.h is placed in the project's build directory, just to
 329 # ensure that all CMake-generated files are kept away from the main source tree.
 330 # As a result, the build directory must to be added to the include path list.
 331 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 332 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 333 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 334 IF(WIN32)
 335     # we also have to generate freeglut.rc, which contains the version
 336     # number
 337     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 338     IF (MSVC AND NOT CMAKE_CL_64)
 339         # .def file only for 32bit Windows builds with Visual Studio
 340         CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 341     ENDIF()
 342 ENDIF()
 343
 344 IF(FREEGLUT_BUILD_SHARED_LIBS)
 345     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 346 ENDIF()
 347 IF(FREEGLUT_BUILD_STATIC_LIBS)
 348     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 349 ENDIF()
 350
 351
 352 IF(WIN32)
 353     LIST(APPEND LIBS winmm)
 354     IF(FREEGLUT_BUILD_SHARED_LIBS)
 355         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 356     ENDIF()
 357     IF(FREEGLUT_BUILD_STATIC_LIBS)
 358         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 359         # need to set machine:x64 for linker, at least for VC10, and
 360         # doesn't hurt for older compilers:
 361         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 362         IF (CMAKE_CL_64)
 363             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 364         ENDIF()
 365     ENDIF()
 366 ELSE()
 367     # on UNIX we need to make sure:
 368     # - all shared libraries must have a soname/version, see :
 369     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 370     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 371     #   Current: -version-info 12:0:9 -> 3.9.0
 372     #   Note: most platforms now prefer the latter major.minor.revision form
 373     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 374     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 375     #   the lack of support for current:revision:age in CMake should
 376     #   not be a problem.
 377         # - the output library should be named glut so it'll be linkable with -lglut
 378         #   (unless FREEGLUT_REPLACE_GLUT is false).
 379     # - the shared library should link to the dependency libraries so that the user
 380     #   won't have to link them explicitly (they shouldn't have to know that we depend
 381     #   on Xrandr or Xxf86vm)
 382     IF(FREEGLUT_GLES)
 383                 SET(LIBNAME freeglut-gles)
 384     ELSE()
 385                 IF(FREEGLUT_REPLACE_GLUT)
 386                         SET(LIBNAME glut)
 387                 ELSE()
 388                         SET(LIBNAME freeglut)
 389                 ENDIF()
 390         ENDIF()
 391
 392     IF(FREEGLUT_BUILD_SHARED_LIBS)
 393       SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION ${SO_MAJOR}.${SO_MINOR}.${SO_REV} SOVERSION ${SO_MAJOR} OUTPUT_NAME ${LIBNAME})
 394     ENDIF()
 395     IF(FREEGLUT_BUILD_STATIC_LIBS)
 396       SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 397     ENDIF()
 398     IF(ANDROID)
 399         # Not in CMake toolchain file, because the toolchain
 400         # file is called several times and generally doesn't
 401         # seem to be meant for modifying CFLAGS:
 402         # '-mandroid' is not mandatory but doesn't hurt
 403         # '-O0 -gstabs+' helps the currently buggy GDB port
 404         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 405         # Not using _INIT variables, they seem to be used internally only
 406         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 407         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 408     ENDIF()
 409 ENDIF()
 410 IF(FREEGLUT_BUILD_SHARED_LIBS)
 411     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 412 ENDIF()
 413 IF(FREEGLUT_BUILD_STATIC_LIBS)
 414     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 415 ENDIF()
 416
 417 IF(FREEGLUT_BUILD_SHARED_LIBS)
 418     INSTALL(TARGETS freeglut
 419             RUNTIME DESTINATION bin
 420             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 421             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 422     )
 423     IF(INSTALL_PDB)
 424         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Debug/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 425             DESTINATION bin
 426                         CONFIGURATIONS Debug)
 427     ENDIF()
 428 ENDIF()
 429 IF(FREEGLUT_BUILD_STATIC_LIBS)
 430     INSTALL(TARGETS freeglut_static
 431             RUNTIME DESTINATION bin
 432             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 433             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 434     )
 435     IF(INSTALL_PDB)
 436         INSTALL(FILES ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/Debug/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 437             DESTINATION lib
 438                         CONFIGURATIONS Debug)
 439     ENDIF()
 440 ENDIF()
 441 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 442
 443
 444
 445 # Optionally build demos, on by default.
 446 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 447
 448 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 449 # lib m for math, not needed on windows
 450 IF (NOT WIN32)
 451     LIST(APPEND DEMO_LIBS m)
 452 ENDIF()
 453
 454 MACRO(ADD_DEMO name)
 455     IF( FREEGLUT_BUILD_DEMOS )
 456         IF(FREEGLUT_BUILD_SHARED_LIBS)
 457             ADD_EXECUTABLE(${name} ${ARGN})
 458             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 459             IF(WIN32 AND MSVC)
 460                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 461             ENDIF()
 462         ENDIF()
 463         IF(FREEGLUT_BUILD_STATIC_LIBS)
 464             ADD_EXECUTABLE(${name}_static ${ARGN})
 465             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 466             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 467             IF(WIN32 AND MSVC)
 468                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 469             ENDIF()
 470         ENDIF()
 471     ENDIF()
 472 ENDMACRO()
 473
 474 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 475 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 476 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 477 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 478 IF (NOT WIN32)
 479     ADD_DEMO(One             progs/demos/One/one.c)
 480 ELSE()
 481     ADD_DEMO(One             progs/demos/One/one.c
 482                              progs/demos/One/one.rc)
 483 ENDIF()
 484 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 485 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 486 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 487                          progs/demos/shapes/glmatrix.h
 488                          progs/demos/shapes/glmatrix.c)
 489 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 490 IF(UNIX)
 491     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 492                              progs/demos/spaceball/vmath.c
 493                              progs/demos/spaceball/vmath.h)
 494 ENDIF()
 495 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 496 ADD_DEMO(timer           progs/demos/timer/timer.c)
 497
 498
 499
 500 # pkg-config support, to install at $(libdir)/pkgconfig
 501 # Define static build dependencies
 502 IF(WIN32)
 503   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 504 ELSEIF(FREEGLUT_GLES)
 505   IF(ANDROID)
 506     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lGLESv1_CM -lEGL -lm")
 507   ELSEIF(BLACKBERRY)
 508     IF(PLAYBOOK)
 509       SET(PC_LIBS_PRIVATE "-lbps -lscreen -lGLESv2 -lGLESv1_CM -lEGL -lm")
 510     ELSE()
 511       SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lscreen -lGLESv2 -lGLESv1_CM -lEGL -lm")
 512     ENDIF()
 513   ELSE()
 514     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lGLESv1_CM -lEGL -lm")
 515   ENDIF()
 516 ELSE()
 517   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 518 ENDIF()
 519 # Client applications need to define FreeGLUT GLES version to
 520 # bootstrap headers inclusion in freeglut_std.h:
 521 SET(PC_LIBNAME "glut")
 522 SET(PC_FILENAME "freeglut.pc")
 523 IF(FREEGLUT_GLES)
 524   SET(PC_CFLAGS "-DFREEGLUT_GLES")
 525   SET(PC_LIBNAME "freeglut-gles")
 526   SET(PC_FILENAME "freeglut-gles.pc")
 527 ENDIF()
 528 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 529 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/ RENAME ${PC_FILENAME})
 530 # TODO: change the library and .pc name when building for GLES,
 531 # e.g. -lglut-GLES