git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # OpenGL ES support
  28 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  29 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  30
  31
  32 SET(FREEGLUT_HEADERS
  33     include/GL/freeglut.h
  34     include/GL/freeglut_ext.h
  35     include/GL/freeglut_std.h
  36     include/GL/glut.h
  37 )
  38 SET(FREEGLUT_SRCS
  39     ${FREEGLUT_HEADERS}
  40     src/fg_callbacks.c
  41     src/fg_cursor.c
  42     src/fg_display.c
  43     src/fg_ext.c
  44     src/fg_font_data.c
  45     src/fg_gamemode.c
  46     src/fg_init.c
  47     src/fg_internal.h
  48     src/fg_input_devices.c
  49     src/fg_joystick.c
  50     src/fg_main.c
  51     src/fg_misc.c
  52     src/fg_overlay.c
  53     src/fg_spaceball.c
  54     src/fg_state.c
  55     src/fg_stroke_mono_roman.c
  56     src/fg_stroke_roman.c
  57     src/fg_structure.c
  58     src/fg_videoresize.c
  59     src/fg_window.c
  60 )
  61 # TODO: OpenGL ES requires a compatible version of these files:
  62 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  63     LIST(APPEND FREEGLUT_SRCS
  64         src/fg_font.c
  65         src/fg_geometry.c
  66         src/fg_menu.c
  67         src/fg_teapot.c
  68         src/fg_teapot_data.h
  69     )
  70 ELSE()
  71     LIST(APPEND FREEGLUT_SRCS
  72         src/gles_stubs.c
  73     )
  74 ENDIF()
  75
  76 IF(WIN32)
  77     LIST(APPEND FREEGLUT_SRCS
  78         src/mswin/fg_cursor_mswin.c
  79         src/mswin/fg_display_mswin.c
  80         src/mswin/fg_ext_mswin.c
  81         src/mswin/fg_gamemode_mswin.c
  82         src/mswin/fg_init_mswin.c
  83         src/mswin/fg_internal_mswin.h
  84         src/mswin/fg_input_devices_mswin.c
  85         src/mswin/fg_joystick_mswin.c
  86         src/mswin/fg_main_mswin.c
  87         src/mswin/fg_menu_mswin.c
  88         src/mswin/fg_spaceball_mswin.c
  89         src/mswin/fg_state_mswin.c
  90         src/mswin/fg_structure_mswin.c
  91         src/mswin/fg_window_mswin.c
  92         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  93     )
  94     IF (MSVC AND NOT CMAKE_CL_64)
  95         # .def file only for 32bit Windows builds
  96         LIST(APPEND FREEGLUT_SRCS
  97             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
  98         )
  99     ENDIF()
 100
 101 ELSEIF(ANDROID)
 102     LIST(APPEND FREEGLUT_SRCS
 103         src/egl/fg_internal_egl.h
 104         src/egl/fg_display_egl.c
 105         src/egl/fg_init_egl.c
 106         src/egl/fg_state_egl.c
 107         src/egl/fg_structure_egl.c
 108         src/egl/fg_structure_egl.h
 109         src/egl/fg_window_egl.c
 110         src/egl/fg_window_egl.h
 111         src/android/native_app_glue/android_native_app_glue.c
 112         src/android/native_app_glue/android_native_app_glue.h
 113         src/android/fg_runtime_android.c
 114         src/android/fg_gamemode_android.c
 115         src/android/fg_structure_android.c
 116         src/android/fg_init_android.c
 117         src/android/fg_input_devices_android.c
 118         src/android/fg_joystick_android.c
 119         src/android/fg_main_android.c
 120         src/android/fg_spaceball_android.c
 121         src/android/fg_state_android.c
 122         src/android/fg_window_android.c
 123         src/android/fg_internal_android.h
 124     )
 125 ELSE()
 126     LIST(APPEND FREEGLUT_SRCS
 127         src/x11/fg_cursor_x11.c
 128         src/x11/fg_ext_x11.c
 129         src/x11/fg_gamemode_x11.c
 130         src/x11/fg_glutfont_definitions_x11.c
 131         src/x11/fg_init_x11.c
 132         src/x11/fg_internal_x11.h
 133         src/x11/fg_input_devices_x11.c
 134         src/x11/fg_joystick_x11.c
 135         src/x11/fg_main_x11.c
 136         src/x11/fg_menu_x11.c
 137         src/x11/fg_spaceball_x11.c
 138         src/x11/fg_state_x11.c
 139         src/x11/fg_structure_x11.c
 140         src/x11/fg_window_x11.c
 141         src/x11/fg_xinput_x11.c
 142     )
 143     IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 144         LIST(APPEND FREEGLUT_SRCS
 145             src/egl/fg_internal_egl.h
 146             src/egl/fg_display_egl.c
 147             src/egl/fg_init_egl.c
 148             src/egl/fg_state_egl.c
 149             src/egl/fg_structure_egl.c
 150             src/egl/fg_window_egl.c
 151         )
 152     ELSE()
 153         LIST(APPEND FREEGLUT_SRCS
 154             src/x11/fg_internal_x11_glx.h
 155             src/x11/fg_display_x11_glx.c
 156             src/x11/fg_state_x11_glx.c
 157             src/x11/fg_window_x11_glx.c
 158             src/x11/fg_window_x11_glx.h
 159         )
 160     ENDIF()
 161 ENDIF()
 162
 163 # For OpenGL ES (GLES):
 164 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 165 #   bootstrap headers inclusion in freeglut_std.h; these constants
 166 #   also need to be defined in client applications (e.g through
 167 #   pkg-config), but use GLES constants directly for all other needs
 168 # - define GLES version-specific library
 169 IF(FREEGLUT_GLES2)
 170   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 171   LIST(APPEND LIBS GLESv2 EGL)
 172 ELSEIF(FREEGLUT_GLES1)
 173   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 174   LIST(APPEND LIBS GLESv1_CM EGL)
 175 ELSE()
 176   FIND_PACKAGE(OpenGL REQUIRED)
 177   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 178   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 179 ENDIF()
 180
 181 # lib m for math, not needed on windows
 182 IF (NOT WIN32)
 183     LIST(APPEND LIBS m)
 184 ENDIF()
 185
 186 IF(WIN32)
 187     # hide insecure CRT warnings, common practice
 188     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 189 ENDIF()
 190
 191 if(UNIX AND NOT ANDROID)
 192     FIND_PACKAGE(X11 REQUIRED)
 193     LIST(APPEND LIBS ${X11_LIBRARIES})
 194     IF(X11_Xrandr_FOUND)
 195         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 196         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 197     ENDIF()
 198     IF(X11_xf86vmode_FOUND)
 199         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 200         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 201         IF(NOT "${X11_Xxf86vm_LIB}")
 202             SET(X11_Xxf86vm_LIB "Xxf86vm")
 203         ENDIF()
 204         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 205     ENDIF()
 206 ENDIF()
 207
 208 INCLUDE(CheckIncludeFiles)
 209 INCLUDE(CheckFunctionExists)
 210 INCLUDE(CheckTypeSize)
 211 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 212 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 213 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 214 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 215 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 216 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 217 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 218 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 219 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 220 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 221 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 222 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 223 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 224 IF (NOT HAVE_XPARSEGEOMETRY)
 225    LIST(APPEND FREEGLUT_SRCS
 226         src/util/xparsegeometry_repl.c
 227         src/util/xparsegeometry_repl.h)
 228    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 229 ENDIF()
 230 # decide on suitable type for internal time keeping, 64-bit if possible
 231 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 232 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 233 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 234     IF (MSVC)
 235         # Some old Microsoft VC don't support unsigned long long, but all we
 236         # care about support unsigned __int64, so test for presence of that
 237         # type
 238         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 239     ELSEIF()
 240         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 241     ENDIF()
 242 ENDIF()
 243
 244
 245 # The generated config.h is placed in the project's build directory, just to
 246 # ensure that all CMake-generated files are kept away from the main source tree.
 247 # As a result, the build directory must to be added to the include path list.
 248 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 249 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 250 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 251 IF(WIN32)
 252     # we also have to generate freeglut.rc, which contains the version
 253     # number
 254     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 255     IF (MSVC AND NOT CMAKE_CL_64)
 256         # .def file only for 32bit Windows builds with Visual Studio
 257         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 258     ENDIF()
 259 ENDIF()
 260
 261 IF(BUILD_SHARED_LIBS)
 262     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 263 ENDIF()
 264 IF(BUILD_STATIC_LIBS)
 265     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 266 ENDIF()
 267
 268
 269 IF(WIN32)
 270     LIST(APPEND LIBS winmm)
 271     IF(BUILD_SHARED_LIBS)
 272         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 273     ENDIF()
 274     IF(BUILD_STATIC_LIBS)
 275         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 276         # need to set machine:x64 for linker, at least for VC10, and
 277         # doesn't hurt for older compilers:
 278         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 279         IF (CMAKE_CL_64)
 280             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 281         ENDIF()
 282     ENDIF()
 283 ELSE()
 284     # on UNIX we need to make sure:
 285     # - all shared libraries must have a soname/version, see :
 286     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 287     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 288     #   Current: -version-info 12:0:9 -> 3.9.0
 289     # - the output library should be named glut so it'll be linkable with -lglut
 290     # - the shared library should link to the dependency libraries so that the user
 291     #   won't have to link them explicitly (they shouldn't have to know that we depend
 292     #   on Xrandr or Xxf86vm)
 293     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 294     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 295     IF(ANDROID)
 296         # Not in CMake toolchain file, because the toolchain
 297         # file is called several times and generally doesn't
 298         # seem to be meant for modifying CFLAGS:
 299         # '-mandroid' is not mandatory but doesn't hurt
 300         # '-O0 -gstabs+' helps the currently buggy GDB port
 301         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 302         # Not using _INIT variables, they seem to be used internally only
 303         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 304         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 305     ENDIF()
 306 ENDIF()
 307 IF(BUILD_SHARED_LIBS)
 308     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 309 ENDIF()
 310 IF(BUILD_STATIC_LIBS)
 311     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 312 ENDIF()
 313
 314 IF(BUILD_SHARED_LIBS)
 315     INSTALL(TARGETS freeglut DESTINATION lib)
 316 ENDIF()
 317 IF(BUILD_STATIC_LIBS)
 318     INSTALL(TARGETS freeglut_static DESTINATION lib)
 319 ENDIF()
 320 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 321
 322
 323
 324 # Optionally build demos, on by default.
 325 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 326
 327 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 328 # lib m for math, not needed on windows
 329 IF (NOT WIN32)
 330     LIST(APPEND DEMO_LIBS m)
 331 ENDIF()
 332
 333 MACRO(ADD_DEMO name)
 334     IF( FREEGLUT_BUILD_DEMOS )
 335         IF(BUILD_SHARED_LIBS)
 336             ADD_EXECUTABLE(${name} ${ARGN})
 337             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 338         ENDIF()
 339         IF(BUILD_STATIC_LIBS)
 340             ADD_EXECUTABLE(${name}_static ${ARGN})
 341             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 342             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 343         ENDIF()
 344     ENDIF()
 345 ENDMACRO()
 346
 347 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 348 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 349 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 350 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 351 ADD_DEMO(One             progs/demos/One/one.c)
 352 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 353 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 354 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 355 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 356                          progs/demos/spaceball/vmath.c
 357                          progs/demos/spaceball/vmath.h)
 358 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 359 ADD_DEMO(timer           progs/demos/timer/timer.c)
 360
 361 # finally, if any demos are built, copy needed files to output directory
 362 # (currently, thats just the input file for the Fractals demo)
 363 IF(FREEGLUT_BUILD_DEMOS)
 364     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 365     IF(BUILD_SHARED_LIBS)
 366         SET(Frac_target Fractals)
 367     ELSE()
 368         SET(Frac_target Fractals_static)
 369     ENDIF()
 370     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 371     ADD_CUSTOM_COMMAND(
 372         TARGET ${Frac_target}
 373         POST_BUILD
 374         COMMAND ${CMAKE_COMMAND} -E copy
 375         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 376         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 377     )
 378 ENDIF()
 379
 380 # pkg-config support, to install at $(libdir)/pkgconfig
 381 # Define static build dependencies
 382 IF(WIN32)
 383   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 384 ELSEIF(FREEGLUT_GLES2)
 385   IF(ANDROID)
 386     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 387   ELSE()
 388     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 389   ENDIF()
 390 ELSEIF(FREEGLUT_GLES1)
 391   IF(ANDROID)
 392     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 393   ELSE()
 394     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 395   ENDIF()
 396 ELSE()
 397   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 398 ENDIF()
 399 # Client applications need to define FreeGLUT GLES version to
 400 # bootstrap headers inclusion in freeglut_std.h:
 401 IF(FREEGLUT_GLES2)
 402   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 403 ELSEIF(FREEGLUT_GLES1)
 404   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 405 ENDIF()
 406 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 407 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig)
 408 # TODO: change the library and .pc name when building for GLES,
 409 # e.g. -lglut-GLES2