git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # OpenGL ES support
  28 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  29 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  30
  31
  32 SET(FREEGLUT_HEADERS
  33     include/GL/freeglut.h
  34     include/GL/freeglut_ext.h
  35     include/GL/freeglut_std.h
  36     include/GL/glut.h
  37 )
  38 SET(FREEGLUT_SRCS
  39     ${FREEGLUT_HEADERS}
  40     src/fg_callbacks.c
  41     src/fg_cursor.c
  42     src/fg_display.c
  43     src/fg_ext.c
  44     src/fg_font_data.c
  45     src/fg_gamemode.c
  46     src/fg_gl2.c
  47     src/fg_gl2.h
  48     src/fg_init.c
  49     src/fg_internal.h
  50     src/fg_input_devices.c
  51     src/fg_joystick.c
  52     src/fg_main.c
  53     src/fg_misc.c
  54     src/fg_overlay.c
  55     src/fg_spaceball.c
  56     src/fg_state.c
  57     src/fg_stroke_mono_roman.c
  58     src/fg_stroke_roman.c
  59     src/fg_structure.c
  60     src/fg_videoresize.c
  61     src/fg_window.c
  62 )
  63 # TODO: OpenGL ES requires a compatible version of these files:
  64 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  65     LIST(APPEND FREEGLUT_SRCS
  66         src/fg_font.c
  67         src/fg_menu.c
  68         src/fg_teapot.c
  69         src/fg_teapot_data.h
  70         src/fg_geometry.c
  71     )
  72 ELSE()
  73     LIST(APPEND FREEGLUT_SRCS
  74         src/fg_geometry.c
  75         src/gles_stubs.c
  76     )
  77 ENDIF()
  78
  79 IF(WIN32)
  80     LIST(APPEND FREEGLUT_SRCS
  81         src/mswin/fg_cursor_mswin.c
  82         src/mswin/fg_display_mswin.c
  83         src/mswin/fg_ext_mswin.c
  84         src/mswin/fg_gamemode_mswin.c
  85         src/mswin/fg_init_mswin.c
  86         src/mswin/fg_internal_mswin.h
  87         src/mswin/fg_input_devices_mswin.c
  88         src/mswin/fg_joystick_mswin.c
  89         src/mswin/fg_main_mswin.c
  90         src/mswin/fg_menu_mswin.c
  91         src/mswin/fg_spaceball_mswin.c
  92         src/mswin/fg_state_mswin.c
  93         src/mswin/fg_structure_mswin.c
  94         src/mswin/fg_window_mswin.c
  95         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  96     )
  97     IF (MSVC AND NOT CMAKE_CL_64)
  98         # .def file only for 32bit Windows builds
  99         LIST(APPEND FREEGLUT_SRCS
 100             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 101         )
 102     ENDIF()
 103
 104 ELSEIF(ANDROID)
 105     LIST(APPEND FREEGLUT_SRCS
 106         src/egl/fg_internal_egl.h
 107         src/egl/fg_display_egl.c
 108         src/egl/fg_ext_egl.c
 109         src/egl/fg_init_egl.c
 110         src/egl/fg_state_egl.c
 111         src/egl/fg_structure_egl.c
 112         src/egl/fg_structure_egl.h
 113         src/egl/fg_window_egl.c
 114         src/egl/fg_window_egl.h
 115         src/android/native_app_glue/android_native_app_glue.c
 116         src/android/native_app_glue/android_native_app_glue.h
 117         src/android/fg_runtime_android.c
 118         src/android/fg_gamemode_android.c
 119         src/android/fg_structure_android.c
 120         src/android/fg_init_android.c
 121         src/android/fg_input_devices_android.c
 122         src/android/fg_joystick_android.c
 123         src/android/fg_main_android.c
 124         src/android/fg_spaceball_android.c
 125         src/android/fg_state_android.c
 126         src/android/fg_window_android.c
 127         src/android/fg_internal_android.h
 128     )
 129 ELSE()
 130     LIST(APPEND FREEGLUT_SRCS
 131         src/x11/fg_cursor_x11.c
 132         src/x11/fg_ext_x11.c
 133         src/x11/fg_gamemode_x11.c
 134         src/x11/fg_glutfont_definitions_x11.c
 135         src/x11/fg_init_x11.c
 136         src/x11/fg_internal_x11.h
 137         src/x11/fg_input_devices_x11.c
 138         src/x11/fg_joystick_x11.c
 139         src/x11/fg_main_x11.c
 140         src/x11/fg_menu_x11.c
 141         src/x11/fg_spaceball_x11.c
 142         src/x11/fg_state_x11.c
 143         src/x11/fg_structure_x11.c
 144         src/x11/fg_window_x11.c
 145         src/x11/fg_xinput_x11.c
 146     )
 147     IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 148         LIST(APPEND FREEGLUT_SRCS
 149             src/egl/fg_internal_egl.h
 150             src/egl/fg_display_egl.c
 151             src/egl/fg_ext_egl.c
 152             src/egl/fg_init_egl.c
 153             src/egl/fg_state_egl.c
 154             src/egl/fg_structure_egl.c
 155             src/egl/fg_window_egl.c
 156         )
 157     ELSE()
 158         LIST(APPEND FREEGLUT_SRCS
 159             src/x11/fg_internal_x11_glx.h
 160             src/x11/fg_display_x11_glx.c
 161             src/x11/fg_state_x11_glx.c
 162             src/x11/fg_window_x11_glx.c
 163             src/x11/fg_window_x11_glx.h
 164         )
 165     ENDIF()
 166 ENDIF()
 167
 168 # For OpenGL ES (GLES):
 169 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 170 #   bootstrap headers inclusion in freeglut_std.h; these constants
 171 #   also need to be defined in client applications (e.g through
 172 #   pkg-config), but use GLES constants directly for all other needs
 173 # - define GLES version-specific library
 174 IF(FREEGLUT_GLES2)
 175   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 176   LIST(APPEND LIBS GLESv2 EGL)
 177 ELSEIF(FREEGLUT_GLES1)
 178   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 179   LIST(APPEND LIBS GLESv1_CM EGL)
 180 ELSE()
 181   FIND_PACKAGE(OpenGL REQUIRED)
 182   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 183   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 184 ENDIF()
 185
 186 # lib m for math, not needed on windows
 187 IF (NOT WIN32)
 188     LIST(APPEND LIBS m)
 189 ENDIF()
 190
 191 IF(WIN32)
 192     # hide insecure CRT warnings, common practice
 193     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 194 ENDIF()
 195
 196 if(UNIX AND NOT ANDROID)
 197     FIND_PACKAGE(X11 REQUIRED)
 198     LIST(APPEND LIBS ${X11_LIBRARIES})
 199     IF(X11_Xrandr_FOUND)
 200         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 201         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 202     ENDIF()
 203     IF(X11_xf86vmode_FOUND)
 204         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 205         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 206         IF(NOT "${X11_Xxf86vm_LIB}")
 207             SET(X11_Xxf86vm_LIB "Xxf86vm")
 208         ENDIF()
 209         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 210     ENDIF()
 211 ENDIF()
 212
 213 INCLUDE(CheckIncludeFiles)
 214 INCLUDE(CheckFunctionExists)
 215 INCLUDE(CheckTypeSize)
 216 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 217 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 218 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 219 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 220 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 221 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 222 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 223 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 224 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 225 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 226 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 227 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 228 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 229 IF (NOT HAVE_XPARSEGEOMETRY)
 230    LIST(APPEND FREEGLUT_SRCS
 231         src/util/xparsegeometry_repl.c
 232         src/util/xparsegeometry_repl.h)
 233    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 234 ENDIF()
 235 # decide on suitable type for internal time keeping, 64-bit if possible
 236 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 237 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 238 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 239     IF (MSVC)
 240         # Some old Microsoft VC don't support unsigned long long, but all we
 241         # care about support unsigned __int64, so test for presence of that
 242         # type
 243         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 244     ELSEIF()
 245         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 246     ENDIF()
 247 ENDIF()
 248
 249
 250 # The generated config.h is placed in the project's build directory, just to
 251 # ensure that all CMake-generated files are kept away from the main source tree.
 252 # As a result, the build directory must to be added to the include path list.
 253 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 254 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 255 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 256 IF(WIN32)
 257     # we also have to generate freeglut.rc, which contains the version
 258     # number
 259     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 260     IF (MSVC AND NOT CMAKE_CL_64)
 261         # .def file only for 32bit Windows builds with Visual Studio
 262         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 263     ENDIF()
 264 ENDIF()
 265
 266 IF(BUILD_SHARED_LIBS)
 267     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 268 ENDIF()
 269 IF(BUILD_STATIC_LIBS)
 270     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 271 ENDIF()
 272
 273
 274 IF(WIN32)
 275     LIST(APPEND LIBS winmm)
 276     IF(BUILD_SHARED_LIBS)
 277         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 278     ENDIF()
 279     IF(BUILD_STATIC_LIBS)
 280         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 281         # need to set machine:x64 for linker, at least for VC10, and
 282         # doesn't hurt for older compilers:
 283         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 284         IF (CMAKE_CL_64)
 285             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 286         ENDIF()
 287     ENDIF()
 288 ELSE()
 289     # on UNIX we need to make sure:
 290     # - all shared libraries must have a soname/version, see :
 291     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 292     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 293     #   Current: -version-info 12:0:9 -> 3.9.0
 294     # - the output library should be named glut so it'll be linkable with -lglut
 295     # - the shared library should link to the dependency libraries so that the user
 296     #   won't have to link them explicitly (they shouldn't have to know that we depend
 297     #   on Xrandr or Xxf86vm)
 298     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 299     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 300     IF(ANDROID)
 301         # Not in CMake toolchain file, because the toolchain
 302         # file is called several times and generally doesn't
 303         # seem to be meant for modifying CFLAGS:
 304         # '-mandroid' is not mandatory but doesn't hurt
 305         # '-O0 -gstabs+' helps the currently buggy GDB port
 306         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 307         # Not using _INIT variables, they seem to be used internally only
 308         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 309         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 310     ENDIF()
 311 ENDIF()
 312 IF(BUILD_SHARED_LIBS)
 313     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 314 ENDIF()
 315 IF(BUILD_STATIC_LIBS)
 316     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 317 ENDIF()
 318
 319 IF(BUILD_SHARED_LIBS)
 320     INSTALL(TARGETS freeglut DESTINATION lib)
 321 ENDIF()
 322 IF(BUILD_STATIC_LIBS)
 323     INSTALL(TARGETS freeglut_static DESTINATION lib)
 324 ENDIF()
 325 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 326
 327
 328
 329 # Optionally build demos, on by default.
 330 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 331
 332 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 333 # lib m for math, not needed on windows
 334 IF (NOT WIN32)
 335     LIST(APPEND DEMO_LIBS m)
 336 ENDIF()
 337
 338 MACRO(ADD_DEMO name)
 339     IF( FREEGLUT_BUILD_DEMOS )
 340         IF(BUILD_SHARED_LIBS)
 341             ADD_EXECUTABLE(${name} ${ARGN})
 342             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 343         ENDIF()
 344         IF(BUILD_STATIC_LIBS)
 345             ADD_EXECUTABLE(${name}_static ${ARGN})
 346             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 347             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 348         ENDIF()
 349     ENDIF()
 350 ENDMACRO()
 351
 352 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 353 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 354 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 355 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 356 ADD_DEMO(One             progs/demos/One/one.c)
 357 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 358 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 359 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 360 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 361                          progs/demos/spaceball/vmath.c
 362                          progs/demos/spaceball/vmath.h)
 363 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 364 ADD_DEMO(timer           progs/demos/timer/timer.c)
 365
 366 # finally, if any demos are built, copy needed files to output directory
 367 # (currently, thats just the input file for the Fractals demo)
 368 IF(FREEGLUT_BUILD_DEMOS)
 369     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 370     IF(BUILD_SHARED_LIBS)
 371         SET(Frac_target Fractals)
 372     ELSE()
 373         SET(Frac_target Fractals_static)
 374     ENDIF()
 375     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 376     ADD_CUSTOM_COMMAND(
 377         TARGET ${Frac_target}
 378         POST_BUILD
 379         COMMAND ${CMAKE_COMMAND} -E copy
 380         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 381         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 382     )
 383 ENDIF()
 384
 385 # pkg-config support, to install at $(libdir)/pkgconfig
 386 # Define static build dependencies
 387 IF(WIN32)
 388   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 389 ELSEIF(FREEGLUT_GLES2)
 390   IF(ANDROID)
 391     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 392   ELSE()
 393     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 394   ENDIF()
 395 ELSEIF(FREEGLUT_GLES1)
 396   IF(ANDROID)
 397     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 398   ELSE()
 399     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 400   ENDIF()
 401 ELSE()
 402   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 403 ENDIF()
 404 # Client applications need to define FreeGLUT GLES version to
 405 # bootstrap headers inclusion in freeglut_std.h:
 406 IF(FREEGLUT_GLES2)
 407   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 408 ELSEIF(FREEGLUT_GLES1)
 409   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 410 ENDIF()
 411 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 412 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig)
 413 # TODO: change the library and .pc name when building for GLES,
 414 # e.g. -lglut-GLES2