git.mutantstargoat.com Git - faros-demo/blob - glsl-noise/periodic/4d.glsl

   1 //
   2 // GLSL textureless classic 4D noise "cnoise",
   3 // with an RSL-style periodic variant "pnoise".
   4 // Author:  Stefan Gustavson (stefan.gustavson@liu.se)
   5 // Version: 2011-08-22
   6 //
   7 // Many thanks to Ian McEwan of Ashima Arts for the
   8 // ideas for permutation and gradient selection.
   9 //
  10 // Copyright (c) 2011 Stefan Gustavson. All rights reserved.
  11 // Distributed under the MIT license. See LICENSE file.
  12 // https://github.com/ashima/webgl-noise
  13 //
  14
  15 vec4 mod289(vec4 x)
  16 {
  17   return x - floor(x * (1.0 / 289.0)) * 289.0;
  18 }
  19
  20 vec4 permute(vec4 x)
  21 {
  22   return mod289(((x*34.0)+1.0)*x);
  23 }
  24
  25 vec4 taylorInvSqrt(vec4 r)
  26 {
  27   return 1.79284291400159 - 0.85373472095314 * r;
  28 }
  29
  30 vec4 fade(vec4 t) {
  31   return t*t*t*(t*(t*6.0-15.0)+10.0);
  32 }
  33
  34 // Classic Perlin noise, periodic version
  35 float pnoise(vec4 P, vec4 rep)
  36 {
  37   vec4 Pi0 = mod(floor(P), rep); // Integer part modulo rep
  38   vec4 Pi1 = mod(Pi0 + 1.0, rep); // Integer part + 1 mod rep
  39   Pi0 = mod289(Pi0);
  40   Pi1 = mod289(Pi1);
  41   vec4 Pf0 = fract(P); // Fractional part for interpolation
  42   vec4 Pf1 = Pf0 - 1.0; // Fractional part - 1.0
  43   vec4 ix = vec4(Pi0.x, Pi1.x, Pi0.x, Pi1.x);
  44   vec4 iy = vec4(Pi0.yy, Pi1.yy);
  45   vec4 iz0 = vec4(Pi0.zzzz);
  46   vec4 iz1 = vec4(Pi1.zzzz);
  47   vec4 iw0 = vec4(Pi0.wwww);
  48   vec4 iw1 = vec4(Pi1.wwww);
  49
  50   vec4 ixy = permute(permute(ix) + iy);
  51   vec4 ixy0 = permute(ixy + iz0);
  52   vec4 ixy1 = permute(ixy + iz1);
  53   vec4 ixy00 = permute(ixy0 + iw0);
  54   vec4 ixy01 = permute(ixy0 + iw1);
  55   vec4 ixy10 = permute(ixy1 + iw0);
  56   vec4 ixy11 = permute(ixy1 + iw1);
  57
  58   vec4 gx00 = ixy00 * (1.0 / 7.0);
  59   vec4 gy00 = floor(gx00) * (1.0 / 7.0);
  60   vec4 gz00 = floor(gy00) * (1.0 / 6.0);
  61   gx00 = fract(gx00) - 0.5;
  62   gy00 = fract(gy00) - 0.5;
  63   gz00 = fract(gz00) - 0.5;
  64   vec4 gw00 = vec4(0.75) - abs(gx00) - abs(gy00) - abs(gz00);
  65   vec4 sw00 = step(gw00, vec4(0.0));
  66   gx00 -= sw00 * (step(0.0, gx00) - 0.5);
  67   gy00 -= sw00 * (step(0.0, gy00) - 0.5);
  68
  69   vec4 gx01 = ixy01 * (1.0 / 7.0);
  70   vec4 gy01 = floor(gx01) * (1.0 / 7.0);
  71   vec4 gz01 = floor(gy01) * (1.0 / 6.0);
  72   gx01 = fract(gx01) - 0.5;
  73   gy01 = fract(gy01) - 0.5;
  74   gz01 = fract(gz01) - 0.5;
  75   vec4 gw01 = vec4(0.75) - abs(gx01) - abs(gy01) - abs(gz01);
  76   vec4 sw01 = step(gw01, vec4(0.0));
  77   gx01 -= sw01 * (step(0.0, gx01) - 0.5);
  78   gy01 -= sw01 * (step(0.0, gy01) - 0.5);
  79
  80   vec4 gx10 = ixy10 * (1.0 / 7.0);
  81   vec4 gy10 = floor(gx10) * (1.0 / 7.0);
  82   vec4 gz10 = floor(gy10) * (1.0 / 6.0);
  83   gx10 = fract(gx10) - 0.5;
  84   gy10 = fract(gy10) - 0.5;
  85   gz10 = fract(gz10) - 0.5;
  86   vec4 gw10 = vec4(0.75) - abs(gx10) - abs(gy10) - abs(gz10);
  87   vec4 sw10 = step(gw10, vec4(0.0));
  88   gx10 -= sw10 * (step(0.0, gx10) - 0.5);
  89   gy10 -= sw10 * (step(0.0, gy10) - 0.5);
  90
  91   vec4 gx11 = ixy11 * (1.0 / 7.0);
  92   vec4 gy11 = floor(gx11) * (1.0 / 7.0);
  93   vec4 gz11 = floor(gy11) * (1.0 / 6.0);
  94   gx11 = fract(gx11) - 0.5;
  95   gy11 = fract(gy11) - 0.5;
  96   gz11 = fract(gz11) - 0.5;
  97   vec4 gw11 = vec4(0.75) - abs(gx11) - abs(gy11) - abs(gz11);
  98   vec4 sw11 = step(gw11, vec4(0.0));
  99   gx11 -= sw11 * (step(0.0, gx11) - 0.5);
 100   gy11 -= sw11 * (step(0.0, gy11) - 0.5);
 101
 102   vec4 g0000 = vec4(gx00.x,gy00.x,gz00.x,gw00.x);
 103   vec4 g1000 = vec4(gx00.y,gy00.y,gz00.y,gw00.y);
 104   vec4 g0100 = vec4(gx00.z,gy00.z,gz00.z,gw00.z);
 105   vec4 g1100 = vec4(gx00.w,gy00.w,gz00.w,gw00.w);
 106   vec4 g0010 = vec4(gx10.x,gy10.x,gz10.x,gw10.x);
 107   vec4 g1010 = vec4(gx10.y,gy10.y,gz10.y,gw10.y);
 108   vec4 g0110 = vec4(gx10.z,gy10.z,gz10.z,gw10.z);
 109   vec4 g1110 = vec4(gx10.w,gy10.w,gz10.w,gw10.w);
 110   vec4 g0001 = vec4(gx01.x,gy01.x,gz01.x,gw01.x);
 111   vec4 g1001 = vec4(gx01.y,gy01.y,gz01.y,gw01.y);
 112   vec4 g0101 = vec4(gx01.z,gy01.z,gz01.z,gw01.z);
 113   vec4 g1101 = vec4(gx01.w,gy01.w,gz01.w,gw01.w);
 114   vec4 g0011 = vec4(gx11.x,gy11.x,gz11.x,gw11.x);
 115   vec4 g1011 = vec4(gx11.y,gy11.y,gz11.y,gw11.y);
 116   vec4 g0111 = vec4(gx11.z,gy11.z,gz11.z,gw11.z);
 117   vec4 g1111 = vec4(gx11.w,gy11.w,gz11.w,gw11.w);
 118
 119   vec4 norm00 = taylorInvSqrt(vec4(dot(g0000, g0000), dot(g0100, g0100), dot(g1000, g1000), dot(g1100, g1100)));
 120   g0000 *= norm00.x;
 121   g0100 *= norm00.y;
 122   g1000 *= norm00.z;
 123   g1100 *= norm00.w;
 124
 125   vec4 norm01 = taylorInvSqrt(vec4(dot(g0001, g0001), dot(g0101, g0101), dot(g1001, g1001), dot(g1101, g1101)));
 126   g0001 *= norm01.x;
 127   g0101 *= norm01.y;
 128   g1001 *= norm01.z;
 129   g1101 *= norm01.w;
 130
 131   vec4 norm10 = taylorInvSqrt(vec4(dot(g0010, g0010), dot(g0110, g0110), dot(g1010, g1010), dot(g1110, g1110)));
 132   g0010 *= norm10.x;
 133   g0110 *= norm10.y;
 134   g1010 *= norm10.z;
 135   g1110 *= norm10.w;
 136
 137   vec4 norm11 = taylorInvSqrt(vec4(dot(g0011, g0011), dot(g0111, g0111), dot(g1011, g1011), dot(g1111, g1111)));
 138   g0011 *= norm11.x;
 139   g0111 *= norm11.y;
 140   g1011 *= norm11.z;
 141   g1111 *= norm11.w;
 142
 143   float n0000 = dot(g0000, Pf0);
 144   float n1000 = dot(g1000, vec4(Pf1.x, Pf0.yzw));
 145   float n0100 = dot(g0100, vec4(Pf0.x, Pf1.y, Pf0.zw));
 146   float n1100 = dot(g1100, vec4(Pf1.xy, Pf0.zw));
 147   float n0010 = dot(g0010, vec4(Pf0.xy, Pf1.z, Pf0.w));
 148   float n1010 = dot(g1010, vec4(Pf1.x, Pf0.y, Pf1.z, Pf0.w));
 149   float n0110 = dot(g0110, vec4(Pf0.x, Pf1.yz, Pf0.w));
 150   float n1110 = dot(g1110, vec4(Pf1.xyz, Pf0.w));
 151   float n0001 = dot(g0001, vec4(Pf0.xyz, Pf1.w));
 152   float n1001 = dot(g1001, vec4(Pf1.x, Pf0.yz, Pf1.w));
 153   float n0101 = dot(g0101, vec4(Pf0.x, Pf1.y, Pf0.z, Pf1.w));
 154   float n1101 = dot(g1101, vec4(Pf1.xy, Pf0.z, Pf1.w));
 155   float n0011 = dot(g0011, vec4(Pf0.xy, Pf1.zw));
 156   float n1011 = dot(g1011, vec4(Pf1.x, Pf0.y, Pf1.zw));
 157   float n0111 = dot(g0111, vec4(Pf0.x, Pf1.yzw));
 158   float n1111 = dot(g1111, Pf1);
 159
 160   vec4 fade_xyzw = fade(Pf0);
 161   vec4 n_0w = mix(vec4(n0000, n1000, n0100, n1100), vec4(n0001, n1001, n0101, n1101), fade_xyzw.w);
 162   vec4 n_1w = mix(vec4(n0010, n1010, n0110, n1110), vec4(n0011, n1011, n0111, n1111), fade_xyzw.w);
 163   vec4 n_zw = mix(n_0w, n_1w, fade_xyzw.z);
 164   vec2 n_yzw = mix(n_zw.xy, n_zw.zw, fade_xyzw.y);
 165   float n_xyzw = mix(n_yzw.x, n_yzw.y, fade_xyzw.x);
 166   return 2.2 * n_xyzw;
 167 }
 168
 169 #pragma glslify: export(pnoise)