git.mutantstargoat.com Git - faros-demo/blob - glsl-noise/simplex/3d.glsl

   1 //
   2 // Description : Array and textureless GLSL 2D/3D/4D simplex
   3 //               noise functions.
   4 //      Author : Ian McEwan, Ashima Arts.
   5 //  Maintainer : ijm
   6 //     Lastmod : 20110822 (ijm)
   7 //     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
   8 //               Distributed under the MIT License. See LICENSE file.
   9 //               https://github.com/ashima/webgl-noise
  10 //
  11
  12 vec3 mod289(vec3 x) {
  13   return x - floor(x * (1.0 / 289.0)) * 289.0;
  14 }
  15
  16 vec4 mod289(vec4 x) {
  17   return x - floor(x * (1.0 / 289.0)) * 289.0;
  18 }
  19
  20 vec4 permute(vec4 x) {
  21      return mod289(((x*34.0)+1.0)*x);
  22 }
  23
  24 vec4 taylorInvSqrt(vec4 r)
  25 {
  26   return 1.79284291400159 - 0.85373472095314 * r;
  27 }
  28
  29 float snoise(vec3 v)
  30   {
  31   const vec2  C = vec2(1.0/6.0, 1.0/3.0) ;
  32   const vec4  D = vec4(0.0, 0.5, 1.0, 2.0);
  33
  34 // First corner
  35   vec3 i  = floor(v + dot(v, C.yyy) );
  36   vec3 x0 =   v - i + dot(i, C.xxx) ;
  37
  38 // Other corners
  39   vec3 g = step(x0.yzx, x0.xyz);
  40   vec3 l = 1.0 - g;
  41   vec3 i1 = min( g.xyz, l.zxy );
  42   vec3 i2 = max( g.xyz, l.zxy );
  43
  44   //   x0 = x0 - 0.0 + 0.0 * C.xxx;
  45   //   x1 = x0 - i1  + 1.0 * C.xxx;
  46   //   x2 = x0 - i2  + 2.0 * C.xxx;
  47   //   x3 = x0 - 1.0 + 3.0 * C.xxx;
  48   vec3 x1 = x0 - i1 + C.xxx;
  49   vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
  50   vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y
  51
  52 // Permutations
  53   i = mod289(i);
  54   vec4 p = permute( permute( permute(
  55              i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
  56            + i.y + vec4(0.0, i1.y, i2.y, 1.0 ))
  57            + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));
  58
  59 // Gradients: 7x7 points over a square, mapped onto an octahedron.
  60 // The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
  61   float n_ = 0.142857142857; // 1.0/7.0
  62   vec3  ns = n_ * D.wyz - D.xzx;
  63
  64   vec4 j = p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)
  65
  66   vec4 x_ = floor(j * ns.z);
  67   vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)
  68
  69   vec4 x = x_ *ns.x + ns.yyyy;
  70   vec4 y = y_ *ns.x + ns.yyyy;
  71   vec4 h = 1.0 - abs(x) - abs(y);
  72
  73   vec4 b0 = vec4( x.xy, y.xy );
  74   vec4 b1 = vec4( x.zw, y.zw );
  75
  76   //vec4 s0 = vec4(lessThan(b0,0.0))*2.0 - 1.0;
  77   //vec4 s1 = vec4(lessThan(b1,0.0))*2.0 - 1.0;
  78   vec4 s0 = floor(b0)*2.0 + 1.0;
  79   vec4 s1 = floor(b1)*2.0 + 1.0;
  80   vec4 sh = -step(h, vec4(0.0));
  81
  82   vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
  83   vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;
  84
  85   vec3 p0 = vec3(a0.xy,h.x);
  86   vec3 p1 = vec3(a0.zw,h.y);
  87   vec3 p2 = vec3(a1.xy,h.z);
  88   vec3 p3 = vec3(a1.zw,h.w);
  89
  90 //Normalise gradients
  91   vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
  92   p0 *= norm.x;
  93   p1 *= norm.y;
  94   p2 *= norm.z;
  95   p3 *= norm.w;
  96
  97 // Mix final noise value
  98   vec4 m = max(0.6 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
  99   m = m * m;
 100   return 42.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1),
 101                                 dot(p2,x2), dot(p3,x3) ) );
 102   }
 103
 104 #pragma glslify: export(snoise)