git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8 FATAL_ERROR)
   2 PROJECT(freeglut)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms.
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  14
  15 # setup version numbers
  16 # TODO: Update these for each release!
  17 set(VERSION_MAJOR 3)
  18 set(VERSION_MINOR 0)
  19 set(VERSION_PATCH 0)
  20
  21
  22 # FREEGLUT_BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  23 # re-declare it here so it will show up in the GUI.
  24 # by default, we want to build both
  25 OPTION(FREEGLUT_BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  26 OPTION(FREEGLUT_BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  27
  28 # option for whether warnings and errors should be printed
  29 OPTION(FREEGLUT_PRINT_ERRORS "Lib prints errors to stderr" ON)
  30 #MARK_AS_ADVANCED(FREEGLUT_PRINT_ERRORS)
  31 OPTION(FREEGLUT_PRINT_WARNINGS "Lib prints warnings to stderr" ON)
  32 #MARK_AS_ADVANCED(FREEGLUT_PRINT_WARNINGS)
  33
  34 # option to also copy .pdb files to install directory when executing
  35 # INSTALL target
  36 IF(MSVC)
  37     OPTION(INSTALL_PDB "Also install .pdb files" ON)
  38 ELSE()
  39     SET(INSTALL_PDB OFF)
  40 ENDIF()
  41
  42 # OpenGL ES support
  43 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  44 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  45
  46
  47
  48 SET(FREEGLUT_HEADERS
  49     include/GL/freeglut.h
  50     include/GL/freeglut_ext.h
  51     include/GL/freeglut_std.h
  52     include/GL/glut.h
  53 )
  54 SET(FREEGLUT_SRCS
  55     ${FREEGLUT_HEADERS}
  56     src/fg_callbacks.c
  57     src/fg_cursor.c
  58     src/fg_display.c
  59     src/fg_ext.c
  60     src/fg_font_data.c
  61     src/fg_gamemode.c
  62     src/fg_geometry.c
  63     src/fg_gl2.c
  64     src/fg_gl2.h
  65     src/fg_init.c
  66     src/fg_init.h
  67     src/fg_internal.h
  68     src/fg_input_devices.c
  69     src/fg_joystick.c
  70     src/fg_main.c
  71     src/fg_misc.c
  72     src/fg_overlay.c
  73     src/fg_spaceball.c
  74     src/fg_state.c
  75     src/fg_stroke_mono_roman.c
  76     src/fg_stroke_roman.c
  77     src/fg_structure.c
  78     src/fg_teapot.c
  79     src/fg_teapot_data.h
  80     src/fg_videoresize.c
  81     src/fg_window.c
  82 )
  83 # TODO: OpenGL ES requires a compatible version of these files:
  84 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  85     LIST(APPEND FREEGLUT_SRCS
  86         src/fg_font.c
  87         src/fg_menu.c
  88     )
  89 ELSE()
  90     LIST(APPEND FREEGLUT_SRCS
  91         src/gles_stubs.c
  92     )
  93 ENDIF()
  94
  95 IF(WIN32)
  96     LIST(APPEND FREEGLUT_SRCS
  97         src/mswin/fg_cursor_mswin.c
  98         src/mswin/fg_display_mswin.c
  99         src/mswin/fg_ext_mswin.c
 100         src/mswin/fg_gamemode_mswin.c
 101         src/mswin/fg_init_mswin.c
 102         src/mswin/fg_internal_mswin.h
 103         src/mswin/fg_input_devices_mswin.c
 104         src/mswin/fg_joystick_mswin.c
 105         src/mswin/fg_main_mswin.c
 106         src/mswin/fg_menu_mswin.c
 107         src/mswin/fg_spaceball_mswin.c
 108         src/mswin/fg_state_mswin.c
 109         src/mswin/fg_structure_mswin.c
 110         src/mswin/fg_window_mswin.c
 111         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
 112     )
 113     IF (MSVC AND NOT CMAKE_CL_64)
 114         # .def file only for 32bit Windows builds (TODO: MSVC only right
 115         # now, needed for any other Windows platform?)
 116         LIST(APPEND FREEGLUT_SRCS
 117             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
 118         )
 119     ENDIF()
 120
 121 ELSEIF(ANDROID OR BLACKBERRY)
 122     LIST(APPEND FREEGLUT_SRCS
 123         src/android/fg_cursor_android.c
 124         src/android/fg_ext_android.c
 125         src/android/fg_gamemode_android.c
 126         src/android/fg_joystick_android.c
 127         src/android/fg_spaceball_android.c
 128         src/android/fg_structure_android.c
 129     )
 130     IF(ANDROID)
 131         LIST(APPEND FREEGLUT_SRCS
 132             src/android/native_app_glue/android_native_app_glue.c
 133             src/android/native_app_glue/android_native_app_glue.h
 134             src/android/fg_init_android.c
 135             src/android/fg_internal_android.h
 136             src/android/fg_input_devices_android.c
 137             src/android/fg_main_android.c
 138             src/android/fg_main_android.h
 139             src/android/fg_runtime_android.c
 140             src/android/fg_state_android.c
 141             src/android/fg_window_android.c
 142         )
 143     ELSE()
 144         LIST(APPEND FREEGLUT_SRCS
 145             src/blackberry/fg_init_blackberry.c
 146             src/blackberry/fg_internal_blackberry.h
 147             src/x11/fg_input_devices_x11.c
 148             src/blackberry/fg_main_blackberry.c
 149             src/blackberry/fg_state_blackberry.c
 150             src/blackberry/fg_window_blackberry.c
 151         )
 152     ENDIF()
 153 ELSE()
 154     LIST(APPEND FREEGLUT_SRCS
 155         src/x11/fg_cursor_x11.c
 156         src/x11/fg_ext_x11.c
 157         src/x11/fg_gamemode_x11.c
 158         src/x11/fg_glutfont_definitions_x11.c
 159         src/x11/fg_init_x11.c
 160         src/x11/fg_internal_x11.h
 161         src/x11/fg_input_devices_x11.c
 162         src/x11/fg_joystick_x11.c
 163         src/x11/fg_main_x11.c
 164         src/x11/fg_menu_x11.c
 165         src/x11/fg_spaceball_x11.c
 166         src/x11/fg_state_x11.c
 167         src/x11/fg_structure_x11.c
 168         src/x11/fg_window_x11.c
 169         src/x11/fg_xinput_x11.c
 170     )
 171     IF(NOT(FREEGLUT_GLES2 OR FREEGLUT_GLES1))
 172         LIST(APPEND FREEGLUT_SRCS
 173             src/x11/fg_internal_x11_glx.h
 174             src/x11/fg_display_x11_glx.c
 175             src/x11/fg_state_x11_glx.c
 176             src/x11/fg_state_x11_glx.h
 177             src/x11/fg_window_x11_glx.c
 178             src/x11/fg_window_x11_glx.h
 179         )
 180     ENDIF()
 181 ENDIF()
 182 IF(FREEGLUT_GLES2 OR FREEGLUT_GLES1)
 183     LIST(APPEND FREEGLUT_SRCS
 184         src/egl/fg_internal_egl.h
 185         src/egl/fg_display_egl.c
 186         src/egl/fg_ext_egl.c
 187         src/egl/fg_init_egl.c
 188         src/egl/fg_init_egl.h
 189         src/egl/fg_state_egl.c
 190         src/egl/fg_state_egl.h
 191         src/egl/fg_structure_egl.c
 192         src/egl/fg_structure_egl.h
 193         src/egl/fg_window_egl.c
 194         src/egl/fg_window_egl.h
 195     )
 196 ENDIF()
 197
 198 # For OpenGL ES (GLES):
 199 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 200 #   bootstrap headers inclusion in freeglut_std.h; these constants
 201 #   also need to be defined in client applications (e.g. through
 202 #   pkg-config), but use GLES constants directly for all other needs
 203 # - define GLES version-specific library
 204 IF(FREEGLUT_GLES2)
 205   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 206   LIST(APPEND LIBS GLESv2 EGL)
 207 ELSEIF(FREEGLUT_GLES1)
 208   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 209   LIST(APPEND LIBS GLESv1_CM EGL)
 210 ELSE()
 211   FIND_PACKAGE(OpenGL REQUIRED)
 212   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 213   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 214 ENDIF()
 215
 216 # lib m for math, not needed on windows
 217 IF (NOT WIN32)
 218     # For compilation:
 219     LIST(APPEND LIBS m)
 220     # For CHECK_FUNCTION_EXISTS:
 221     LIST(APPEND CMAKE_REQUIRED_LIBRARIES m)
 222 ENDIF()
 223
 224 IF(WIN32)
 225     # hide insecure CRT warnings, common practice
 226     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 227     IF(MSVC)
 228         SET( CMAKE_DEBUG_POSTFIX "d" )
 229     ENDIF(MSVC)
 230
 231 ENDIF()
 232
 233 IF(CMAKE_COMPILER_IS_GNUCC)
 234   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 235   IF(NOT(ANDROID OR BLACKBERRY))
 236     # not setting -ansi as EGL/KHR headers doesn't support it
 237     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ansi")
 238   ENDIF()
 239 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 240
 241 INCLUDE(CheckIncludeFiles)
 242 IF(UNIX AND NOT(ANDROID OR BLACKBERRY))
 243     FIND_PACKAGE(X11 REQUIRED)
 244     LIST(APPEND LIBS ${X11_LIBRARIES})
 245     IF(X11_Xrandr_FOUND)
 246         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 247         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 248     ENDIF()
 249     IF(X11_xf86vmode_FOUND)
 250         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 251         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 252         IF(NOT "${X11_Xxf86vm_LIB}")
 253             SET(X11_Xxf86vm_LIB "Xxf86vm")
 254         ENDIF()
 255         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 256     ENDIF()
 257     IF(X11_Xinput_FOUND)
 258         # Needed for multi-touch:
 259         CHECK_INCLUDE_FILES("${X11_Xinput_INCLUDE_PATH}/X11/extensions/XInput2.h" HAVE_X11_EXTENSIONS_XINPUT2_H)
 260         LIST(APPEND LIBS ${X11_Xinput_LIB})
 261     ENDIF()
 262 ENDIF()
 263 IF(ANDROID)
 264     # -landroid for ANativeWindow
 265     # -llog for native Android logging
 266     LIST(APPEND LIBS android log)
 267 ELSEIF(BLACKBERRY)
 268     # -lbps for event loop
 269     # -lslog2 for logging
 270     # -screen for native screen
 271     LIST(APPEND LIBS bps slog2 screen)
 272 ENDIF()
 273
 274 INCLUDE(CheckFunctionExists)
 275 INCLUDE(CheckTypeSize)
 276 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 277 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 278 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 279 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 280 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 281 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 282 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 283 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 284 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 285 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 286 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 287 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 288 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 289 IF (NOT HAVE_XPARSEGEOMETRY)
 290    LIST(APPEND FREEGLUT_SRCS
 291         src/util/xparsegeometry_repl.c
 292         src/util/xparsegeometry_repl.h)
 293    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 294 ENDIF()
 295 # decide on suitable type for internal time keeping, 64-bit if possible
 296 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 297 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 298 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 299     IF (MSVC)
 300         # Some old Microsoft VC releases don't support unsigned long
 301         # long, but all we care about is support for unsigned __int64 on
 302         # MSVC, so test for presence of that type
 303         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 304     ELSEIF()
 305         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 306     ENDIF()
 307 ENDIF()
 308
 309 # The generated config.h is placed in the project's build directory, just to
 310 # ensure that all CMake-generated files are kept away from the main source tree.
 311 # As a result, the build directory must to be added to the include path list.
 312 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 313 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 314 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 315 IF(WIN32)
 316     # we also have to generate freeglut.rc, which contains the version
 317     # number
 318     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 319     IF (MSVC AND NOT CMAKE_CL_64)
 320         # .def file only for 32bit Windows builds with Visual Studio
 321         CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 322     ENDIF()
 323 ENDIF()
 324
 325 IF(FREEGLUT_BUILD_SHARED_LIBS)
 326     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 327 ENDIF()
 328 IF(FREEGLUT_BUILD_STATIC_LIBS)
 329     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 330 ENDIF()
 331
 332
 333 IF(WIN32)
 334     LIST(APPEND LIBS winmm)
 335     IF(FREEGLUT_BUILD_SHARED_LIBS)
 336         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 337     ENDIF()
 338     IF(FREEGLUT_BUILD_STATIC_LIBS)
 339         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 340         # need to set machine:x64 for linker, at least for VC10, and
 341         # doesn't hurt for older compilers:
 342         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 343         IF (CMAKE_CL_64)
 344             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 345         ENDIF()
 346     ENDIF()
 347 ELSE()
 348     # on UNIX we need to make sure:
 349     # - all shared libraries must have a soname/version, see :
 350     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 351     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 352     #   Current: -version-info 12:0:9 -> 3.9.0
 353     #   Note: most platforms now prefer the latter major.minor.revision form
 354     #   (e.g. FreeBSD, cf. http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8765),
 355     #   or special-cased FreeGLUT long ago (e.g. .so.4 on OpenBSD), so
 356     #   the lack of support for current:revision:age in CMake should
 357     #   not be a problem.
 358     # - the output library should be named glut so it'll be linkable with -lglut
 359     # - the shared library should link to the dependency libraries so that the user
 360     #   won't have to link them explicitly (they shouldn't have to know that we depend
 361     #   on Xrandr or Xxf86vm)
 362     IF(FREEGLUT_GLES2)
 363       SET(LIBNAME freeglut-gles2)
 364     ELSEIF(FREEGLUT_GLES1)
 365       SET(LIBNAME freeglut-gles1)
 366     ELSE()
 367       SET(LIBNAME glut)
 368     ENDIF()
 369
 370     IF(FREEGLUT_BUILD_SHARED_LIBS)
 371       SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME ${LIBNAME})
 372     ENDIF()
 373     IF(FREEGLUT_BUILD_STATIC_LIBS)
 374       SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME ${LIBNAME})
 375     ENDIF()
 376     IF(ANDROID)
 377         # Not in CMake toolchain file, because the toolchain
 378         # file is called several times and generally doesn't
 379         # seem to be meant for modifying CFLAGS:
 380         # '-mandroid' is not mandatory but doesn't hurt
 381         # '-O0 -gstabs+' helps the currently buggy GDB port
 382         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 383         # Not using _INIT variables, they seem to be used internally only
 384         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 385         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 386     ENDIF()
 387 ENDIF()
 388 IF(FREEGLUT_BUILD_SHARED_LIBS)
 389     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 390 ENDIF()
 391 IF(FREEGLUT_BUILD_STATIC_LIBS)
 392     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 393 ENDIF()
 394
 395 IF(FREEGLUT_BUILD_SHARED_LIBS)
 396     INSTALL(TARGETS freeglut
 397             RUNTIME DESTINATION bin
 398             LIBRARY DESTINATION lib
 399             ARCHIVE DESTINATION lib
 400     )
 401     IF(INSTALL_PDB)
 402         INSTALL(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Debug/freeglut${CMAKE_DEBUG_POSTFIX}.pdb
 403             DESTINATION bin
 404                         CONFIGURATIONS Debug)
 405     ENDIF()
 406 ENDIF()
 407 IF(FREEGLUT_BUILD_STATIC_LIBS)
 408     INSTALL(TARGETS freeglut_static
 409             RUNTIME DESTINATION bin
 410             LIBRARY DESTINATION lib
 411             ARCHIVE DESTINATION lib
 412     )
 413     IF(INSTALL_PDB)
 414         INSTALL(FILES ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/Debug/freeglut_static${CMAKE_DEBUG_POSTFIX}.pdb
 415             DESTINATION lib
 416                         CONFIGURATIONS Debug)
 417     ENDIF()
 418 ENDIF()
 419 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 420
 421
 422
 423 # Optionally build demos, on by default.
 424 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 425
 426 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 427 # lib m for math, not needed on windows
 428 IF (NOT WIN32)
 429     LIST(APPEND DEMO_LIBS m)
 430 ENDIF()
 431
 432 MACRO(ADD_DEMO name)
 433     IF( FREEGLUT_BUILD_DEMOS )
 434         IF(FREEGLUT_BUILD_SHARED_LIBS)
 435             ADD_EXECUTABLE(${name} ${ARGN})
 436             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 437             IF(WIN32 AND MSVC)
 438                 SET_TARGET_PROPERTIES(${name} PROPERTIES DEBUG_POSTFIX d)
 439             ENDIF()
 440         ENDIF()
 441         IF(FREEGLUT_BUILD_STATIC_LIBS)
 442             ADD_EXECUTABLE(${name}_static ${ARGN})
 443             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 444             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 445             IF(WIN32 AND MSVC)
 446                 SET_TARGET_PROPERTIES(${name}_static PROPERTIES DEBUG_POSTFIX d)
 447             ENDIF()
 448         ENDIF()
 449     ENDIF()
 450 ENDMACRO()
 451
 452 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 453 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 454 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 455 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 456 IF (NOT WIN32)
 457     ADD_DEMO(One             progs/demos/One/one.c)
 458 ELSE()
 459     ADD_DEMO(One             progs/demos/One/one.c
 460                              progs/demos/One/one.rc)
 461 ENDIF()
 462 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 463 ADD_DEMO(multi-touch     progs/demos/multi-touch/multi-touch.c)
 464 ADD_DEMO(shapes          progs/demos/shapes/shapes.c
 465                          progs/demos/shapes/glmatrix.h
 466                          progs/demos/shapes/glmatrix.c)
 467 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 468 IF(UNIX)
 469     ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 470                              progs/demos/spaceball/vmath.c
 471                              progs/demos/spaceball/vmath.h)
 472 ENDIF()
 473 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 474 ADD_DEMO(timer           progs/demos/timer/timer.c)
 475
 476
 477
 478 # pkg-config support, to install at $(libdir)/pkgconfig
 479 # Define static build dependencies
 480 IF(WIN32)
 481   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32 -lm")
 482 ELSEIF(FREEGLUT_GLES2)
 483   IF(ANDROID)
 484     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL -lm")
 485   ELSEIF(BLACKBERRY)
 486     SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lscreen -lGLESv2 -lEGL -lm")
 487   ELSE()
 488     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL -lm")
 489   ENDIF()
 490 ELSEIF(FREEGLUT_GLES1)
 491   IF(ANDROID)
 492     SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv1_CM -lEGL -lm")
 493   ELSEIF(BLACKBERRY)
 494     SET(PC_LIBS_PRIVATE "-lbps -lslog2 -lscreen -lGLESv1_CM -lEGL -lm")
 495   ELSE()
 496     SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv1_CM -lEGL -lm")
 497   ENDIF()
 498 ELSE()
 499   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGL -lm")
 500 ENDIF()
 501 # Client applications need to define FreeGLUT GLES version to
 502 # bootstrap headers inclusion in freeglut_std.h:
 503 SET(PC_LIBNAME "glut")
 504 SET(PC_FILENAME "freeglut.pc")
 505 IF(FREEGLUT_GLES2)
 506   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 507   SET(PC_LIBNAME "freeglut-gles2")
 508   SET(PC_FILENAME "freeglut-gles2.pc")
 509 ELSEIF(FREEGLUT_GLES1)
 510   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 511   SET(PC_LIBNAME "freeglut-gles1")
 512   SET(PC_FILENAME "freeglut-gles1.pc")
 513 ENDIF()
 514 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 515 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig/ RENAME ${PC_FILENAME})
 516 # TODO: change the library and .pc name when building for GLES,
 517 # e.g. -lglut-GLES2