+
+str_read_error: .asciz "Read error while reading track: "
+
+abort_read:
+ mov $str_read_error, %esi
+ call putstr
+ mov cur_track, %eax
+ call print_num
+ mov $10, %al
+ call putchar
+
+ cli
+0: hlt
+ jmp 0b
+
+
+ # better print routines, since we're not constrainted by the 512b of
+ # the boot sector.
+ .global cursor_x
+ .global cursor_y
+cursor_x: .long 0
+cursor_y: .long 0
+
+putchar:
+ pushal
+ call ser_putchar
+
+ cmp $10, %al
+ jnz 0f
+ call video_newline
+ jmp 1f
+
+0: push %eax
+ mov cursor_y, %eax
+ mov $80, %ecx
+ mul %ecx
+ add cursor_x, %eax
+ mov %eax, %ebx
+ pop %eax
+
+ mov $0xb8000, %edx
+
+ # this looks retarded. in nasm: [ebx * 2 + edx]
+ mov %al, (%edx, %ebx, 2)
+ movb $7, 1(%edx, %ebx, 2)
+ incl cursor_x
+ cmpl $80, cursor_x
+ jnz 1f
+ call video_newline
+
+1: popal
+ ret
+
+ # expects string pointer in esi
+putstr:
+ mov (%esi), %al
+ cmp $0, %al
+ jz 0f
+ call putchar
+ inc %esi
+ jmp putstr
+0: ret
+
+ # expects number in eax
+print_num:
+ # save registers
+ pushal
+
+ mov $numbuf + 16, %esi
+ movb $0, (%esi)
+ mov $10, %ebx
+convloop:
+ xor %edx, %edx
+ div %ebx
+ add $48, %dl
+ dec %esi
+ mov %dl, (%esi)
+ cmp $0, %eax
+ jnz convloop
+
+ call putstr
+
+ # restore regs
+ popal
+ ret
+
+
+video_newline:
+ movl $0, cursor_x
+ incl cursor_y
+ cmpl $25, cursor_y
+ jnz 0f
+ call scrollup
+ decl cursor_y
+0: ret
+
+scrollup:
+ pushal
+ # move 80 * 24 lines from b80a0 -> b8000
+ mov $0xb8000, %edi
+ mov $0xb80a0, %esi
+ mov $960, %ecx
+ addr32 rep movsl
+ # clear last line (b8f00)
+ mov $0xb8f00, %edi
+ xor %eax, %eax
+ mov $40, %ecx
+ addr32 rep stosl
+ popal
+ ret
+
+clearscr:
+ mov $0xb8000, %edi
+ # clear with white-on-black spaces
+ mov $0x07200720, %eax
+ mov $1000, %ecx
+ addr32 rep stosl
+ ret
+
+ .set UART_DATA, 0x3f8
+ .set UART_DIVLO, 0x3f8
+ .set UART_DIVHI, 0x3f9
+ .set UART_FIFO, 0x3fa
+ .set UART_LCTL, 0x3fb
+ .set UART_MCTL, 0x3fc
+ .set UART_LSTAT, 0x3fd
+ .set DIV_9600, 115200 / 9600
+ .set LCTL_8N1, 0x03
+ .set LCTL_DLAB, 0x80
+ .set FIFO_ENABLE_CLEAR, 0x07
+ .set MCTL_DTR_RTS_OUT2, 0x0b
+ .set LST_TREG_EMPTY, 0x20
+
+setup_serial:
+ # set clock divisor
+ mov $LCTL_DLAB, %al
+ mov $UART_LCTL, %dx
+ out %al, %dx
+ mov $DIV_9600, %ax
+ mov $UART_DIVLO, %dx
+ out %al, %dx
+ shr $8, %ax
+ mov $UART_DIVHI, %dx
+ out %al, %dx
+ # set format 8n1
+ mov $LCTL_8N1, %al
+ mov $UART_LCTL, %dx
+ out %al, %dx
+ # clear and enable fifo
+ mov $FIFO_ENABLE_CLEAR, %al
+ mov $UART_FIFO, %dx
+ out %al, %dx
+ # assert RTS and DTR
+ mov $MCTL_DTR_RTS_OUT2, %al
+ mov $UART_MCTL, %dx
+ out %al, %dx
+ ret
+
+
+ser_putchar:
+ push %dx
+
+ cmp $10, %al
+ jnz 0f
+ push %ax
+ mov $13, %al
+ call ser_putchar
+ pop %ax
+
+0: mov %al, %ah
+ # wait until the transmit register is empty
+ mov $UART_LSTAT, %dx
+wait: in %dx, %al
+ and $LST_TREG_EMPTY, %al
+ jz wait
+ mov $UART_DATA, %dx
+ mov %ah, %al
+ out %al, %dx
+
+ pop %dx
+ ret
+
+
+
+ena20_msg: .asciz "A20 line enabled\n"
+
+enable_a20:
+ call test_a20
+ jnc a20done
+ call enable_a20_kbd
+ call test_a20
+ jnc a20done
+ call enable_a20_fast
+ call test_a20
+ jnc a20done
+ # keep trying ... we can't do anything useful without A20 anyway
+ jmp enable_a20
+a20done:
+ mov $ena20_msg, %esi
+ call putstr
+ ret
+
+ # CF = 1 if A20 test fails (not enabled)
+test_a20:
+ mov $0x07c000, %ebx
+ mov $0x17c000, %edx
+ movl $0xbaadf00d, (%ebx)
+ movl $0xaabbcc42, (%edx)
+ subl $0xbaadf00d, (%ebx)
+ ret
+
+ # enable A20 line through port 0x92 (fast A20)
+enable_a20_fast:
+ mov $ena20_fast_msg, %esi
+ call putstr
+
+ in $0x92, %al
+ or $2, %al
+ out %al, $0x92
+ ret
+
+ena20_fast_msg: .asciz "Attempting fast A20 enable\n"
+
+
+ # enable A20 line through the keyboard controller
+ .set KBC_DATA_PORT, 0x60
+ .set KBC_CMD_PORT, 0x64
+ .set KBC_STATUS_PORT, 0x64
+ .set KBC_CMD_RD_OUTPORT, 0xd0
+ .set KBC_CMD_WR_OUTPORT, 0xd1
+
+ .set KBC_STAT_OUT_RDY, 0x01
+ .set KBC_STAT_IN_FULL, 0x02
+
+enable_a20_kbd:
+ mov $ena20_kbd_msg, %esi
+ call putstr
+
+ call kbc_wait_write
+ mov $KBC_CMD_WR_OUTPORT, %al
+ out %al, $KBC_CMD_PORT
+ call kbc_wait_write
+ mov $0xdf, %al
+ out %al, $KBC_DATA_PORT
+ ret
+
+ena20_kbd_msg: .asciz "Attempting KBD A20 enable\n"
+
+ # wait until the keyboard controller is ready to accept another byte
+kbc_wait_write:
+ in $KBC_STATUS_PORT, %al
+ and $KBC_STAT_IN_FULL, %al
+ jnz kbc_wait_write
+ ret
+
+numbuf: .space 16
+
+
+detect_memory:
+ mov $memdet_e820_msg, %esi
+ call putstr
+ call detect_mem_e820
+ jnc memdet_done
+ mov $rdfail_msg, %esi
+ call putstr
+
+ mov $memdet_e801_msg, %esi
+ call putstr
+ call detect_mem_e801
+ jnc memdet_done
+ mov $rdfail_msg, %esi
+ call putstr
+
+ mov $memdet_88_msg, %esi
+ call putstr
+ call detect_mem_88
+ jnc memdet_done
+ mov $rdfail_msg, %esi
+ call putstr
+
+ # just panic...
+ mov $memdet_fail_msg, %esi
+ call putstr
+0: hlt
+ jmp 0b
+
+memdet_done:
+ mov $rdok_msg, %esi
+ call putstr
+ ret
+
+memdet_fail_msg: .ascii "Failed to detect available memory!\n"
+ .ascii "Please file a bug report: https://github.com/jtsiomb/pcboot/issues\n"
+ .asciz " or contact me through email: nuclear@member.fsf.org\n"
+memdet_e820_msg: .asciz "Detecting RAM (BIOS 15h/0xe820)... "
+memdet_e801_msg: .asciz "Detecting RAM (BIOS 15h/0xe801)... "
+memdet_88_msg: .asciz "Detecting RAM (BIOS 15h/0x88, max 64mb)... "
+
+ # detect extended memory using BIOS call 15h/e820
+detect_mem_e820:
+ movl $0, boot_mem_map_size
+
+ mov $buffer, %edi
+ xor %ebx, %ebx
+ mov $0x534d4150, %edx
+
+e820_looptop:
+ mov $0xe820, %eax
+ mov $24, %ecx
+ int $0x15
+ jc e820_fail
+ cmp $0x534d4150, %eax
+ jnz e820_fail
+
+ # skip areas starting above 4GB as we won't be able to use them
+ cmpl $0, 4(%edi)
+ jnz e820_skip
+
+ # only care for type 1 (usable ram), otherwise ignore
+ cmpl $1, 16(%edi)
+ jnz e820_skip
+
+ mov buffer, %eax
+ mov $boot_mem_map, %esi
+ mov boot_mem_map_size, %ebp
+ # again, that's [ebp * 8 + esi]
+ mov %eax, (%esi,%ebp,8)
+
+ # skip areas with 0 size (also clamp size to 4gb)
+ # test high 32bits
+ cmpl $0, 12(%edi)
+ jz e820_highzero
+ # high part is non-zero, make low part ffffffff
+ xor %eax, %eax
+ not %eax
+ jmp 0f
+
+e820_highzero:
+ # if both high and low parts are zero, ignore
+ mov 8(%edi), %eax
+ cmpl $0, %eax
+ jz e820_skip
+
+0: mov %eax, 4(%esi,%ebp,8)
+ incl boot_mem_map_size
+
+e820_skip:
+ # terminate the loop if ebx was reset to 0
+ cmp $0, %ebx
+ jz e820_done
+ jmp e820_looptop
+
+e820_done:
+ clc
+ ret
+
+e820_fail:
+ # if size > 0, then it's not a failure, just the end
+ cmpl $0, boot_mem_map_size
+ jnz e820_done
+
+ stc
+ ret
+
+
+ # detect extended memory using BIOS call 15h/e801
+detect_mem_e801:
+ mov $boot_mem_map, %esi
+ mov boot_mem_map_size, %ebp
+ movl $0, (%ebp)
+
+ xor %cx, %cx
+ xor %dx, %dx
+ mov $0xe801, %ax
+ int $0x15
+ jc e801_fail
+
+ cmp $0, %cx
+ jnz 0f
+ cmp $0, %ax
+ jz e801_fail
+ mov %ax, %cx
+ mov %bx, %dx
+
+0: movl $0x100000, (%esi)
+ movzx %cx, %eax
+ # first size is in KB, convert to bytes
+ shl $10, %eax
+ jnc 0f
+ # overflow means it's >4GB, clamp to 4GB
+ mov $0xffffffff, %eax
+0: mov %eax, 4(%esi)
+ incl boot_mem_map_size
+ cmp $0, %dx
+ jz e801_done
+ movl $0x1000000, 8(%esi)
+ movzx %dx, %eax
+ # second size is in 64kb blocks, convert to bytes
+ shl $16, %eax
+ jnc 0f
+ # overflow means it's >4GB, clamp to 4GB
+ mov $0xffffffff, %eax
+0: mov %eax, 12(%esi)
+ incl boot_mem_map_size
+e801_done:
+ clc
+ ret
+e801_fail:
+ stc
+ ret
+
+detect_mem_88:
+ # reportedly some BIOS implementations fail to clear CF on success
+ clc
+ mov $0x88, %ah
+ int $0x15
+ jc x88_fail
+
+ cmp $0, %ax
+ jz x88_fail
+
+ # ax has size in KB, convert to bytes in eax
+ and $0xffff, %eax
+ shl $10, %eax
+
+ mov $boot_mem_map, %esi
+ movl $0x100000, (%esi)
+ mov %eax, 4(%esi)
+
+ movl $1, boot_mem_map_size
+ clc
+ ret
+
+x88_fail:
+ stc
+ ret
+
+
+ .global boot_mem_map_size
+boot_mem_map_size: .long 0
+ .global boot_mem_map
+boot_mem_map: .space 128
+
+
+# this is not boot loader code. It's called later on by the main kernel
+# code in 32bit protected mode. It's placed here because it needs to be
+# located in base memory as it returns and runs in real mode.
+ .code32
+ .align 4
+ # place to save the protected mode IDTR pseudo-descriptor
+ # with sidt, so that it can be restored before returning
+ .short 0
+saved_idtr:
+idtlim: .short 0
+idtaddr:.long 0
+ # real mode IDTR pseudo-descriptor pointing to the IVT at addr 0
+ .short 0
+rmidt: .short 0x3ff
+ .long 0
+
+saved_esp: .long 0
+saved_ebp: .long 0
+saved_eax: .long 0
+saved_es: .word 0
+saved_ds: .word 0
+saved_flags: .word 0
+saved_pic1_mask: .byte 0
+saved_pic2_mask: .byte 0
+
+ # drop back to unreal mode to call 16bit interrupt
+ .global int86
+int86:
+ push %ebp
+ mov %esp, %ebp
+ pushal
+ cli
+ # save protected mode IDTR and replace it with the real mode vectors
+ sidt (saved_idtr)
+ lidt (rmidt)
+
+ # save PIC masks
+ pushl $0
+ call get_pic_mask
+ add $4, %esp
+ mov %al, saved_pic1_mask
+ pushl $1
+ call get_pic_mask
+ add $4, %esp
+ mov %al, saved_pic2_mask
+
+ # modify the int instruction. do this here before the
+ # cs-load jumps, to let them flush the instruction cache
+ mov $int_op, %ebx
+ movb 8(%ebp), %al
+ movb %al, 1(%ebx)
+
+ # long jump to load code selector for 16bit code (6)
+ ljmp $0x30,$0f
+0:
+ .code16
+ # disable protection
+ mov %cr0, %eax
+ and $0xfffe, %ax
+ mov %eax, %cr0
+ # load cs <- 0
+ ljmp $0,$0f
+0: # zero data segments
+ xor %ax, %ax
+ mov %ax, %ds
+ mov %ax, %es
+ mov %ax, %ss
+ nop
+
+ # load registers from the int86regs struct
+ # point esp to the regs struct to load registers with popa/popf
+ mov %esp, saved_esp
+ mov %ebp, saved_ebp
+ mov 12(%ebp), %esp
+ popal
+ popfw
+ pop %es
+ pop %ds
+ # ignore fs and gs for now, don't think I'm going to need them
+
+ # move to the real-mode stack, accessible from ss=0
+ # just in case the BIOS call screws up our unreal mode
+ mov $0x7be0, %esp
+
+ # call 16bit interrupt
+int_op: int $0
+ # BIOS call might have enabled interrupts, cli for good measure
+ cli
+
+ # save all registers that we'll clobber before having the
+ # chance to populate the int86regs structure
+ mov %eax, saved_eax
+ mov %ds, saved_ds
+ mov %es, saved_es
+ pushfw
+ popw %ax
+ mov %ax, saved_flags
+
+ # re-enable protection
+ mov %cr0, %eax
+ or $1, %ax
+ mov %eax, %cr0
+ # long jump to load code selector for 32bit code (1)
+ ljmp $0x8,$0f
+0:
+ .code32
+ # set data selector (2) to all segment regs
+ mov $0x10, %ax
+ mov %ax, %ds
+ mov %ax, %es
+ mov %ax, %ss
+ nop
+
+ # point the esp to our regs struct, to fill it with pusha/pushf
+ mov saved_ebp, %ebp
+ mov 12(%ebp), %esp
+ add $38, %esp
+ mov saved_ds, %ax
+ pushw %ax
+ mov saved_es, %ax
+ pushw %ax
+ # grab the flags and replace the carry bit from the saved flags
+ pushfw
+ popw %ax
+ and $0xfffe, %ax
+ or saved_flags, %ax
+ pushw %ax
+ mov saved_eax, %eax
+ pushal
+ mov saved_esp, %esp
+
+ # restore 32bit interrupt descriptor table
+ lidt (saved_idtr)
+
+ # restore PIC configuration
+ call init_pic
+
+ # restore IRQ masks
+ movzbl saved_pic1_mask, %eax
+ push %eax
+ pushl $0
+ call set_pic_mask
+ add $8, %esp
+
+ movzbl saved_pic2_mask, %eax
+ push %eax
+ pushl $1
+ call set_pic_mask
+ add $8, %esp
+
+ # keyboard voodoo: with some BIOS implementations, after returning from
+ # int13, there's (I guess) leftover data in the keyboard port and we
+ # can't receive any more keyboard interrupts afterwards. Reading from
+ # the keyboard data port (60h) once, seems to resolve this. And it's
+ # cheap enough, so why not... I give up.
+ push %eax
+ in $0x60, %al
+ pop %eax
+
+ sti
+ popal
+ pop %ebp
+ ret
+
+
+ .align 4
+ .global boot_drive_number
+boot_drive_number:
+ .long 0
+
+ # buffer used by the track loader ... to load tracks.
+ .align 16
+buffer:
+ .global low_mem_buffer
+low_mem_buffer: