git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms.
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # option to also copy .pdb files to install directory when executing
  28 # INSTALL target
  29 IF(MSVC)
  30     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  31 ELSE()
  32     SET(INSTALL_PDB OFF)
  33 ENDIF()
  34
  35 # OpenGL ES support
  36 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  37 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  38
  39
  40
  41 SET(FREEGLUT_HEADERS
  42     include/GL/freeglut.h
  43     include/GL/freeglut_ext.h
  44     include/GL/freeglut_std.h
  45     include/GL/glut.h
  46 )
  47 SET(FREEGLUT_SRCS
  48     ${FREEGLUT_HEADERS}
  49     src/fg_callbacks.c
  50     src/fg_cursor.c
  51     src/fg_display.c
  52     src/fg_ext.c
  53     src/fg_font_data.c
  54     src/fg_gamemode.c
  55     src/fg_gl2.c
  56     src/fg_gl2.h
  57     src/fg_init.c
  58     src/fg_init.h
  59     src/fg_internal.h
  60     src/fg_input_devices.c
  61     src/fg_joystick.c
  62     src/fg_main.c
  63     src/fg_main.h
  64     src/fg_misc.c
  65     src/fg_overlay.c
  66     src/fg_spaceball.c
  67     src/fg_state.c
  68     src/fg_stroke_mono_roman.c
  69     src/fg_stroke_roman.c
  70     src/fg_structure.c
  71     src/fg_videoresize.c
  72     src/fg_window.c
  73 )
  74 # TODO: OpenGL ES requires a compatible version of these files:
  75 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  76     LIST(APPEND FREEGLUT_SRCS
  77         src/fg_font.c
  78         src/fg_menu.c
  79         src/fg_teapot.c
  80         src/fg_teapot_data.h
  81         src/fg_geometry.c
  82     )
  83 ELSE()
  84     LIST(APPEND FREEGLUT_SRCS
  85         src/fg_geometry.c
  86         src/gles_stubs.c
  87     )
  88 ENDIF()
  89
  90 IF(WIN32)
  91     LIST(APPEND FREEGLUT_SRCS
  92         src/mswin/fg_cursor_mswin.c
  93         src/mswin/fg_display_mswin.c
  94         src/mswin/fg_ext_mswin.c
  95         src/mswin/fg_gamemode_mswin.c
  96         src/mswin/fg_init_mswin.c
  97         src/mswin/fg_internal_mswin.h
  98         src/mswin/fg_input_devices_mswin.c
  99         src/mswin/fg_joystick_mswin.c
 100         src/mswin/fg_main_mswin.c
 101         src/mswin/fg_menu_mswin.c
 102         src/mswin/fg_spaceball_mswin.c
 103         src/mswin/fg_state_mswin.c
 104         src/mswin/fg_structure_mswin.c
 105         src/mswin/fg_window_mswin.c
 106         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 107     )
 108     IF (MSVC AND NOT CMAKE_CL_64)
 109         # .def file only for 32bit Windows builds (TODO: MSVC only right
 110         # now, needed for any other Windows platform?)
 111         LIST(APPEND FREEGLUT_SRCS
 112             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 113         )
 114     ENDIF()
 115
 116 ELSEIF(ANDROID)
 117     LIST(APPEND FREEGLUT_SRCS
 118         src/android/native_app_glue/android_native_app_glue.c
 119         src/android/native_app_glue/android_native_app_glue.h
 120         src/android/fg_internal_android.h
 121         src/android/fg_cursor_android.c
 122         src/android/fg_ext_android.c
 123         src/android/fg_gamemode_android.c
 124         src/android/fg_init_android.c
 125         src/android/fg_input_devices_android.c
 126         src/android/fg_joystick_android.c
 127         src/android/fg_main_android.c
 128         src/android/fg_main_android.h
 129         src/android/fg_runtime_android.c
 130         src/android/fg_spaceball_android.c
 131         src/android/fg_state_android.c
 132         src/android/fg_structure_android.c
 133         src/android/fg_window_android.c
 134     )
 135 ELSE()
 136     LIST(APPEND FREEGLUT_SRCS
 137         src/x11/fg_cursor_x11.c
 138         src/x11/fg_ext_x11.c
 139         src/x11/fg_gamemode_x11.c
 140         src/x11/fg_glutfont_definitions_x11.c
 141         src/x11/fg_init_x11.c
 142         src/x11/fg_internal_x11.h
 143         src/x11/fg_input_devices_x11.c
 144         src/x11/fg_joystick_x11.c
 145         src/x11/fg_main_x11.c
 146         src/x11/fg_menu_x11.c
 147         src/x11/fg_spaceball_x11.c
 148         src/x11/fg_state_x11.c
 149         src/x11/fg_structure_x11.c
 150         src/x11/fg_window_x11.c
 151         src/x11/fg_xinput_x11.c
 152     )
 153     IF(NOT(FREEGLUT_GLES2 OR FREEGLUT_GLES1))
 154         LIST(APPEND FREEGLUT_SRCS
 155             src/x11/fg_internal_x11_glx.h
 156             src/x11/fg_display_x11_glx.c
 157             src/x11/fg_state_x11_glx.c
 158             src/x11/fg_state_x11_glx.h
 159             src/x11/fg_window_x11_glx.c
 160             src/x11/fg_window_x11_glx.h
 161         )
 162     ENDIF()
 163 ENDIF()
 164 IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 165     LIST(APPEND FREEGLUT_SRCS
 166         src/egl/fg_internal_egl.h
 167         src/egl/fg_display_egl.c
 168         src/egl/fg_ext_egl.c
 169         src/egl/fg_init_egl.c
 170         src/egl/fg_init_egl.h
 171         src/egl/fg_state_egl.c
 172         src/egl/fg_state_egl.h
 173         src/egl/fg_structure_egl.c
 174         src/egl/fg_structure_egl.h
 175         src/egl/fg_window_egl.c
 176         src/egl/fg_window_egl.h
 177     )
 178 ENDIF()
 179
 180 # For OpenGL ES (GLES):
 181 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 182 #   bootstrap headers inclusion in freeglut_std.h; these constants
 183 #   also need to be defined in client applications (e.g. through
 184 #   pkg-config), but use GLES constants directly for all other needs
 185 # - define GLES version-specific library
 186 IF(FREEGLUT_GLES2)
 187   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 188   LIST(APPEND LIBS GLESv2 EGL)
 189 ELSEIF(FREEGLUT_GLES1)
 190   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 191   LIST(APPEND LIBS GLESv1_CM EGL)
 192 ELSE()
 193   FIND_PACKAGE(OpenGL REQUIRED)
 194   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 195   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 196 ENDIF()
 197
 198 # lib m for math, not needed on windows
 199 IF (NOT WIN32)
 200     # For compilation:
 201     LIST(APPEND LIBS m)
 202     # For CHECK_FUNCTION_EXISTS:
 203     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 204 ENDIF()
 205
 206 IF(WIN32)
 207     # hide insecure CRT warnings, common practice
 208     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 209     IF(MSVC)
 210         SET( CMAKE_DEBUG_POSTFIX "d" )
 211     ENDIF(MSVC)
 212
 213 ENDIF()
 214
 215 IF(CMAKE_COMPILER_IS_GNUCC)
 216   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 217   IF(!ANDROID)
 218     # not setting -ansi as EGL/KHR headers doesn't support it
 219     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ansi")
 220   ENDIF()
 221 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 222
 223 INCLUDE(CheckIncludeFiles)
 224 IF(UNIX AND NOT ANDROID)
 225     FIND_PACKAGE(X11 REQUIRED)
 226     LIST(APPEND LIBS ${X11_LIBRARIES})
 227     IF(X11_Xrandr_FOUND)
 228         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 229         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 230     ENDIF()
 231     IF(X11_xf86vmode_FOUND)
 232         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 233         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 234         IF(NOT "${X11_Xxf86vm_LIB}")
 235             SET(X11_Xxf86vm_LIB "Xxf86vm")
 236         ENDIF()
 237         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 238     ENDIF()
 239     IF(X11_Xinput_FOUND)
 240         # Needed for multi-touch:
 241         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 242         LIST(APPEND LIBS ${X11_Xinput_LIB})
 243     ENDIF()
 244 ENDIF()
 245 IF(ANDROID)
 246     # -landroid for ANativeWindow
 247     # -llog for native Android logging
 248     LIST(APPEND LIBS android log)
 249 ENDIF()
 250
 251 INCLUDE(CheckFunctionExists)
 252 INCLUDE(CheckTypeSize)
 253 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 254 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 255 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 256 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 257 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 258 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 259 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 260 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 261 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 262 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 263 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 264 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 265 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 266 IF (NOT HAVE_XPARSEGEOMETRY)
 267    LIST(APPEND FREEGLUT_SRCS
 268         src/util/xparsegeometry_repl.c
 269         src/util/xparsegeometry_repl.h)
 270    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 271 ENDIF()
 272 # decide on suitable type for internal time keeping, 64-bit if possible
 273 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 274 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 275 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 276     IF (MSVC)
 277         # Some old Microsoft VC releases don't support unsigned long
 278         # long, but all we care about is support for unsigned __int64 on
 279         # MSVC, so test for presence of that type
 280         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 281     ELSEIF()
 282         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 283     ENDIF()
 284 ENDIF()
 285
 286 # The generated config.h is placed in the project's build directory, just to
 287 # ensure that all CMake-generated files are kept away from the main source tree.
 288 # As a result, the build directory must to be added to the include path list.
 289 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 290 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 291 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 292 IF(WIN32)
 293     # we also have to generate freeglut.rc, which contains the version
 294     # number
 295     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 296     IF (MSVC AND NOT CMAKE_CL_64)
 297         # .def file only for 32bit Windows builds with Visual Studio
 298         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 299     ENDIF()
 300 ENDIF()
 301
 302 IF(BUILD_SHARED_LIBS)
 303     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 304 ENDIF()
 305 IF(BUILD_STATIC_LIBS)
 306     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 307 ENDIF()
 308
 309
 310 IF(WIN32)
 311     LIST(APPEND LIBS winmm)
 312     IF(BUILD_SHARED_LIBS)
 313         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 314     ENDIF()
 315     IF(BUILD_STATIC_LIBS)
 316         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 317         # need to set machine:x64 for linker, at least for VC10, and
 318         # doesn't hurt for older compilers:
 319         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 320         IF (CMAKE_CL_64)
 321             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 322         ENDIF()
 323     ENDIF()
 324 ELSE()
 325     # on UNIX we need to make sure:
 326     # - all shared libraries must have a soname/version, see :
 327     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 328     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 329     #   Current: -version-info 12:0:9 -> 3.9.0
 330     #   Note: most platforms now prefer the latter major.minor.revision form
 331     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 332     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 333     #   the lack of support for current:revision:age in CMake should
 334     #   not be a problem.
 335     # - the output library should be named glut so it'll be linkable with -lglut
 336     # - the shared library should link to the dependency libraries so that the user
 337     #   won't have to link them explicitly (they shouldn't have to know that we depend
 338     #   on Xrandr or Xxf86vm)
 339     IF(FREEGLUT_GLES2)
 340       SET(LIBNAME freeglut-gles2)
 341     ELSEIF(FREEGLUT_GLES1)
 342       SET(LIBNAME freeglut-gles1)
 343     ELSE()
 344       SET(LIBNAME glut)
 345     ENDIF()
 346
 347     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME ${LIBNAME})
 348     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 349     IF(ANDROID)
 350         # Not in CMake toolchain file, because the toolchain
 351         # file is called several times and generally doesn't
 352         # seem to be meant for modifying CFLAGS:
 353         # '-mandroid' is not mandatory but doesn't hurt
 354         # '-O0 -gstabs+' helps the currently buggy GDB port
 355         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 356         # Not using _INIT variables, they seem to be used internally only
 357         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 358         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 359     ENDIF()
 360 ENDIF()
 361 IF(BUILD_SHARED_LIBS)
 362     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 363 ENDIF()
 364 IF(BUILD_STATIC_LIBS)
 365     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 366 ENDIF()
 367
 368
 369 IF(BUILD_SHARED_LIBS)
 370     INSTALL(TARGETS freeglut DESTINATION lib)
 371     IF(INSTALL_PDB)
 372         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 373             DESTINATION lib
 374                         CONFIGURATIONS Debug)
 375     ENDIF()
 376 ENDIF()
 377 IF(BUILD_STATIC_LIBS)
 378     INSTALL(TARGETS freeglut_static DESTINATION lib)
 379     IF(INSTALL_PDB)
 380         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 381             DESTINATION lib
 382                         CONFIGURATIONS Debug)
 383     ENDIF()
 384 ENDIF()
 385 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 386
 387
 388
 389 # Optionally build demos, on by default.
 390 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 391
 392 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 393 # lib m for math, not needed on windows
 394 IF (NOT WIN32)
 395     LIST(APPEND DEMO_LIBS m)
 396 ENDIF()
 397
 398 MACRO(ADD_DEMO name)
 399     IF( FREEGLUT_BUILD_DEMOS )
 400         IF(BUILD_SHARED_LIBS)
 401             ADD_EXECUTABLE(${name} ${ARGN})
 402             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 403             IF(WIN32 AND MSVC)
 404                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 405             ENDIF()
 406         ENDIF()
 407         IF(BUILD_STATIC_LIBS)
 408             ADD_EXECUTABLE(${name}_static ${ARGN})
 409             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 410             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 411             IF(WIN32 AND MSVC)
 412                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 413             ENDIF()
 414         ENDIF()
 415     ENDIF()
 416 ENDMACRO()
 417
 418 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 419 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 420 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 421 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 422 ADD_DEMO(One             progs/demos/One/one.c)
 423 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 424 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 425 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 426                          progs/demos/shapes/glmatrix.h
 427                          progs/demos/shapes/glmatrix.c)
 428 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 429 IF(UNIX)
 430     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 431                              progs/demos/spaceball/vmath.c
 432                              progs/demos/spaceball/vmath.h)
 433 ENDIF()
 434 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 435 ADD_DEMO(timer           progs/demos/timer/timer.c)
 436
 437
 438
 439 # pkg-config support, to install at $(libdir)/pkgconfig
 440 # Define static build dependencies
 441 IF(WIN32)
 442   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 443 ELSEIF(FREEGLUT_GLES2)
 444   IF(ANDROID)
 445     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 446   ELSE()
 447     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 448   ENDIF()
 449 ELSEIF(FREEGLUT_GLES1)
 450   IF(ANDROID)
 451     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 452   ELSE()
 453     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 454   ENDIF()
 455 ELSE()
 456   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 457 ENDIF()
 458 # Client applications need to define FreeGLUT GLES version to
 459 # bootstrap headers inclusion in freeglut_std.h:
 460 SET(PC_LIBNAME "glut")
 461 SET(PC_FILENAME "freeglut.pc")
 462 IF(FREEGLUT_GLES2)
 463   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 464   SET(PC_LIBNAME "freeglut-gles2")
 465   SET(PC_FILENAME "freeglut-gles2.pc")
 466 ELSEIF(FREEGLUT_GLES1)
 467   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 468   SET(PC_LIBNAME "freeglut-gles1")
 469   SET(PC_FILENAME "freeglut-gles1.pc")
 470 ENDIF()
 471 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 472 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 473 # TODO: change the library and .pc name when building for GLES,
 474 # e.g. -lglut-GLES2