git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8 FATAL_ERROR)
   2 PROJECT(freeglut)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms.
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  14
  15 # setup version numbers
  16 # TODO: Update these for each release!
  17 set(VERSION_MAJOR 3)
  18 set(VERSION_MINOR 0)
  19 set(VERSION_PATCH 0)
  20
  21
  22 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  23 # re-declare it here so it will show up in the GUI.
  24 # by default, we want to build both
  25 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  26 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  27
  28 # option for whether warnings and errors should be printed
  29 OPTION(FREEGLUT_ERRORS "Lib prints errors to stderr" ON)
  30 #MARK_AS_ADVANCED(FREEGLUT_ERRORS)
  31 OPTION(FREEGLUT_WARNINGS "Lib prints warnings to stderr" ON)
  32 #MARK_AS_ADVANCED(FREEGLUT_WARNINGS)
  33
  34 # option to also copy .pdb files to install directory when executing
  35 # INSTALL target
  36 IF(MSVC)
  37     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  38 ELSE()
  39     SET(INSTALL_PDB OFF)
  40 ENDIF()
  41
  42 # OpenGL ES support
  43 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  44 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  45
  46
  47
  48 SET(FREEGLUT_HEADERS
  49     include/GL/freeglut.h
  50     include/GL/freeglut_ext.h
  51     include/GL/freeglut_std.h
  52     include/GL/glut.h
  53 )
  54 SET(FREEGLUT_SRCS
  55     ${FREEGLUT_HEADERS}
  56     src/fg_callbacks.c
  57     src/fg_cursor.c
  58     src/fg_display.c
  59     src/fg_ext.c
  60     src/fg_font_data.c
  61     src/fg_gamemode.c
  62     src/fg_gl2.c
  63     src/fg_gl2.h
  64     src/fg_init.c
  65     src/fg_init.h
  66     src/fg_internal.h
  67     src/fg_input_devices.c
  68     src/fg_joystick.c
  69     src/fg_main.c
  70     src/fg_misc.c
  71     src/fg_overlay.c
  72     src/fg_spaceball.c
  73     src/fg_state.c
  74     src/fg_stroke_mono_roman.c
  75     src/fg_stroke_roman.c
  76     src/fg_structure.c
  77     src/fg_videoresize.c
  78     src/fg_window.c
  79 )
  80 # TODO: OpenGL ES requires a compatible version of these files:
  81 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  82     LIST(APPEND FREEGLUT_SRCS
  83         src/fg_font.c
  84         src/fg_menu.c
  85         src/fg_teapot.c
  86         src/fg_teapot_data.h
  87         src/fg_geometry.c
  88     )
  89 ELSE()
  90     LIST(APPEND FREEGLUT_SRCS
  91         src/fg_geometry.c
  92         src/gles_stubs.c
  93     )
  94 ENDIF()
  95
  96 IF(WIN32)
  97     LIST(APPEND FREEGLUT_SRCS
  98         src/mswin/fg_cursor_mswin.c
  99         src/mswin/fg_display_mswin.c
 100         src/mswin/fg_ext_mswin.c
 101         src/mswin/fg_gamemode_mswin.c
 102         src/mswin/fg_init_mswin.c
 103         src/mswin/fg_internal_mswin.h
 104         src/mswin/fg_input_devices_mswin.c
 105         src/mswin/fg_joystick_mswin.c
 106         src/mswin/fg_main_mswin.c
 107         src/mswin/fg_menu_mswin.c
 108         src/mswin/fg_spaceball_mswin.c
 109         src/mswin/fg_state_mswin.c
 110         src/mswin/fg_structure_mswin.c
 111         src/mswin/fg_window_mswin.c
 112         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 113     )
 114     IF (MSVC AND NOT CMAKE_CL_64)
 115         # .def file only for 32bit Windows builds (TODO: MSVC only right
 116         # now, needed for any other Windows platform?)
 117         LIST(APPEND FREEGLUT_SRCS
 118             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 119         )
 120     ENDIF()
 121
 122 ELSEIF(ANDROID)
 123     LIST(APPEND FREEGLUT_SRCS
 124         src/android/native_app_glue/android_native_app_glue.c
 125         src/android/native_app_glue/android_native_app_glue.h
 126         src/android/fg_internal_android.h
 127         src/android/fg_cursor_android.c
 128         src/android/fg_ext_android.c
 129         src/android/fg_gamemode_android.c
 130         src/android/fg_init_android.c
 131         src/android/fg_input_devices_android.c
 132         src/android/fg_joystick_android.c
 133         src/android/fg_main_android.c
 134         src/android/fg_main_android.h
 135         src/android/fg_runtime_android.c
 136         src/android/fg_spaceball_android.c
 137         src/android/fg_state_android.c
 138         src/android/fg_structure_android.c
 139         src/android/fg_window_android.c
 140     )
 141 ELSE()
 142     LIST(APPEND FREEGLUT_SRCS
 143         src/x11/fg_cursor_x11.c
 144         src/x11/fg_ext_x11.c
 145         src/x11/fg_gamemode_x11.c
 146         src/x11/fg_glutfont_definitions_x11.c
 147         src/x11/fg_init_x11.c
 148         src/x11/fg_internal_x11.h
 149         src/x11/fg_input_devices_x11.c
 150         src/x11/fg_joystick_x11.c
 151         src/x11/fg_main_x11.c
 152         src/x11/fg_menu_x11.c
 153         src/x11/fg_spaceball_x11.c
 154         src/x11/fg_state_x11.c
 155         src/x11/fg_structure_x11.c
 156         src/x11/fg_window_x11.c
 157         src/x11/fg_xinput_x11.c
 158     )
 159     IF(NOT(FREEGLUT_GLES2 OR FREEGLUT_GLES1))
 160         LIST(APPEND FREEGLUT_SRCS
 161             src/x11/fg_internal_x11_glx.h
 162             src/x11/fg_display_x11_glx.c
 163             src/x11/fg_state_x11_glx.c
 164             src/x11/fg_state_x11_glx.h
 165             src/x11/fg_window_x11_glx.c
 166             src/x11/fg_window_x11_glx.h
 167         )
 168     ENDIF()
 169 ENDIF()
 170 IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 171     LIST(APPEND FREEGLUT_SRCS
 172         src/egl/fg_internal_egl.h
 173         src/egl/fg_display_egl.c
 174         src/egl/fg_ext_egl.c
 175         src/egl/fg_init_egl.c
 176         src/egl/fg_init_egl.h
 177         src/egl/fg_state_egl.c
 178         src/egl/fg_state_egl.h
 179         src/egl/fg_structure_egl.c
 180         src/egl/fg_structure_egl.h
 181         src/egl/fg_window_egl.c
 182         src/egl/fg_window_egl.h
 183     )
 184 ENDIF()
 185
 186 # For OpenGL ES (GLES):
 187 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 188 #   bootstrap headers inclusion in freeglut_std.h; these constants
 189 #   also need to be defined in client applications (e.g. through
 190 #   pkg-config), but use GLES constants directly for all other needs
 191 # - define GLES version-specific library
 192 IF(FREEGLUT_GLES2)
 193   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 194   LIST(APPEND LIBS GLESv2 EGL)
 195 ELSEIF(FREEGLUT_GLES1)
 196   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 197   LIST(APPEND LIBS GLESv1_CM EGL)
 198 ELSE()
 199   FIND_PACKAGE(OpenGL REQUIRED)
 200   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 201   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 202 ENDIF()
 203
 204 # lib m for math, not needed on windows
 205 IF (NOT WIN32)
 206     # For compilation:
 207     LIST(APPEND LIBS m)
 208     # For CHECK_FUNCTION_EXISTS:
 209     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 210 ENDIF()
 211
 212 IF(WIN32)
 213     # hide insecure CRT warnings, common practice
 214     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 215     IF(MSVC)
 216         SET( CMAKE_DEBUG_POSTFIX "d" )
 217     ENDIF(MSVC)
 218
 219 ENDIF()
 220
 221 IF(CMAKE_COMPILER_IS_GNUCC)
 222   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 223   IF(!ANDROID)
 224     # not setting -ansi as EGL/KHR headers doesn't support it
 225     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ansi")
 226   ENDIF()
 227 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 228
 229 INCLUDE(CheckIncludeFiles)
 230 IF(UNIX AND NOT ANDROID)
 231     FIND_PACKAGE(X11 REQUIRED)
 232     LIST(APPEND LIBS ${X11_LIBRARIES})
 233     IF(X11_Xrandr_FOUND)
 234         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 235         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 236     ENDIF()
 237     IF(X11_xf86vmode_FOUND)
 238         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 239         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 240         IF(NOT "${X11_Xxf86vm_LIB}")
 241             SET(X11_Xxf86vm_LIB "Xxf86vm")
 242         ENDIF()
 243         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 244     ENDIF()
 245     IF(X11_Xinput_FOUND)
 246         # Needed for multi-touch:
 247         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 248         LIST(APPEND LIBS ${X11_Xinput_LIB})
 249     ENDIF()
 250 ENDIF()
 251 IF(ANDROID)
 252     # -landroid for ANativeWindow
 253     # -llog for native Android logging
 254     LIST(APPEND LIBS android log)
 255 ENDIF()
 256
 257 INCLUDE(CheckFunctionExists)
 258 INCLUDE(CheckTypeSize)
 259 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 260 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 261 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 262 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 263 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 264 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 265 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 266 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 267 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 268 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 269 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 270 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 271 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 272 IF (NOT HAVE_XPARSEGEOMETRY)
 273    LIST(APPEND FREEGLUT_SRCS
 274         src/util/xparsegeometry_repl.c
 275         src/util/xparsegeometry_repl.h)
 276    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 277 ENDIF()
 278 # decide on suitable type for internal time keeping, 64-bit if possible
 279 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 280 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 281 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 282     IF (MSVC)
 283         # Some old Microsoft VC releases don't support unsigned long
 284         # long, but all we care about is support for unsigned __int64 on
 285         # MSVC, so test for presence of that type
 286         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 287     ELSEIF()
 288         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 289     ENDIF()
 290 ENDIF()
 291
 292 # The generated config.h is placed in the project's build directory, just to
 293 # ensure that all CMake-generated files are kept away from the main source tree.
 294 # As a result, the build directory must to be added to the include path list.
 295 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 296 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 297 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 298 IF(WIN32)
 299     # we also have to generate freeglut.rc, which contains the version
 300     # number
 301     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 302     IF (MSVC AND NOT CMAKE_CL_64)
 303         # .def file only for 32bit Windows builds with Visual Studio
 304         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 305     ENDIF()
 306 ENDIF()
 307
 308 IF(BUILD_SHARED_LIBS)
 309     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 310 ENDIF()
 311 IF(BUILD_STATIC_LIBS)
 312     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 313 ENDIF()
 314
 315
 316 IF(WIN32)
 317     LIST(APPEND LIBS winmm)
 318     IF(BUILD_SHARED_LIBS)
 319         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 320     ENDIF()
 321     IF(BUILD_STATIC_LIBS)
 322         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 323         # need to set machine:x64 for linker, at least for VC10, and
 324         # doesn't hurt for older compilers:
 325         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 326         IF (CMAKE_CL_64)
 327             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 328         ENDIF()
 329     ENDIF()
 330 ELSE()
 331     # on UNIX we need to make sure:
 332     # - all shared libraries must have a soname/version, see :
 333     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 334     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 335     #   Current: -version-info 12:0:9 -> 3.9.0
 336     #   Note: most platforms now prefer the latter major.minor.revision form
 337     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 338     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 339     #   the lack of support for current:revision:age in CMake should
 340     #   not be a problem.
 341     # - the output library should be named glut so it'll be linkable with -lglut
 342     # - the shared library should link to the dependency libraries so that the user
 343     #   won't have to link them explicitly (they shouldn't have to know that we depend
 344     #   on Xrandr or Xxf86vm)
 345     IF(FREEGLUT_GLES2)
 346       SET(LIBNAME freeglut-gles2)
 347     ELSEIF(FREEGLUT_GLES1)
 348       SET(LIBNAME freeglut-gles1)
 349     ELSE()
 350       SET(LIBNAME glut)
 351     ENDIF()
 352
 353     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME ${LIBNAME})
 354     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 355     IF(ANDROID)
 356         # Not in CMake toolchain file, because the toolchain
 357         # file is called several times and generally doesn't
 358         # seem to be meant for modifying CFLAGS:
 359         # '-mandroid' is not mandatory but doesn't hurt
 360         # '-O0 -gstabs+' helps the currently buggy GDB port
 361         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 362         # Not using _INIT variables, they seem to be used internally only
 363         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 364         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 365     ENDIF()
 366 ENDIF()
 367 IF(BUILD_SHARED_LIBS)
 368     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 369 ENDIF()
 370 IF(BUILD_STATIC_LIBS)
 371     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 372 ENDIF()
 373
 374 IF(BUILD_SHARED_LIBS)
 375     INSTALL(TARGETS freeglut
 376             RUNTIME DESTINATION bin
 377             LIBRARY DESTINATION lib
 378             ARCHIVE DESTINATION lib
 379     )
 380     IF(INSTALL_PDB)
 381         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Debug/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 382             DESTINATION bin
 383                         CONFIGURATIONS Debug)
 384     ENDIF()
 385 ENDIF()
 386 IF(BUILD_STATIC_LIBS)
 387     INSTALL(TARGETS freeglut_static
 388             RUNTIME DESTINATION bin
 389             LIBRARY DESTINATION lib
 390             ARCHIVE DESTINATION lib
 391     )
 392     IF(INSTALL_PDB)
 393         INSTALL(FILES ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/Debug/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 394             DESTINATION lib
 395                         CONFIGURATIONS Debug)
 396     ENDIF()
 397 ENDIF()
 398 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 399
 400
 401
 402 # Optionally build demos, on by default.
 403 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 404
 405 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 406 # lib m for math, not needed on windows
 407 IF (NOT WIN32)
 408     LIST(APPEND DEMO_LIBS m)
 409 ENDIF()
 410
 411 MACRO(ADD_DEMO name)
 412     IF( FREEGLUT_BUILD_DEMOS )
 413         IF(BUILD_SHARED_LIBS)
 414             ADD_EXECUTABLE(${name} ${ARGN})
 415             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 416             IF(WIN32 AND MSVC)
 417                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 418             ENDIF()
 419         ENDIF()
 420         IF(BUILD_STATIC_LIBS)
 421             ADD_EXECUTABLE(${name}_static ${ARGN})
 422             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 423             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 424             IF(WIN32 AND MSVC)
 425                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 426             ENDIF()
 427         ENDIF()
 428     ENDIF()
 429 ENDMACRO()
 430
 431 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 432 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 433 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 434 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 435 ADD_DEMO(One             progs/demos/One/one.c)
 436 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 437 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 438 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 439                          progs/demos/shapes/glmatrix.h
 440                          progs/demos/shapes/glmatrix.c)
 441 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 442 IF(UNIX)
 443     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 444                              progs/demos/spaceball/vmath.c
 445                              progs/demos/spaceball/vmath.h)
 446 ENDIF()
 447 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 448 ADD_DEMO(timer           progs/demos/timer/timer.c)
 449
 450
 451
 452 # pkg-config support, to install at $(libdir)/pkgconfig
 453 # Define static build dependencies
 454 IF(WIN32)
 455   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 456 ELSEIF(FREEGLUT_GLES2)
 457   IF(ANDROID)
 458     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 459   ELSE()
 460     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 461   ENDIF()
 462 ELSEIF(FREEGLUT_GLES1)
 463   IF(ANDROID)
 464     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 465   ELSE()
 466     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 467   ENDIF()
 468 ELSE()
 469   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 470 ENDIF()
 471 # Client applications need to define FreeGLUT GLES version to
 472 # bootstrap headers inclusion in freeglut_std.h:
 473 SET(PC_LIBNAME "glut")
 474 SET(PC_FILENAME "freeglut.pc")
 475 IF(FREEGLUT_GLES2)
 476   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 477   SET(PC_LIBNAME "freeglut-gles2")
 478   SET(PC_FILENAME "freeglut-gles2.pc")
 479 ELSEIF(FREEGLUT_GLES1)
 480   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 481   SET(PC_LIBNAME "freeglut-gles1")
 482   SET(PC_FILENAME "freeglut-gles1.pc")
 483 ENDIF()
 484 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 485 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 486 # TODO: change the library and .pc name when building for GLES,
 487 # e.g. -lglut-GLES2