git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8 FATAL_ERROR)
   2 PROJECT(freeglut)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms.
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  14
  15 # setup version numbers
  16 # TODO: Update these for each release!
  17 set(VERSION_MAJOR 3)
  18 set(VERSION_MINOR 0)
  19 set(VERSION_PATCH 0)
  20
  21
  22 # FREEGLUT_BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  23 # re-declare it here so it will show up in the GUI.
  24 # by default, we want to build both
  25 OPTION(FREEGLUT_BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  26 OPTION(FREEGLUT_BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  27
  28 # option for whether warnings and errors should be printed
  29 OPTION(FREEGLUT_ERRORS "Lib prints errors to stderr" ON)
  30 #MARK_AS_ADVANCED(FREEGLUT_ERRORS)
  31 OPTION(FREEGLUT_WARNINGS "Lib prints warnings to stderr" ON)
  32 #MARK_AS_ADVANCED(FREEGLUT_WARNINGS)
  33
  34 # option to also copy .pdb files to install directory when executing
  35 # INSTALL target
  36 IF(MSVC)
  37     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  38 ELSE()
  39     SET(INSTALL_PDB OFF)
  40 ENDIF()
  41
  42 # OpenGL ES support
  43 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  44 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  45
  46
  47
  48 SET(FREEGLUT_HEADERS
  49     include/GL/freeglut.h
  50     include/GL/freeglut_ext.h
  51     include/GL/freeglut_std.h
  52     include/GL/glut.h
  53 )
  54 SET(FREEGLUT_SRCS
  55     ${FREEGLUT_HEADERS}
  56     src/fg_callbacks.c
  57     src/fg_cursor.c
  58     src/fg_display.c
  59     src/fg_ext.c
  60     src/fg_font_data.c
  61     src/fg_gamemode.c
  62     src/fg_geometry.c
  63     src/fg_gl2.c
  64     src/fg_gl2.h
  65     src/fg_init.c
  66     src/fg_init.h
  67     src/fg_internal.h
  68     src/fg_input_devices.c
  69     src/fg_joystick.c
  70     src/fg_main.c
  71     src/fg_misc.c
  72     src/fg_overlay.c
  73     src/fg_spaceball.c
  74     src/fg_state.c
  75     src/fg_stroke_mono_roman.c
  76     src/fg_stroke_roman.c
  77     src/fg_structure.c
  78     src/fg_teapot.c
  79     src/fg_teapot_data.h
  80     src/fg_videoresize.c
  81     src/fg_window.c
  82 )
  83 # TODO: OpenGL ES requires a compatible version of these files:
  84 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  85     LIST(APPEND FREEGLUT_SRCS
  86         src/fg_font.c
  87         src/fg_menu.c
  88     )
  89 ELSE()
  90     LIST(APPEND FREEGLUT_SRCS
  91         src/gles_stubs.c
  92     )
  93 ENDIF()
  94
  95 IF(WIN32)
  96     LIST(APPEND FREEGLUT_SRCS
  97         src/mswin/fg_cursor_mswin.c
  98         src/mswin/fg_display_mswin.c
  99         src/mswin/fg_ext_mswin.c
 100         src/mswin/fg_gamemode_mswin.c
 101         src/mswin/fg_init_mswin.c
 102         src/mswin/fg_internal_mswin.h
 103         src/mswin/fg_input_devices_mswin.c
 104         src/mswin/fg_joystick_mswin.c
 105         src/mswin/fg_main_mswin.c
 106         src/mswin/fg_menu_mswin.c
 107         src/mswin/fg_spaceball_mswin.c
 108         src/mswin/fg_state_mswin.c
 109         src/mswin/fg_structure_mswin.c
 110         src/mswin/fg_window_mswin.c
 111         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 112     )
 113     IF (MSVC AND NOT CMAKE_CL_64)
 114         # .def file only for 32bit Windows builds (TODO: MSVC only right
 115         # now, needed for any other Windows platform?)
 116         LIST(APPEND FREEGLUT_SRCS
 117             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 118         )
 119     ENDIF()
 120
 121 ELSEIF(ANDROID)
 122     LIST(APPEND FREEGLUT_SRCS
 123         src/android/native_app_glue/android_native_app_glue.c
 124         src/android/native_app_glue/android_native_app_glue.h
 125         src/android/fg_internal_android.h
 126         src/android/fg_cursor_android.c
 127         src/android/fg_ext_android.c
 128         src/android/fg_gamemode_android.c
 129         src/android/fg_init_android.c
 130         src/android/fg_input_devices_android.c
 131         src/android/fg_joystick_android.c
 132         src/android/fg_main_android.c
 133         src/android/fg_main_android.h
 134         src/android/fg_runtime_android.c
 135         src/android/fg_spaceball_android.c
 136         src/android/fg_state_android.c
 137         src/android/fg_structure_android.c
 138         src/android/fg_window_android.c
 139     )
 140 ELSE()
 141     LIST(APPEND FREEGLUT_SRCS
 142         src/x11/fg_cursor_x11.c
 143         src/x11/fg_ext_x11.c
 144         src/x11/fg_gamemode_x11.c
 145         src/x11/fg_glutfont_definitions_x11.c
 146         src/x11/fg_init_x11.c
 147         src/x11/fg_internal_x11.h
 148         src/x11/fg_input_devices_x11.c
 149         src/x11/fg_joystick_x11.c
 150         src/x11/fg_main_x11.c
 151         src/x11/fg_menu_x11.c
 152         src/x11/fg_spaceball_x11.c
 153         src/x11/fg_state_x11.c
 154         src/x11/fg_structure_x11.c
 155         src/x11/fg_window_x11.c
 156         src/x11/fg_xinput_x11.c
 157     )
 158     IF(NOT(FREEGLUT_GLES2 OR FREEGLUT_GLES1))
 159         LIST(APPEND FREEGLUT_SRCS
 160             src/x11/fg_internal_x11_glx.h
 161             src/x11/fg_display_x11_glx.c
 162             src/x11/fg_state_x11_glx.c
 163             src/x11/fg_state_x11_glx.h
 164             src/x11/fg_window_x11_glx.c
 165             src/x11/fg_window_x11_glx.h
 166         )
 167     ENDIF()
 168 ENDIF()
 169 IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 170     LIST(APPEND FREEGLUT_SRCS
 171         src/egl/fg_internal_egl.h
 172         src/egl/fg_display_egl.c
 173         src/egl/fg_ext_egl.c
 174         src/egl/fg_init_egl.c
 175         src/egl/fg_init_egl.h
 176         src/egl/fg_state_egl.c
 177         src/egl/fg_state_egl.h
 178         src/egl/fg_structure_egl.c
 179         src/egl/fg_structure_egl.h
 180         src/egl/fg_window_egl.c
 181         src/egl/fg_window_egl.h
 182     )
 183 ENDIF()
 184
 185 # For OpenGL ES (GLES):
 186 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 187 #   bootstrap headers inclusion in freeglut_std.h; these constants
 188 #   also need to be defined in client applications (e.g. through
 189 #   pkg-config), but use GLES constants directly for all other needs
 190 # - define GLES version-specific library
 191 IF(FREEGLUT_GLES2)
 192   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 193   LIST(APPEND LIBS GLESv2 EGL)
 194 ELSEIF(FREEGLUT_GLES1)
 195   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 196   LIST(APPEND LIBS GLESv1_CM EGL)
 197 ELSE()
 198   FIND_PACKAGE(OpenGL REQUIRED)
 199   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 200   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 201 ENDIF()
 202
 203 # lib m for math, not needed on windows
 204 IF (NOT WIN32)
 205     # For compilation:
 206     LIST(APPEND LIBS m)
 207     # For CHECK_FUNCTION_EXISTS:
 208     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 209 ENDIF()
 210
 211 IF(WIN32)
 212     # hide insecure CRT warnings, common practice
 213     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 214     IF(MSVC)
 215         SET( CMAKE_DEBUG_POSTFIX "d" )
 216     ENDIF(MSVC)
 217
 218 ENDIF()
 219
 220 IF(CMAKE_COMPILER_IS_GNUCC)
 221   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 222   IF(!ANDROID)
 223     # not setting -ansi as EGL/KHR headers doesn't support it
 224     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ansi")
 225   ENDIF()
 226 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 227
 228 INCLUDE(CheckIncludeFiles)
 229 IF(UNIX AND NOT ANDROID)
 230     FIND_PACKAGE(X11 REQUIRED)
 231     LIST(APPEND LIBS ${X11_LIBRARIES})
 232     IF(X11_Xrandr_FOUND)
 233         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 234         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 235     ENDIF()
 236     IF(X11_xf86vmode_FOUND)
 237         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 238         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 239         IF(NOT "${X11_Xxf86vm_LIB}")
 240             SET(X11_Xxf86vm_LIB "Xxf86vm")
 241         ENDIF()
 242         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 243     ENDIF()
 244     IF(X11_Xinput_FOUND)
 245         # Needed for multi-touch:
 246         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 247         LIST(APPEND LIBS ${X11_Xinput_LIB})
 248     ENDIF()
 249 ENDIF()
 250 IF(ANDROID)
 251     # -landroid for ANativeWindow
 252     # -llog for native Android logging
 253     LIST(APPEND LIBS android log)
 254 ENDIF()
 255
 256 INCLUDE(CheckFunctionExists)
 257 INCLUDE(CheckTypeSize)
 258 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 259 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 260 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 261 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 262 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 263 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 264 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 265 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 266 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 267 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 268 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 269 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 270 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 271 IF (NOT HAVE_XPARSEGEOMETRY)
 272    LIST(APPEND FREEGLUT_SRCS
 273         src/util/xparsegeometry_repl.c
 274         src/util/xparsegeometry_repl.h)
 275    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 276 ENDIF()
 277 # decide on suitable type for internal time keeping, 64-bit if possible
 278 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 279 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 280 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 281     IF (MSVC)
 282         # Some old Microsoft VC releases don't support unsigned long
 283         # long, but all we care about is support for unsigned __int64 on
 284         # MSVC, so test for presence of that type
 285         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 286     ELSEIF()
 287         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 288     ENDIF()
 289 ENDIF()
 290
 291 # The generated config.h is placed in the project's build directory, just to
 292 # ensure that all CMake-generated files are kept away from the main source tree.
 293 # As a result, the build directory must to be added to the include path list.
 294 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 295 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 296 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 297 IF(WIN32)
 298     # we also have to generate freeglut.rc, which contains the version
 299     # number
 300     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 301     IF (MSVC AND NOT CMAKE_CL_64)
 302         # .def file only for 32bit Windows builds with Visual Studio
 303         CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 304     ENDIF()
 305 ENDIF()
 306
 307 IF(FREEGLUT_BUILD_SHARED_LIBS)
 308     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 309 ENDIF()
 310 IF(FREEGLUT_BUILD_STATIC_LIBS)
 311     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 312 ENDIF()
 313
 314
 315 IF(WIN32)
 316     LIST(APPEND LIBS winmm)
 317     IF(FREEGLUT_BUILD_SHARED_LIBS)
 318         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 319     ENDIF()
 320     IF(FREEGLUT_BUILD_STATIC_LIBS)
 321         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 322         # need to set machine:x64 for linker, at least for VC10, and
 323         # doesn't hurt for older compilers:
 324         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 325         IF (CMAKE_CL_64)
 326             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 327         ENDIF()
 328     ENDIF()
 329 ELSE()
 330     # on UNIX we need to make sure:
 331     # - all shared libraries must have a soname/version, see :
 332     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 333     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 334     #   Current: -version-info 12:0:9 -> 3.9.0
 335     #   Note: most platforms now prefer the latter major.minor.revision form
 336     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 337     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 338     #   the lack of support for current:revision:age in CMake should
 339     #   not be a problem.
 340     # - the output library should be named glut so it'll be linkable with -lglut
 341     # - the shared library should link to the dependency libraries so that the user
 342     #   won't have to link them explicitly (they shouldn't have to know that we depend
 343     #   on Xrandr or Xxf86vm)
 344     IF(FREEGLUT_GLES2)
 345       SET(LIBNAME freeglut-gles2)
 346     ELSEIF(FREEGLUT_GLES1)
 347       SET(LIBNAME freeglut-gles1)
 348     ELSE()
 349       SET(LIBNAME glut)
 350     ENDIF()
 351
 352     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME ${LIBNAME})
 353     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 354     IF(ANDROID)
 355         # Not in CMake toolchain file, because the toolchain
 356         # file is called several times and generally doesn't
 357         # seem to be meant for modifying CFLAGS:
 358         # '-mandroid' is not mandatory but doesn't hurt
 359         # '-O0 -gstabs+' helps the currently buggy GDB port
 360         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 361         # Not using _INIT variables, they seem to be used internally only
 362         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 363         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 364     ENDIF()
 365 ENDIF()
 366 IF(FREEGLUT_BUILD_SHARED_LIBS)
 367     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 368 ENDIF()
 369 IF(FREEGLUT_BUILD_STATIC_LIBS)
 370     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 371 ENDIF()
 372
 373 IF(FREEGLUT_BUILD_SHARED_LIBS)
 374     INSTALL(TARGETS freeglut
 375             RUNTIME DESTINATION bin
 376             LIBRARY DESTINATION lib
 377             ARCHIVE DESTINATION lib
 378     )
 379     IF(INSTALL_PDB)
 380         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Debug/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 381             DESTINATION bin
 382                         CONFIGURATIONS Debug)
 383     ENDIF()
 384 ENDIF()
 385 IF(FREEGLUT_BUILD_STATIC_LIBS)
 386     INSTALL(TARGETS freeglut_static
 387             RUNTIME DESTINATION bin
 388             LIBRARY DESTINATION lib
 389             ARCHIVE DESTINATION lib
 390     )
 391     IF(INSTALL_PDB)
 392         INSTALL(FILES ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/Debug/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 393             DESTINATION lib
 394                         CONFIGURATIONS Debug)
 395     ENDIF()
 396 ENDIF()
 397 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 398
 399
 400
 401 # Optionally build demos, on by default.
 402 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 403
 404 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 405 # lib m for math, not needed on windows
 406 IF (NOT WIN32)
 407     LIST(APPEND DEMO_LIBS m)
 408 ENDIF()
 409
 410 MACRO(ADD_DEMO name)
 411     IF( FREEGLUT_BUILD_DEMOS )
 412         IF(FREEGLUT_BUILD_SHARED_LIBS)
 413             ADD_EXECUTABLE(${name} ${ARGN})
 414             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 415             IF(WIN32 AND MSVC)
 416                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 417             ENDIF()
 418         ENDIF()
 419         IF(FREEGLUT_BUILD_STATIC_LIBS)
 420             ADD_EXECUTABLE(${name}_static ${ARGN})
 421             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 422             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 423             IF(WIN32 AND MSVC)
 424                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 425             ENDIF()
 426         ENDIF()
 427     ENDIF()
 428 ENDMACRO()
 429
 430 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 431 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 432 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 433 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 434 IF (NOT WIN32)
 435     ADD_DEMO(One             progs/demos/One/one.c)
 436 ELSE()
 437     ADD_DEMO(One             progs/demos/One/one.c
 438                              progs/demos/One/one.rc)
 439 ENDIF()
 440 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 441 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 442 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 443                          progs/demos/shapes/glmatrix.h
 444                          progs/demos/shapes/glmatrix.c)
 445 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 446 IF(UNIX)
 447     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 448                              progs/demos/spaceball/vmath.c
 449                              progs/demos/spaceball/vmath.h)
 450 ENDIF()
 451 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 452 ADD_DEMO(timer           progs/demos/timer/timer.c)
 453
 454
 455
 456 # pkg-config support, to install at $(libdir)/pkgconfig
 457 # Define static build dependencies
 458 IF(WIN32)
 459   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 460 ELSEIF(FREEGLUT_GLES2)
 461   IF(ANDROID)
 462     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 463   ELSE()
 464     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 465   ENDIF()
 466 ELSEIF(FREEGLUT_GLES1)
 467   IF(ANDROID)
 468     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 469   ELSE()
 470     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 471   ENDIF()
 472 ELSE()
 473   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 474 ENDIF()
 475 # Client applications need to define FreeGLUT GLES version to
 476 # bootstrap headers inclusion in freeglut_std.h:
 477 SET(PC_LIBNAME "glut")
 478 SET(PC_FILENAME "freeglut.pc")
 479 IF(FREEGLUT_GLES2)
 480   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 481   SET(PC_LIBNAME "freeglut-gles2")
 482   SET(PC_FILENAME "freeglut-gles2.pc")
 483 ELSEIF(FREEGLUT_GLES1)
 484   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 485   SET(PC_LIBNAME "freeglut-gles1")
 486   SET(PC_FILENAME "freeglut-gles1.pc")
 487 ENDIF()
 488 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 489 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 490 # TODO: change the library and .pc name when building for GLES,
 491 # e.g. -lglut-GLES2