# along with this program. If not, see <https://www.gnu.org/licenses/>.
# this is the second-stage boot loader
+# plus some other code that needs to run below 1mb (int86 implementation).
+
.code16
.section .boot2,"ax"
# just in case we were loaded from floppy, turn all floppy motors off
mov $0x3f2, %dx
in %dx, %al
- and $0xf0, %al
+ and $0xf, %al
out %al, %dx
mov $10, %ax
numbuf: .space 16
- # sets the carry flag on failure
detect_memory:
+ mov $memdet_e820_msg, %esi
+ call putstr
+ call detect_mem_e820
+ jnc memdet_done
+ mov $rdfail_msg, %esi
+ call putstr
+
+ mov $memdet_e801_msg, %esi
+ call putstr
+ call detect_mem_e801
+ jnc memdet_done
+ mov $rdfail_msg, %esi
+ call putstr
+
+ mov $memdet_88_msg, %esi
+ call putstr
+ call detect_mem_88
+ jnc memdet_done
+ mov $rdfail_msg, %esi
+ call putstr
+
+ # just panic...
+ mov $memdet_fail_msg, %esi
+ call putstr
+0: hlt
+ jmp 0b
+
+memdet_done:
+ mov $rdok_msg, %esi
+ call putstr
+ ret
+
+memdet_fail_msg: .ascii "Failed to detect available memory!\n"
+ .ascii "Please file a bug report: https://github.com/jtsiomb/pcboot/issues\n"
+ .asciz " or contact me through email: nuclear@member.fsf.org\n"
+memdet_e820_msg: .asciz "Detecting RAM (BIOS 15h/0xe820)... "
+memdet_e801_msg: .asciz "Detecting RAM (BIOS 15h/0xe801)... "
+memdet_88_msg: .asciz "Detecting RAM (BIOS 15h/0x88, max 64mb)... "
+
+ # detect extended memory using BIOS call 15h/e820
+detect_mem_e820:
+ movl $0, boot_mem_map_size
+
mov $buffer, %edi
xor %ebx, %ebx
mov $0x534d4150, %edx
-memdet_looptop:
+e820_looptop:
mov $0xe820, %eax
mov $24, %ecx
int $0x15
- jc memdet_fail
+ jc e820_fail
cmp $0x534d4150, %eax
- jnz memdet_fail
+ jnz e820_fail
+
+ # skip areas starting above 4GB as we won't be able to use them
+ cmpl $0, 4(%edi)
+ jnz e820_skip
+
+ # only care for type 1 (usable ram), otherwise ignore
+ cmpl $1, 16(%edi)
+ jnz e820_skip
mov buffer, %eax
mov $boot_mem_map, %esi
# again, that's [ebp * 8 + esi]
mov %eax, (%esi,%ebp,8)
- # only care for type 1 (usable ram), otherwise ignore
- cmpl $1, 16(%edi)
- jnz memdet_skip
-
# skip areas with 0 size (also clamp size to 4gb)
# test high 32bits
cmpl $0, 12(%edi)
- jz memdet_highzero
+ jz e820_highzero
# high part is non-zero, make low part ffffffff
xor %eax, %eax
not %eax
jmp 0f
-memdet_highzero:
+e820_highzero:
# if both high and low parts are zero, ignore
mov 8(%edi), %eax
cmpl $0, %eax
- jz memdet_skip
+ jz e820_skip
0: mov %eax, 4(%esi,%ebp,8)
incl boot_mem_map_size
-memdet_skip:
+e820_skip:
# terminate the loop if ebx was reset to 0
cmp $0, %ebx
- jz memdet_done
- jmp memdet_looptop
+ jz e820_done
+ jmp e820_looptop
-memdet_done:
+e820_done:
+ clc
ret
-memdet_fail:
+e820_fail:
# if size > 0, then it's not a failure, just the end
cmpl $0, boot_mem_map_size
- jnz memdet_done
+ jnz e820_done
- # just panic...
- mov $memdet_fail_msg, %esi
- call putstr
-0: hlt
- jmp 0b
+ stc
+ ret
+
+
+ # detect extended memory using BIOS call 15h/e801
+detect_mem_e801:
+ mov $boot_mem_map, %esi
+ mov boot_mem_map_size, %ebp
+ movl $0, (%ebp)
+
+ xor %cx, %cx
+ xor %dx, %dx
+ mov $0xe801, %ax
+ int $0x15
+ jc e801_fail
+
+ cmp $0, %cx
+ jnz 0f
+ cmp $0, %ax
+ jz e801_fail
+ mov %ax, %cx
+ mov %bx, %dx
+
+0: movl $0x100000, (%esi)
+ movzx %cx, %eax
+ # first size is in KB, convert to bytes
+ shl $10, %eax
+ jnc 0f
+ # overflow means it's >4GB, clamp to 4GB
+ mov $0xffffffff, %eax
+0: mov %eax, 4(%esi)
+ incl boot_mem_map_size
+ cmp $0, %dx
+ jz e801_done
+ movl $0x1000000, 8(%esi)
+ movzx %dx, %eax
+ # second size is in 64kb blocks, convert to bytes
+ shl $16, %eax
+ jnc 0f
+ # overflow means it's >4GB, clamp to 4GB
+ mov $0xffffffff, %eax
+0: mov %eax, 12(%esi)
+ incl boot_mem_map_size
+e801_done:
+ clc
+ ret
+e801_fail:
+ stc
+ ret
+
+detect_mem_88:
+ # reportedly some BIOS implementations fail to clear CF on success
+ clc
+ mov $0x88, %ah
+ int $0x15
+ jc x88_fail
+
+ cmp $0, %ax
+ jz x88_fail
+
+ # ax has size in KB, convert to bytes in eax
+ and $0xffff, %eax
+ shl $10, %eax
+
+ mov $boot_mem_map, %esi
+ movl $0x100000, (%esi)
+ mov %eax, 4(%esi)
+
+ movl $1, boot_mem_map_size
+ clc
+ ret
+
+x88_fail:
+ stc
+ ret
-memdet_fail_msg: .asciz "Failed to detect available memory!\n"
.global boot_mem_map_size
boot_mem_map_size: .long 0
saved_esp: .long 0
saved_ebp: .long 0
+saved_eax: .long 0
+saved_es: .word 0
+saved_ds: .word 0
+saved_flags: .word 0
# drop back to unreal mode to call 16bit interrupt
.global int86
sidt (saved_idtr)
lidt (rmidt)
- # modify the int instruction do this here before the
+ # modify the int instruction. do this here before the
# cs-load jumps, to let them flush the instruction cache
mov $int_op, %ebx
movb 8(%ebp), %al
nop
# load registers from the int86regs struct
+ # point esp to the regs struct to load registers with popa/popf
mov %esp, saved_esp
mov %ebp, saved_ebp
mov 12(%ebp), %esp
popal
+ popfw
+ pop %es
+ pop %ds
+ # ignore fs and gs for now, don't think I'm going to need them
mov saved_esp, %esp
+ # move to the real-mode stack, accessible from ss=0
+ # just in case the BIOS call screws up our unreal mode
+ mov $0x7be0, %esp
+
# call 16bit interrupt
int_op: int $0
+ # BIOS call might have enabled interrupts, cli for good measure
+ cli
- mov saved_ebp, %ebp
- mov 12(%ebp), %esp
- add $34, %esp
+ # save all registers that we'll clobber before having the
+ # chance to populate the int86regs structure
+ mov %eax, saved_eax
+ mov %ds, saved_ds
+ mov %es, saved_es
pushfw
- pushal
- mov saved_esp, %esp
+ pop %ax
+ mov %ax, saved_flags
# re-enable protection
mov %cr0, %eax
mov %ax, %ss
nop
+ # point the esp to our regs struct, to fill it with pusha/pushf
+ mov saved_ebp, %ebp
+ mov 12(%ebp), %esp
+ add $38, %esp
+ mov saved_ds, %ax
+ pushw %ax
+ mov saved_es, %ax
+ pushw %ax
+ mov saved_flags, %ax
+ pushw %ax
+ mov saved_eax, %eax
+ pushal
+ mov saved_esp, %esp
+
# restore 32bit interrupt descriptor table
lidt (saved_idtr)
sti
# buffer used by the track loader ... to load tracks.
.align 16
buffer:
+ .global low_mem_buffer
+low_mem_buffer: