git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # OpenGL ES support
  28 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  29 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  30
  31
  32 SET(FREEGLUT_HEADERS
  33     include/GL/freeglut.h
  34     include/GL/freeglut_ext.h
  35     include/GL/freeglut_std.h
  36     include/GL/glut.h
  37 )
  38 SET(FREEGLUT_SRCS
  39     ${FREEGLUT_HEADERS}
  40     src/fg_callbacks.c
  41     src/fg_cursor.c
  42     src/fg_display.c
  43     src/fg_ext.c
  44     src/fg_font_data.c
  45     src/fg_gamemode.c
  46     src/fg_init.c
  47     src/fg_internal.h
  48     src/fg_input_devices.c
  49     src/fg_joystick.c
  50     src/fg_main.c
  51     src/fg_misc.c
  52     src/fg_overlay.c
  53     src/fg_spaceball.c
  54     src/fg_state.c
  55     src/fg_stroke_mono_roman.c
  56     src/fg_stroke_roman.c
  57     src/fg_structure.c
  58     src/fg_videoresize.c
  59     src/fg_window.c
  60 )
  61 # TODO: OpenGL ES requires a compatible version of these files:
  62 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  63     LIST(APPEND FREEGLUT_SRCS
  64         src/fg_font.c
  65         src/fg_geometry.c
  66         src/fg_menu.c
  67         src/fg_teapot.c
  68     )
  69 ENDIF()
  70
  71 IF(WIN32)
  72     LIST(APPEND FREEGLUT_SRCS
  73         src/mswin/fg_cursor_mswin.c
  74         src/mswin/fg_display_mswin.c
  75         src/mswin/fg_ext_mswin.c
  76         src/mswin/fg_gamemode_mswin.c
  77         src/mswin/fg_init_mswin.c
  78         src/mswin/fg_internal_mswin.h
  79         src/mswin/fg_input_devices_mswin.c
  80         src/mswin/fg_joystick_mswin.c
  81         src/mswin/fg_main_mswin.c
  82         src/mswin/fg_menu_mswin.c
  83         src/mswin/fg_spaceball_mswin.c
  84         src/mswin/fg_state_mswin.c
  85         src/mswin/fg_structure_mswin.c
  86         src/mswin/fg_window_mswin.c
  87         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  88     )
  89     IF (MSVC AND NOT CMAKE_CL_64)
  90         # .def file only for 32bit Windows builds
  91         LIST(APPEND FREEGLUT_SRCS
  92             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
  93         )
  94     ENDIF()
  95
  96 ELSEIF(ANDROID)
  97     LIST(APPEND FREEGLUT_SRCS
  98         src/egl/fg_internal_egl.h
  99         src/egl/fg_display_egl.c
 100         src/egl/fg_init_egl.c
 101         src/egl/fg_structure_egl.c
 102         src/egl/fg_window_egl.c
 103         src/egl/fg_window_egl.h
 104         src/android/native_app_glue/android_native_app_glue.c
 105         src/android/native_app_glue/android_native_app_glue.h
 106         src/android/fg_runtime_android.c
 107         src/android/fg_gamemode_android.c
 108         src/android/fg_input_devices_android.c
 109         src/android/fg_joystick_android.c
 110         src/android/fg_main_android.c
 111         src/android/fg_spaceball_android.c
 112         src/android/fg_state_android.c
 113         src/android/fg_window_android.c
 114         src/android/opengles_stubs.c
 115         src/android/fg_internal_android.h
 116     )
 117 ELSE()
 118     LIST(APPEND FREEGLUT_SRCS
 119         src/x11/fg_cursor_x11.c
 120         src/x11/fg_display_x11.c
 121         src/x11/fg_ext_x11.c
 122         src/x11/fg_gamemode_x11.c
 123         src/x11/fg_glutfont_definitions_x11.c
 124         src/x11/fg_init_x11.c
 125         src/x11/fg_internal_x11.h
 126         src/x11/fg_input_devices_x11.c
 127         src/x11/fg_joystick_x11.c
 128         src/x11/fg_main_x11.c
 129         src/x11/fg_menu_x11.c
 130         src/x11/fg_spaceball_x11.c
 131         src/x11/fg_state_x11.c
 132         src/x11/fg_structure_x11.c
 133         src/x11/fg_window_x11.c
 134         src/x11/fg_xinput_x11.c
 135     )
 136 ENDIF()
 137
 138 # For OpenGL ES (GLES):
 139 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 140 #   bootstrap headers inclusion in freeglut_std.h; these constants
 141 #   also need to be defined in client applications (e.g through
 142 #   pkg-config), but use GLES constants directly for all other needs
 143 # - define GLES version-specific library
 144 IF(FREEGLUT_GLES2)
 145   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 146   LIST(APPEND LIBS GLESv2 EGL)
 147 ELSEIF(FREEGLUT_GLES1)
 148   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 149   LIST(APPEND LIBS GLESv1 EGL)
 150 ELSE()
 151   FIND_PACKAGE(OpenGL REQUIRED)
 152   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 153   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 154 ENDIF()
 155
 156 # lib m for math, not needed on windows
 157 IF (NOT WIN32)
 158     LIST(APPEND LIBS m)
 159 ENDIF()
 160
 161 IF(WIN32)
 162     # hide insecure CRT warnings, common practice
 163     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 164 ENDIF()
 165
 166 if(UNIX AND NOT ANDROID)
 167     FIND_PACKAGE(X11 REQUIRED)
 168     LIST(APPEND LIBS ${X11_LIBRARIES})
 169     IF(X11_Xrandr_FOUND)
 170         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 171         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 172     ENDIF()
 173     IF(X11_xf86vmode_FOUND)
 174         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 175         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 176         IF(NOT "${X11_Xxf86vm_LIB}")
 177             SET(X11_Xxf86vm_LIB "Xxf86vm")
 178         ENDIF()
 179         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 180     ENDIF()
 181 ENDIF()
 182
 183 INCLUDE(CheckIncludeFiles)
 184 INCLUDE(CheckFunctionExists)
 185 INCLUDE(CheckTypeSize)
 186 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 187 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 188 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 189 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 190 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 191 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 192 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 193 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 194 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 195 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 196 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 197 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 198 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 199 IF (NOT HAVE_XPARSEGEOMETRY)
 200    LIST(APPEND FREEGLUT_SRCS
 201         src/util/xparsegeometry_repl.c
 202         src/util/xparsegeometry_repl.h)
 203    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 204 ENDIF()
 205 # decide on suitable type for internal time keeping, 64-bit if possible
 206 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 207 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 208 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 209     IF (MSVC)
 210         # Some old Microsoft VC don't support unsigned long long, but all we
 211         # care about support unsigned __int64, so test for presence of that
 212         # type
 213         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 214     ELSEIF()
 215         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 216     ENDIF()
 217 ENDIF()
 218
 219
 220 # The generated config.h is placed in the project's build directory, just to
 221 # ensure that all CMake-generated files are kept away from the main source tree.
 222 # As a result, the build directory must to be added to the include path list.
 223 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 224 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 225 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 226 IF(WIN32)
 227     # we also have to generate freeglut.rc, which contains the version
 228     # number
 229     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 230     IF (MSVC AND NOT CMAKE_CL_64)
 231         # .def file only for 32bit Windows builds with Visual Studio
 232         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 233     ENDIF()
 234 ENDIF()
 235
 236 IF(BUILD_SHARED_LIBS)
 237     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 238 ENDIF()
 239 IF(BUILD_STATIC_LIBS)
 240     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 241 ENDIF()
 242
 243
 244 IF(WIN32)
 245     LIST(APPEND LIBS winmm)
 246     IF(BUILD_SHARED_LIBS)
 247         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 248     ENDIF()
 249     IF(BUILD_STATIC_LIBS)
 250         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 251         # need to set machine:x64 for linker, at least for VC10, and
 252         # doesn't hurt for older compilers:
 253         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 254         IF (CMAKE_CL_64)
 255             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 256         ENDIF()
 257     ENDIF()
 258 ELSE()
 259     # on UNIX we need to make sure:
 260     # - all shared libraries must have a soname/version, see :
 261     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 262     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 263     #   Current: -version-info 12:0:9 -> 3.9.0
 264     # - the output library should be named glut so it'll be linkable with -lglut
 265     # - the shared library should link to the dependency libraries so that the user
 266     #   won't have to link them explicitly (they shouldn't have to know that we depend
 267     #   on Xrandr or Xxf86vm)
 268     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 269     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 270     IF(ANDROID)
 271         # Not in CMake toolchain file, because the toolchain
 272         # file is called several times and generally doesn't
 273         # seem to be meant for modifying CFLAGS:
 274         # '-mandroid' is not mandatory but doesn't hurt
 275         # '-O0 -gstabs+' helps the currently buggy GDB port
 276         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 277         # Not using _INIT variables, they seem to be used internally only
 278         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 279         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 280     ENDIF()
 281 ENDIF()
 282 IF(BUILD_SHARED_LIBS)
 283     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 284 ENDIF()
 285 IF(BUILD_STATIC_LIBS)
 286     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 287 ENDIF()
 288
 289 IF(BUILD_SHARED_LIBS)
 290     INSTALL(TARGETS freeglut DESTINATION lib)
 291 ENDIF()
 292 IF(BUILD_STATIC_LIBS)
 293     INSTALL(TARGETS freeglut_static DESTINATION lib)
 294 ENDIF()
 295 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 296
 297
 298
 299 # Optionally build demos, on by default.
 300 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 301
 302 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 303 # lib m for math, not needed on windows
 304 IF (NOT WIN32)
 305     LIST(APPEND DEMO_LIBS m)
 306 ENDIF()
 307
 308 MACRO(ADD_DEMO name)
 309     IF( FREEGLUT_BUILD_DEMOS )
 310         IF(BUILD_SHARED_LIBS)
 311             ADD_EXECUTABLE(${name} ${ARGN})
 312             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 313         ENDIF()
 314         IF(BUILD_STATIC_LIBS)
 315             ADD_EXECUTABLE(${name}_static ${ARGN})
 316             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 317             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 318         ENDIF()
 319     ENDIF()
 320 ENDMACRO()
 321
 322 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 323 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 324 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 325 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 326 ADD_DEMO(One             progs/demos/One/one.c)
 327 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 328 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 329 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 330 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 331                          progs/demos/spaceball/vmath.c
 332                          progs/demos/spaceball/vmath.h)
 333 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 334 ADD_DEMO(timer           progs/demos/timer/timer.c)
 335
 336 # finally, if any demos are built, copy needed files to output directory
 337 # (currently, thats just the input file for the Fractals demo)
 338 IF(FREEGLUT_BUILD_DEMOS)
 339     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 340     IF(BUILD_SHARED_LIBS)
 341         SET(Frac_target Fractals)
 342     ELSE()
 343         SET(Frac_target Fractals_static)
 344     ENDIF()
 345     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 346     ADD_CUSTOM_COMMAND(
 347         TARGET ${Frac_target}
 348         POST_BUILD
 349         COMMAND ${CMAKE_COMMAND} -E copy
 350         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 351         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 352     )
 353 ENDIF()
 354
 355 # pkg-config support, to install at $(libdir)/pkgconfig
 356 # Define static build dependencies
 357 IF(WIN32)
 358   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32")
 359 ELSEIF(ANDROID)
 360   SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL")
 361 ELSE()
 362   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL")
 363 ENDIF()
 364 # Client applications need to define FreeGLUT GLES version to
 365 # bootstrap headers inclusion in freeglut_std.h:
 366 IF(FREEGLUT_GLES2)
 367   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 368 ELSEIF(FREEGLUT_GLES1)
 369   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 370 ENDIF()
 371 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 372 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig)
 373 # TODO: change the library and .pc name when building for GLES,
 374 # e.g. -lglut-GLES2