git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # OpenGL ES support
  28 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  29 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  30
  31
  32 SET(FREEGLUT_HEADERS
  33     include/GL/freeglut.h
  34     include/GL/freeglut_ext.h
  35     include/GL/freeglut_std.h
  36     include/GL/glut.h
  37 )
  38 SET(FREEGLUT_SRCS
  39     ${FREEGLUT_HEADERS}
  40     src/fg_callbacks.c
  41     src/fg_cursor.c
  42     src/fg_display.c
  43     src/fg_ext.c
  44     src/fg_font_data.c
  45     src/fg_gamemode.c
  46     src/fg_init.c
  47     src/fg_internal.h
  48     src/fg_input_devices.c
  49     src/fg_joystick.c
  50     src/fg_main.c
  51     src/fg_misc.c
  52     src/fg_overlay.c
  53     src/fg_spaceball.c
  54     src/fg_state.c
  55     src/fg_stroke_mono_roman.c
  56     src/fg_stroke_roman.c
  57     src/fg_structure.c
  58     src/fg_videoresize.c
  59     src/fg_window.c
  60 )
  61 # TODO: OpenGL ES requires a compatible version of these files:
  62 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  63     LIST(APPEND FREEGLUT_SRCS
  64         src/fg_font.c
  65         src/fg_geometry.c
  66         src/fg_menu.c
  67         src/fg_teapot.c
  68     )
  69 ELSE()
  70     LIST(APPEND FREEGLUT_SRCS
  71         src/gles_stubs.c
  72     )
  73 ENDIF()
  74
  75 IF(WIN32)
  76     LIST(APPEND FREEGLUT_SRCS
  77         src/mswin/fg_cursor_mswin.c
  78         src/mswin/fg_display_mswin.c
  79         src/mswin/fg_ext_mswin.c
  80         src/mswin/fg_gamemode_mswin.c
  81         src/mswin/fg_init_mswin.c
  82         src/mswin/fg_internal_mswin.h
  83         src/mswin/fg_input_devices_mswin.c
  84         src/mswin/fg_joystick_mswin.c
  85         src/mswin/fg_main_mswin.c
  86         src/mswin/fg_menu_mswin.c
  87         src/mswin/fg_spaceball_mswin.c
  88         src/mswin/fg_state_mswin.c
  89         src/mswin/fg_structure_mswin.c
  90         src/mswin/fg_window_mswin.c
  91         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  92     )
  93     IF (MSVC AND NOT CMAKE_CL_64)
  94         # .def file only for 32bit Windows builds
  95         LIST(APPEND FREEGLUT_SRCS
  96             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
  97         )
  98     ENDIF()
  99
 100 ELSEIF(ANDROID)
 101     LIST(APPEND FREEGLUT_SRCS
 102         src/egl/fg_internal_egl.h
 103         src/egl/fg_display_egl.c
 104         src/egl/fg_init_egl.c
 105         src/egl/fg_state_egl.c
 106         src/egl/fg_structure_egl.c
 107         src/egl/fg_structure_egl.h
 108         src/egl/fg_window_egl.c
 109         src/egl/fg_window_egl.h
 110         src/android/native_app_glue/android_native_app_glue.c
 111         src/android/native_app_glue/android_native_app_glue.h
 112         src/android/fg_runtime_android.c
 113         src/android/fg_gamemode_android.c
 114         src/android/fg_structure_android.c
 115         src/android/fg_init_android.c
 116         src/android/fg_input_devices_android.c
 117         src/android/fg_joystick_android.c
 118         src/android/fg_main_android.c
 119         src/android/fg_spaceball_android.c
 120         src/android/fg_state_android.c
 121         src/android/fg_window_android.c
 122         src/android/fg_internal_android.h
 123     )
 124 ELSE()
 125     LIST(APPEND FREEGLUT_SRCS
 126         src/x11/fg_cursor_x11.c
 127         src/x11/fg_display_x11.c
 128         src/x11/fg_ext_x11.c
 129         src/x11/fg_gamemode_x11.c
 130         src/x11/fg_glutfont_definitions_x11.c
 131         src/x11/fg_init_x11.c
 132         src/x11/fg_internal_x11.h
 133         src/x11/fg_input_devices_x11.c
 134         src/x11/fg_joystick_x11.c
 135         src/x11/fg_main_x11.c
 136         src/x11/fg_menu_x11.c
 137         src/x11/fg_spaceball_x11.c
 138         src/x11/fg_state_x11.c
 139         src/x11/fg_structure_x11.c
 140         src/x11/fg_window_x11.c
 141         src/x11/fg_xinput_x11.c
 142     )
 143 ENDIF()
 144
 145 # For OpenGL ES (GLES):
 146 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 147 #   bootstrap headers inclusion in freeglut_std.h; these constants
 148 #   also need to be defined in client applications (e.g through
 149 #   pkg-config), but use GLES constants directly for all other needs
 150 # - define GLES version-specific library
 151 IF(FREEGLUT_GLES2)
 152   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 153   LIST(APPEND LIBS GLESv2 EGL)
 154 ELSEIF(FREEGLUT_GLES1)
 155   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 156   LIST(APPEND LIBS GLESv1_CM EGL)
 157 ELSE()
 158   FIND_PACKAGE(OpenGL REQUIRED)
 159   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 160   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 161 ENDIF()
 162
 163 # lib m for math, not needed on windows
 164 IF (NOT WIN32)
 165     LIST(APPEND LIBS m)
 166 ENDIF()
 167
 168 IF(WIN32)
 169     # hide insecure CRT warnings, common practice
 170     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 171 ENDIF()
 172
 173 if(UNIX AND NOT ANDROID)
 174     FIND_PACKAGE(X11 REQUIRED)
 175     LIST(APPEND LIBS ${X11_LIBRARIES})
 176     IF(X11_Xrandr_FOUND)
 177         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 178         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 179     ENDIF()
 180     IF(X11_xf86vmode_FOUND)
 181         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 182         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 183         IF(NOT "${X11_Xxf86vm_LIB}")
 184             SET(X11_Xxf86vm_LIB "Xxf86vm")
 185         ENDIF()
 186         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 187     ENDIF()
 188 ENDIF()
 189
 190 INCLUDE(CheckIncludeFiles)
 191 INCLUDE(CheckFunctionExists)
 192 INCLUDE(CheckTypeSize)
 193 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 194 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 195 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 196 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 197 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 198 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 199 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 200 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 201 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 202 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 203 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 204 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 205 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 206 IF (NOT HAVE_XPARSEGEOMETRY)
 207    LIST(APPEND FREEGLUT_SRCS
 208         src/util/xparsegeometry_repl.c
 209         src/util/xparsegeometry_repl.h)
 210    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 211 ENDIF()
 212 # decide on suitable type for internal time keeping, 64-bit if possible
 213 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 214 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 215 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 216     IF (MSVC)
 217         # Some old Microsoft VC don't support unsigned long long, but all we
 218         # care about support unsigned __int64, so test for presence of that
 219         # type
 220         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 221     ELSEIF()
 222         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 223     ENDIF()
 224 ENDIF()
 225
 226
 227 # The generated config.h is placed in the project's build directory, just to
 228 # ensure that all CMake-generated files are kept away from the main source tree.
 229 # As a result, the build directory must to be added to the include path list.
 230 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 231 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 232 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 233 IF(WIN32)
 234     # we also have to generate freeglut.rc, which contains the version
 235     # number
 236     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 237     IF (MSVC AND NOT CMAKE_CL_64)
 238         # .def file only for 32bit Windows builds with Visual Studio
 239         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 240     ENDIF()
 241 ENDIF()
 242
 243 IF(BUILD_SHARED_LIBS)
 244     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 245 ENDIF()
 246 IF(BUILD_STATIC_LIBS)
 247     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 248 ENDIF()
 249
 250
 251 IF(WIN32)
 252     LIST(APPEND LIBS winmm)
 253     IF(BUILD_SHARED_LIBS)
 254         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 255     ENDIF()
 256     IF(BUILD_STATIC_LIBS)
 257         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 258         # need to set machine:x64 for linker, at least for VC10, and
 259         # doesn't hurt for older compilers:
 260         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 261         IF (CMAKE_CL_64)
 262             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 263         ENDIF()
 264     ENDIF()
 265 ELSE()
 266     # on UNIX we need to make sure:
 267     # - all shared libraries must have a soname/version, see :
 268     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 269     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 270     #   Current: -version-info 12:0:9 -> 3.9.0
 271     # - the output library should be named glut so it'll be linkable with -lglut
 272     # - the shared library should link to the dependency libraries so that the user
 273     #   won't have to link them explicitly (they shouldn't have to know that we depend
 274     #   on Xrandr or Xxf86vm)
 275     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 276     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 277     IF(ANDROID)
 278         # Not in CMake toolchain file, because the toolchain
 279         # file is called several times and generally doesn't
 280         # seem to be meant for modifying CFLAGS:
 281         # '-mandroid' is not mandatory but doesn't hurt
 282         # '-O0 -gstabs+' helps the currently buggy GDB port
 283         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 284         # Not using _INIT variables, they seem to be used internally only
 285         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 286         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 287     ENDIF()
 288 ENDIF()
 289 IF(BUILD_SHARED_LIBS)
 290     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 291 ENDIF()
 292 IF(BUILD_STATIC_LIBS)
 293     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 294 ENDIF()
 295
 296 IF(BUILD_SHARED_LIBS)
 297     INSTALL(TARGETS freeglut DESTINATION lib)
 298 ENDIF()
 299 IF(BUILD_STATIC_LIBS)
 300     INSTALL(TARGETS freeglut_static DESTINATION lib)
 301 ENDIF()
 302 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 303
 304
 305
 306 # Optionally build demos, on by default.
 307 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 308
 309 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 310 # lib m for math, not needed on windows
 311 IF (NOT WIN32)
 312     LIST(APPEND DEMO_LIBS m)
 313 ENDIF()
 314
 315 MACRO(ADD_DEMO name)
 316     IF( FREEGLUT_BUILD_DEMOS )
 317         IF(BUILD_SHARED_LIBS)
 318             ADD_EXECUTABLE(${name} ${ARGN})
 319             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 320         ENDIF()
 321         IF(BUILD_STATIC_LIBS)
 322             ADD_EXECUTABLE(${name}_static ${ARGN})
 323             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 324             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 325         ENDIF()
 326     ENDIF()
 327 ENDMACRO()
 328
 329 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 330 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 331 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 332 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 333 ADD_DEMO(One             progs/demos/One/one.c)
 334 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 335 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 336 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 337 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 338                          progs/demos/spaceball/vmath.c
 339                          progs/demos/spaceball/vmath.h)
 340 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 341 ADD_DEMO(timer           progs/demos/timer/timer.c)
 342
 343 # finally, if any demos are built, copy needed files to output directory
 344 # (currently, thats just the input file for the Fractals demo)
 345 IF(FREEGLUT_BUILD_DEMOS)
 346     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 347     IF(BUILD_SHARED_LIBS)
 348         SET(Frac_target Fractals)
 349     ELSE()
 350         SET(Frac_target Fractals_static)
 351     ENDIF()
 352     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 353     ADD_CUSTOM_COMMAND(
 354         TARGET ${Frac_target}
 355         POST_BUILD
 356         COMMAND ${CMAKE_COMMAND} -E copy
 357         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 358         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 359     )
 360 ENDIF()
 361
 362 # pkg-config support, to install at $(libdir)/pkgconfig
 363 # Define static build dependencies
 364 IF(WIN32)
 365   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32")
 366 ELSEIF(FREEGLUT_GLES2)
 367   IF(ANDROID)
 368     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL")
 369   ELSE()
 370     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL")
 371   ENDIF()
 372 ELSEIF(FREEGLUT_GLES1)
 373   IF(ANDROID)
 374     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL")
 375   ELSE()
 376     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL")
 377   ENDIF()
 378 ELSE()
 379   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL")
 380 ENDIF()
 381 # Client applications need to define FreeGLUT GLES version to
 382 # bootstrap headers inclusion in freeglut_std.h:
 383 IF(FREEGLUT_GLES2)
 384   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 385 ELSEIF(FREEGLUT_GLES1)
 386   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 387 ENDIF()
 388 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 389 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig)
 390 # TODO: change the library and .pc name when building for GLES,
 391 # e.g. -lglut-GLES2