git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8 FATAL_ERROR)
   2 PROJECT(freeglut)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms.
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  14
  15 # setup version numbers
  16 # TODO: Update these for each release!
  17 set(VERSION_MAJOR 3)
  18 set(VERSION_MINOR 0)
  19 set(VERSION_PATCH 0)
  20
  21
  22 # FREEGLUT_BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  23 # re-declare it here so it will show up in the GUI.
  24 # by default, we want to build both
  25 OPTION(FREEGLUT_BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  26 OPTION(FREEGLUT_BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  27
  28 # option for whether warnings and errors should be printed
  29 OPTION(FREEGLUT_PRINT_ERRORS "Lib prints errors to stderr" ON)
  30 #MARK_AS_ADVANCED(FREEGLUT_PRINT_ERRORS)
  31 OPTION(FREEGLUT_PRINT_WARNINGS "Lib prints warnings to stderr" ON)
  32 #MARK_AS_ADVANCED(FREEGLUT_PRINT_WARNINGS)
  33
  34 # option to also copy .pdb files to install directory when executing
  35 # INSTALL target
  36 IF(MSVC)
  37     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  38 ELSE()
  39     SET(INSTALL_PDB OFF)
  40 ENDIF()
  41
  42 # OpenGL ES support
  43 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  44 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  45
  46
  47
  48 SET(FREEGLUT_HEADERS
  49     include/GL/freeglut.h
  50     include/GL/freeglut_ext.h
  51     include/GL/freeglut_std.h
  52     include/GL/glut.h
  53 )
  54 SET(FREEGLUT_SRCS
  55     ${FREEGLUT_HEADERS}
  56     src/fg_callbacks.c
  57     src/fg_cursor.c
  58     src/fg_display.c
  59     src/fg_ext.c
  60     src/fg_font_data.c
  61     src/fg_gamemode.c
  62     src/fg_geometry.c
  63     src/fg_gl2.c
  64     src/fg_gl2.h
  65     src/fg_init.c
  66     src/fg_init.h
  67     src/fg_internal.h
  68     src/fg_input_devices.c
  69     src/fg_joystick.c
  70     src/fg_main.c
  71     src/fg_misc.c
  72     src/fg_overlay.c
  73     src/fg_spaceball.c
  74     src/fg_state.c
  75     src/fg_stroke_mono_roman.c
  76     src/fg_stroke_roman.c
  77     src/fg_structure.c
  78     src/fg_teapot.c
  79     src/fg_teapot_data.h
  80     src/fg_videoresize.c
  81     src/fg_window.c
  82 )
  83 # TODO: OpenGL ES requires a compatible version of these files:
  84 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  85     LIST(APPEND FREEGLUT_SRCS
  86         src/fg_font.c
  87         src/fg_menu.c
  88     )
  89 ELSE()
  90     LIST(APPEND FREEGLUT_SRCS
  91         src/gles_stubs.c
  92     )
  93 ENDIF()
  94
  95 IF(WIN32)
  96     LIST(APPEND FREEGLUT_SRCS
  97         src/mswin/fg_cursor_mswin.c
  98         src/mswin/fg_display_mswin.c
  99         src/mswin/fg_ext_mswin.c
 100         src/mswin/fg_gamemode_mswin.c
 101         src/mswin/fg_init_mswin.c
 102         src/mswin/fg_internal_mswin.h
 103         src/mswin/fg_input_devices_mswin.c
 104         src/mswin/fg_joystick_mswin.c
 105         src/mswin/fg_main_mswin.c
 106         src/mswin/fg_menu_mswin.c
 107         src/mswin/fg_spaceball_mswin.c
 108         src/mswin/fg_state_mswin.c
 109         src/mswin/fg_structure_mswin.c
 110         src/mswin/fg_window_mswin.c
 111         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 112     )
 113     IF (MSVC AND NOT CMAKE_CL_64)
 114         # .def file only for 32bit Windows builds (TODO: MSVC only right
 115         # now, needed for any other Windows platform?)
 116         LIST(APPEND FREEGLUT_SRCS
 117             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 118         )
 119     ENDIF()
 120
 121 ELSEIF(ANDROID)
 122     LIST(APPEND FREEGLUT_SRCS
 123         src/android/native_app_glue/android_native_app_glue.c
 124         src/android/native_app_glue/android_native_app_glue.h
 125         src/android/fg_internal_android.h
 126         src/android/fg_cursor_android.c
 127         src/android/fg_ext_android.c
 128         src/android/fg_gamemode_android.c
 129         src/android/fg_init_android.c
 130         src/android/fg_input_devices_android.c
 131         src/android/fg_joystick_android.c
 132         src/android/fg_main_android.c
 133         src/android/fg_main_android.h
 134         src/android/fg_runtime_android.c
 135         src/android/fg_spaceball_android.c
 136         src/android/fg_state_android.c
 137         src/android/fg_structure_android.c
 138         src/android/fg_window_android.c
 139     )
 140 ELSEIF(BLACKBERRY)
 141     LIST(APPEND FREEGLUT_SRCS
 142         src/blackberry/fg_internal_blackberry.h
 143         src/blackberry/fg_main_blackberry.h
 144     )
 145 ELSE()
 146     LIST(APPEND FREEGLUT_SRCS
 147         src/x11/fg_cursor_x11.c
 148         src/x11/fg_ext_x11.c
 149         src/x11/fg_gamemode_x11.c
 150         src/x11/fg_glutfont_definitions_x11.c
 151         src/x11/fg_init_x11.c
 152         src/x11/fg_internal_x11.h
 153         src/x11/fg_input_devices_x11.c
 154         src/x11/fg_joystick_x11.c
 155         src/x11/fg_main_x11.c
 156         src/x11/fg_menu_x11.c
 157         src/x11/fg_spaceball_x11.c
 158         src/x11/fg_state_x11.c
 159         src/x11/fg_structure_x11.c
 160         src/x11/fg_window_x11.c
 161         src/x11/fg_xinput_x11.c
 162     )
 163     IF(NOT(FREEGLUT_GLES2 OR FREEGLUT_GLES1))
 164         LIST(APPEND FREEGLUT_SRCS
 165             src/x11/fg_internal_x11_glx.h
 166             src/x11/fg_display_x11_glx.c
 167             src/x11/fg_state_x11_glx.c
 168             src/x11/fg_state_x11_glx.h
 169             src/x11/fg_window_x11_glx.c
 170             src/x11/fg_window_x11_glx.h
 171         )
 172     ENDIF()
 173 ENDIF()
 174 IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 175     LIST(APPEND FREEGLUT_SRCS
 176         src/egl/fg_internal_egl.h
 177         src/egl/fg_display_egl.c
 178         src/egl/fg_ext_egl.c
 179         src/egl/fg_init_egl.c
 180         src/egl/fg_init_egl.h
 181         src/egl/fg_state_egl.c
 182         src/egl/fg_state_egl.h
 183         src/egl/fg_structure_egl.c
 184         src/egl/fg_structure_egl.h
 185         src/egl/fg_window_egl.c
 186         src/egl/fg_window_egl.h
 187     )
 188 ENDIF()
 189
 190 # For OpenGL ES (GLES):
 191 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 192 #   bootstrap headers inclusion in freeglut_std.h; these constants
 193 #   also need to be defined in client applications (e.g. through
 194 #   pkg-config), but use GLES constants directly for all other needs
 195 # - define GLES version-specific library
 196 IF(FREEGLUT_GLES2)
 197   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 198   LIST(APPEND LIBS GLESv2 EGL)
 199 ELSEIF(FREEGLUT_GLES1)
 200   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 201   LIST(APPEND LIBS GLESv1_CM EGL)
 202 ELSE()
 203   FIND_PACKAGE(OpenGL REQUIRED)
 204   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 205   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 206 ENDIF()
 207
 208 # lib m for math, not needed on windows
 209 IF (NOT WIN32)
 210     # For compilation:
 211     LIST(APPEND LIBS m)
 212     # For CHECK_FUNCTION_EXISTS:
 213     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 214 ENDIF()
 215
 216 IF(WIN32)
 217     # hide insecure CRT warnings, common practice
 218     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 219     IF(MSVC)
 220         SET( CMAKE_DEBUG_POSTFIX "d" )
 221     ENDIF(MSVC)
 222
 223 ENDIF()
 224
 225 IF(CMAKE_COMPILER_IS_GNUCC)
 226   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 227   IF(NOT(ANDROID OR BLACKBERRY))
 228     # not setting -ansi as EGL/KHR headers doesn't support it
 229     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ansi")
 230   ENDIF()
 231 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 232
 233 INCLUDE(CheckIncludeFiles)
 234 IF(UNIX AND NOT(ANDROID OR BLACKBERRY))
 235     FIND_PACKAGE(X11 REQUIRED)
 236     LIST(APPEND LIBS ${X11_LIBRARIES})
 237     IF(X11_Xrandr_FOUND)
 238         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 239         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 240     ENDIF()
 241     IF(X11_xf86vmode_FOUND)
 242         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 243         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 244         IF(NOT "${X11_Xxf86vm_LIB}")
 245             SET(X11_Xxf86vm_LIB "Xxf86vm")
 246         ENDIF()
 247         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 248     ENDIF()
 249     IF(X11_Xinput_FOUND)
 250         # Needed for multi-touch:
 251         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 252         LIST(APPEND LIBS ${X11_Xinput_LIB})
 253     ENDIF()
 254 ENDIF()
 255 IF(ANDROID)
 256     # -landroid for ANativeWindow
 257     # -llog for native Android logging
 258     LIST(APPEND LIBS android log)
 259 ELSEIF(BLACKBERRY)
 260     LIST(APPEND LIBS bps slog2)
 261 ENDIF()
 262
 263 INCLUDE(CheckFunctionExists)
 264 INCLUDE(CheckTypeSize)
 265 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 266 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 267 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 268 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 269 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 270 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 271 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 272 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 273 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 274 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 275 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 276 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 277 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 278 IF (NOT HAVE_XPARSEGEOMETRY)
 279    LIST(APPEND FREEGLUT_SRCS
 280         src/util/xparsegeometry_repl.c
 281         src/util/xparsegeometry_repl.h)
 282    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 283 ENDIF()
 284 # decide on suitable type for internal time keeping, 64-bit if possible
 285 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 286 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 287 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 288     IF (MSVC)
 289         # Some old Microsoft VC releases don't support unsigned long
 290         # long, but all we care about is support for unsigned __int64 on
 291         # MSVC, so test for presence of that type
 292         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 293     ELSEIF()
 294         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 295     ENDIF()
 296 ENDIF()
 297
 298 # The generated config.h is placed in the project's build directory, just to
 299 # ensure that all CMake-generated files are kept away from the main source tree.
 300 # As a result, the build directory must to be added to the include path list.
 301 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 302 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 303 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 304 IF(WIN32)
 305     # we also have to generate freeglut.rc, which contains the version
 306     # number
 307     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 308     IF (MSVC AND NOT CMAKE_CL_64)
 309         # .def file only for 32bit Windows builds with Visual Studio
 310         CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 311     ENDIF()
 312 ENDIF()
 313
 314 IF(FREEGLUT_BUILD_SHARED_LIBS)
 315     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 316 ENDIF()
 317 IF(FREEGLUT_BUILD_STATIC_LIBS)
 318     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 319 ENDIF()
 320
 321
 322 IF(WIN32)
 323     LIST(APPEND LIBS winmm)
 324     IF(FREEGLUT_BUILD_SHARED_LIBS)
 325         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 326     ENDIF()
 327     IF(FREEGLUT_BUILD_STATIC_LIBS)
 328         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 329         # need to set machine:x64 for linker, at least for VC10, and
 330         # doesn't hurt for older compilers:
 331         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 332         IF (CMAKE_CL_64)
 333             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 334         ENDIF()
 335     ENDIF()
 336 ELSE()
 337     # on UNIX we need to make sure:
 338     # - all shared libraries must have a soname/version, see :
 339     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 340     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 341     #   Current: -version-info 12:0:9 -> 3.9.0
 342     #   Note: most platforms now prefer the latter major.minor.revision form
 343     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 344     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 345     #   the lack of support for current:revision:age in CMake should
 346     #   not be a problem.
 347     # - the output library should be named glut so it'll be linkable with -lglut
 348     # - the shared library should link to the dependency libraries so that the user
 349     #   won't have to link them explicitly (they shouldn't have to know that we depend
 350     #   on Xrandr or Xxf86vm)
 351     IF(FREEGLUT_GLES2)
 352       SET(LIBNAME freeglut-gles2)
 353     ELSEIF(FREEGLUT_GLES1)
 354       SET(LIBNAME freeglut-gles1)
 355     ELSE()
 356       SET(LIBNAME glut)
 357     ENDIF()
 358
 359     IF(FREEGLUT_BUILD_SHARED_LIBS)
 360       SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME ${LIBNAME})
 361     ENDIF()
 362     IF(FREEGLUT_BUILD_STATIC_LIBS)
 363       SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 364     ENDIF()
 365     IF(ANDROID)
 366         # Not in CMake toolchain file, because the toolchain
 367         # file is called several times and generally doesn't
 368         # seem to be meant for modifying CFLAGS:
 369         # '-mandroid' is not mandatory but doesn't hurt
 370         # '-O0 -gstabs+' helps the currently buggy GDB port
 371         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 372         # Not using _INIT variables, they seem to be used internally only
 373         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 374         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 375     ENDIF()
 376 ENDIF()
 377 IF(FREEGLUT_BUILD_SHARED_LIBS)
 378     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 379 ENDIF()
 380 IF(FREEGLUT_BUILD_STATIC_LIBS)
 381     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 382 ENDIF()
 383
 384 IF(FREEGLUT_BUILD_SHARED_LIBS)
 385     INSTALL(TARGETS freeglut
 386             RUNTIME DESTINATION bin
 387             LIBRARY DESTINATION lib
 388             ARCHIVE DESTINATION lib
 389     )
 390     IF(INSTALL_PDB)
 391         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Debug/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 392             DESTINATION bin
 393                         CONFIGURATIONS Debug)
 394     ENDIF()
 395 ENDIF()
 396 IF(FREEGLUT_BUILD_STATIC_LIBS)
 397     INSTALL(TARGETS freeglut_static
 398             RUNTIME DESTINATION bin
 399             LIBRARY DESTINATION lib
 400             ARCHIVE DESTINATION lib
 401     )
 402     IF(INSTALL_PDB)
 403         INSTALL(FILES ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/Debug/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 404             DESTINATION lib
 405                         CONFIGURATIONS Debug)
 406     ENDIF()
 407 ENDIF()
 408 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 409
 410
 411
 412 # Optionally build demos, on by default.
 413 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 414
 415 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 416 # lib m for math, not needed on windows
 417 IF (NOT WIN32)
 418     LIST(APPEND DEMO_LIBS m)
 419 ENDIF()
 420
 421 MACRO(ADD_DEMO name)
 422     IF( FREEGLUT_BUILD_DEMOS )
 423         IF(FREEGLUT_BUILD_SHARED_LIBS)
 424             ADD_EXECUTABLE(${name} ${ARGN})
 425             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 426             IF(WIN32 AND MSVC)
 427                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 428             ENDIF()
 429         ENDIF()
 430         IF(FREEGLUT_BUILD_STATIC_LIBS)
 431             ADD_EXECUTABLE(${name}_static ${ARGN})
 432             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 433             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 434             IF(WIN32 AND MSVC)
 435                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 436             ENDIF()
 437         ENDIF()
 438     ENDIF()
 439 ENDMACRO()
 440
 441 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 442 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 443 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 444 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 445 IF (NOT WIN32)
 446     ADD_DEMO(One             progs/demos/One/one.c)
 447 ELSE()
 448     ADD_DEMO(One             progs/demos/One/one.c
 449                              progs/demos/One/one.rc)
 450 ENDIF()
 451 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 452 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 453 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 454                          progs/demos/shapes/glmatrix.h
 455                          progs/demos/shapes/glmatrix.c)
 456 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 457 IF(UNIX)
 458     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 459                              progs/demos/spaceball/vmath.c
 460                              progs/demos/spaceball/vmath.h)
 461 ENDIF()
 462 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 463 ADD_DEMO(timer           progs/demos/timer/timer.c)
 464
 465
 466
 467 # pkg-config support, to install at $(libdir)/pkgconfig
 468 # Define static build dependencies
 469 IF(WIN32)
 470   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 471 ELSEIF(FREEGLUT_GLES2)
 472   IF(ANDROID)
 473     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 474   ELSEIF(BLACKBERRY)
 475     SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lGLESv2 -lEGL -lm")
 476   ELSE()
 477     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 478   ENDIF()
 479 ELSEIF(FREEGLUT_GLES1)
 480   IF(ANDROID)
 481     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 482   ELSEIF(BLACKBERRY)
 483     SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lGLESv1_CM -lEGL -lm")
 484   ELSE()
 485     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 486   ENDIF()
 487 ELSE()
 488   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 489 ENDIF()
 490 # Client applications need to define FreeGLUT GLES version to
 491 # bootstrap headers inclusion in freeglut_std.h:
 492 SET(PC_LIBNAME "glut")
 493 SET(PC_FILENAME "freeglut.pc")
 494 IF(FREEGLUT_GLES2)
 495   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 496   SET(PC_LIBNAME "freeglut-gles2")
 497   SET(PC_FILENAME "freeglut-gles2.pc")
 498 ELSEIF(FREEGLUT_GLES1)
 499   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 500   SET(PC_LIBNAME "freeglut-gles1")
 501   SET(PC_FILENAME "freeglut-gles1.pc")
 502 ENDIF()
 503 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 504 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 505 # TODO: change the library and .pc name when building for GLES,
 506 # e.g. -lglut-GLES2