git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # OpenGL ES support
  28 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  29 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  30
  31
  32 SET(FREEGLUT_HEADERS
  33     include/GL/freeglut.h
  34     include/GL/freeglut_ext.h
  35     include/GL/freeglut_std.h
  36     include/GL/glut.h
  37 )
  38 SET(FREEGLUT_SRCS
  39     ${FREEGLUT_HEADERS}
  40     src/fg_callbacks.c
  41     src/fg_cursor.c
  42     src/fg_display.c
  43     src/fg_ext.c
  44     src/fg_font_data.c
  45     src/fg_gamemode.c
  46     src/fg_init.c
  47     src/fg_internal.h
  48     src/fg_input_devices.c
  49     src/fg_joystick.c
  50     src/fg_main.c
  51     src/fg_misc.c
  52     src/fg_overlay.c
  53     src/fg_spaceball.c
  54     src/fg_state.c
  55     src/fg_stroke_mono_roman.c
  56     src/fg_stroke_roman.c
  57     src/fg_structure.c
  58     src/fg_videoresize.c
  59     src/fg_window.c
  60 )
  61 # TODO: OpenGL ES requires a compatible version of these files:
  62 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  63     LIST(APPEND FREEGLUT_SRCS
  64         src/fg_font.c
  65         src/fg_menu.c
  66         src/fg_teapot.c
  67         src/fg_teapot_data.h
  68         src/fg_geometry.c
  69     )
  70 ELSE()
  71     LIST(APPEND FREEGLUT_SRCS
  72         src/fg_geometry.c
  73         src/gles_stubs.c
  74     )
  75 ENDIF()
  76
  77 IF(WIN32)
  78     LIST(APPEND FREEGLUT_SRCS
  79         src/mswin/fg_cursor_mswin.c
  80         src/mswin/fg_display_mswin.c
  81         src/mswin/fg_ext_mswin.c
  82         src/mswin/fg_gamemode_mswin.c
  83         src/mswin/fg_init_mswin.c
  84         src/mswin/fg_internal_mswin.h
  85         src/mswin/fg_input_devices_mswin.c
  86         src/mswin/fg_joystick_mswin.c
  87         src/mswin/fg_main_mswin.c
  88         src/mswin/fg_menu_mswin.c
  89         src/mswin/fg_spaceball_mswin.c
  90         src/mswin/fg_state_mswin.c
  91         src/mswin/fg_structure_mswin.c
  92         src/mswin/fg_window_mswin.c
  93         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  94     )
  95     IF (MSVC AND NOT CMAKE_CL_64)
  96         # .def file only for 32bit Windows builds
  97         LIST(APPEND FREEGLUT_SRCS
  98             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
  99         )
 100     ENDIF()
 101
 102 ELSEIF(ANDROID)
 103     LIST(APPEND FREEGLUT_SRCS
 104         src/egl/fg_internal_egl.h
 105         src/egl/fg_display_egl.c
 106         src/egl/fg_ext_egl.c
 107         src/egl/fg_init_egl.c
 108         src/egl/fg_state_egl.c
 109         src/egl/fg_structure_egl.c
 110         src/egl/fg_structure_egl.h
 111         src/egl/fg_window_egl.c
 112         src/egl/fg_window_egl.h
 113         src/android/native_app_glue/android_native_app_glue.c
 114         src/android/native_app_glue/android_native_app_glue.h
 115         src/android/fg_runtime_android.c
 116         src/android/fg_gamemode_android.c
 117         src/android/fg_structure_android.c
 118         src/android/fg_init_android.c
 119         src/android/fg_input_devices_android.c
 120         src/android/fg_joystick_android.c
 121         src/android/fg_main_android.c
 122         src/android/fg_spaceball_android.c
 123         src/android/fg_state_android.c
 124         src/android/fg_window_android.c
 125         src/android/fg_internal_android.h
 126     )
 127 ELSE()
 128     LIST(APPEND FREEGLUT_SRCS
 129         src/x11/fg_cursor_x11.c
 130         src/x11/fg_ext_x11.c
 131         src/x11/fg_gamemode_x11.c
 132         src/x11/fg_glutfont_definitions_x11.c
 133         src/x11/fg_init_x11.c
 134         src/x11/fg_internal_x11.h
 135         src/x11/fg_input_devices_x11.c
 136         src/x11/fg_joystick_x11.c
 137         src/x11/fg_main_x11.c
 138         src/x11/fg_menu_x11.c
 139         src/x11/fg_spaceball_x11.c
 140         src/x11/fg_state_x11.c
 141         src/x11/fg_structure_x11.c
 142         src/x11/fg_window_x11.c
 143         src/x11/fg_xinput_x11.c
 144     )
 145     IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 146         LIST(APPEND FREEGLUT_SRCS
 147             src/egl/fg_internal_egl.h
 148             src/egl/fg_display_egl.c
 149             src/egl/fg_ext_egl.c
 150             src/egl/fg_init_egl.c
 151             src/egl/fg_state_egl.c
 152             src/egl/fg_structure_egl.c
 153             src/egl/fg_window_egl.c
 154         )
 155     ELSE()
 156         LIST(APPEND FREEGLUT_SRCS
 157             src/x11/fg_internal_x11_glx.h
 158             src/x11/fg_display_x11_glx.c
 159             src/x11/fg_state_x11_glx.c
 160             src/x11/fg_window_x11_glx.c
 161             src/x11/fg_window_x11_glx.h
 162         )
 163     ENDIF()
 164 ENDIF()
 165
 166 # For OpenGL ES (GLES):
 167 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 168 #   bootstrap headers inclusion in freeglut_std.h; these constants
 169 #   also need to be defined in client applications (e.g through
 170 #   pkg-config), but use GLES constants directly for all other needs
 171 # - define GLES version-specific library
 172 IF(FREEGLUT_GLES2)
 173   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 174   LIST(APPEND LIBS GLESv2 EGL)
 175 ELSEIF(FREEGLUT_GLES1)
 176   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 177   LIST(APPEND LIBS GLESv1_CM EGL)
 178 ELSE()
 179   FIND_PACKAGE(OpenGL REQUIRED)
 180   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 181   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 182 ENDIF()
 183
 184 # lib m for math, not needed on windows
 185 IF (NOT WIN32)
 186     LIST(APPEND LIBS m)
 187 ENDIF()
 188
 189 IF(WIN32)
 190     # hide insecure CRT warnings, common practice
 191     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 192 ENDIF()
 193
 194 if(UNIX AND NOT ANDROID)
 195     FIND_PACKAGE(X11 REQUIRED)
 196     LIST(APPEND LIBS ${X11_LIBRARIES})
 197     IF(X11_Xrandr_FOUND)
 198         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 199         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 200     ENDIF()
 201     IF(X11_xf86vmode_FOUND)
 202         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 203         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 204         IF(NOT "${X11_Xxf86vm_LIB}")
 205             SET(X11_Xxf86vm_LIB "Xxf86vm")
 206         ENDIF()
 207         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 208     ENDIF()
 209 ENDIF()
 210
 211 INCLUDE(CheckIncludeFiles)
 212 INCLUDE(CheckFunctionExists)
 213 INCLUDE(CheckTypeSize)
 214 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 215 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 216 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 217 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 218 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 219 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 220 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 221 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 222 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 223 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 224 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 225 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 226 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 227 IF (NOT HAVE_XPARSEGEOMETRY)
 228    LIST(APPEND FREEGLUT_SRCS
 229         src/util/xparsegeometry_repl.c
 230         src/util/xparsegeometry_repl.h)
 231    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 232 ENDIF()
 233 # decide on suitable type for internal time keeping, 64-bit if possible
 234 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 235 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 236 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 237     IF (MSVC)
 238         # Some old Microsoft VC don't support unsigned long long, but all we
 239         # care about support unsigned __int64, so test for presence of that
 240         # type
 241         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 242     ELSEIF()
 243         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 244     ENDIF()
 245 ENDIF()
 246
 247
 248 # The generated config.h is placed in the project's build directory, just to
 249 # ensure that all CMake-generated files are kept away from the main source tree.
 250 # As a result, the build directory must to be added to the include path list.
 251 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 252 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 253 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 254 IF(WIN32)
 255     # we also have to generate freeglut.rc, which contains the version
 256     # number
 257     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 258     IF (MSVC AND NOT CMAKE_CL_64)
 259         # .def file only for 32bit Windows builds with Visual Studio
 260         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 261     ENDIF()
 262 ENDIF()
 263
 264 IF(BUILD_SHARED_LIBS)
 265     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 266 ENDIF()
 267 IF(BUILD_STATIC_LIBS)
 268     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 269 ENDIF()
 270
 271
 272 IF(WIN32)
 273     LIST(APPEND LIBS winmm)
 274     IF(BUILD_SHARED_LIBS)
 275         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 276     ENDIF()
 277     IF(BUILD_STATIC_LIBS)
 278         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 279         # need to set machine:x64 for linker, at least for VC10, and
 280         # doesn't hurt for older compilers:
 281         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 282         IF (CMAKE_CL_64)
 283             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 284         ENDIF()
 285     ENDIF()
 286 ELSE()
 287     # on UNIX we need to make sure:
 288     # - all shared libraries must have a soname/version, see :
 289     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 290     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 291     #   Current: -version-info 12:0:9 -> 3.9.0
 292     # - the output library should be named glut so it'll be linkable with -lglut
 293     # - the shared library should link to the dependency libraries so that the user
 294     #   won't have to link them explicitly (they shouldn't have to know that we depend
 295     #   on Xrandr or Xxf86vm)
 296     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 297     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 298     IF(ANDROID)
 299         # Not in CMake toolchain file, because the toolchain
 300         # file is called several times and generally doesn't
 301         # seem to be meant for modifying CFLAGS:
 302         # '-mandroid' is not mandatory but doesn't hurt
 303         # '-O0 -gstabs+' helps the currently buggy GDB port
 304         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 305         # Not using _INIT variables, they seem to be used internally only
 306         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 307         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 308     ENDIF()
 309 ENDIF()
 310 IF(BUILD_SHARED_LIBS)
 311     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 312 ENDIF()
 313 IF(BUILD_STATIC_LIBS)
 314     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 315 ENDIF()
 316
 317 IF(BUILD_SHARED_LIBS)
 318     INSTALL(TARGETS freeglut DESTINATION lib)
 319 ENDIF()
 320 IF(BUILD_STATIC_LIBS)
 321     INSTALL(TARGETS freeglut_static DESTINATION lib)
 322 ENDIF()
 323 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 324
 325
 326
 327 # Optionally build demos, on by default.
 328 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 329
 330 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 331 # lib m for math, not needed on windows
 332 IF (NOT WIN32)
 333     LIST(APPEND DEMO_LIBS m)
 334 ENDIF()
 335
 336 MACRO(ADD_DEMO name)
 337     IF( FREEGLUT_BUILD_DEMOS )
 338         IF(BUILD_SHARED_LIBS)
 339             ADD_EXECUTABLE(${name} ${ARGN})
 340             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 341         ENDIF()
 342         IF(BUILD_STATIC_LIBS)
 343             ADD_EXECUTABLE(${name}_static ${ARGN})
 344             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 345             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 346         ENDIF()
 347     ENDIF()
 348 ENDMACRO()
 349
 350 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 351 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 352 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 353 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 354 ADD_DEMO(One             progs/demos/One/one.c)
 355 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 356 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 357 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 358 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 359                          progs/demos/spaceball/vmath.c
 360                          progs/demos/spaceball/vmath.h)
 361 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 362 ADD_DEMO(timer           progs/demos/timer/timer.c)
 363
 364 # finally, if any demos are built, copy needed files to output directory
 365 # (currently, thats just the input file for the Fractals demo)
 366 IF(FREEGLUT_BUILD_DEMOS)
 367     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 368     IF(BUILD_SHARED_LIBS)
 369         SET(Frac_target Fractals)
 370     ELSE()
 371         SET(Frac_target Fractals_static)
 372     ENDIF()
 373     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 374     ADD_CUSTOM_COMMAND(
 375         TARGET ${Frac_target}
 376         POST_BUILD
 377         COMMAND ${CMAKE_COMMAND} -E copy
 378         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 379         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 380     )
 381 ENDIF()
 382
 383 # pkg-config support, to install at $(libdir)/pkgconfig
 384 # Define static build dependencies
 385 IF(WIN32)
 386   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 387 ELSEIF(FREEGLUT_GLES2)
 388   IF(ANDROID)
 389     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 390   ELSE()
 391     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 392   ENDIF()
 393 ELSEIF(FREEGLUT_GLES1)
 394   IF(ANDROID)
 395     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 396   ELSE()
 397     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 398   ENDIF()
 399 ELSE()
 400   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 401 ENDIF()
 402 # Client applications need to define FreeGLUT GLES version to
 403 # bootstrap headers inclusion in freeglut_std.h:
 404 IF(FREEGLUT_GLES2)
 405   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 406 ELSEIF(FREEGLUT_GLES1)
 407   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 408 ENDIF()
 409 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 410 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig)
 411 # TODO: change the library and .pc name when building for GLES,
 412 # e.g. -lglut-GLES2