git.mutantstargoat.com Git - demo_prior/blob - sdr/whitted.p.glsl

   1 struct Material {
   2         vec3 diffuse, specular;
   3         float shin;
   4 };
   5
   6 struct HitPoint {
   7         float dist;
   8         vec3 pos, norm;
   9         vec2 surfpos;
  10         Material mtl;
  11 };
  12
  13 varying vec3 v_rorg, v_rdir;
  14
  15
  16 vec3 shade(in vec3 ro, in vec3 rd, in HitPoint hit);
  17 vec3 backdrop(in vec3 dir);
  18
  19 bool isect_scene(in vec3 ro, in vec3 rd, out HitPoint hit);
  20
  21 bool isect_floor(in vec3 ro, in vec3 rd, float rad, out HitPoint hit);
  22 bool isect_plane(in vec3 ro, in vec3 rd, in vec4 plane, out HitPoint hit);
  23 bool isect_sphere(in vec3 ro, in vec3 rd, in vec3 pos, float rad, out HitPoint hit);
  24
  25
  26 const Material mtl_sph = Material(vec3(1.0, 0.0, 0.0), vec3(1.0, 1.0, 1.0), 80.0);
  27 const Material mtl_floor = Material(vec3(0.5, 0.5, 0.5), vec3(0.0, 0.0, 0.0), 1.0);
  28
  29 const vec3 light_pos = vec3(-20, 20, 30);
  30
  31 void main()
  32 {
  33         vec3 rdir = normalize(v_rdir);
  34         gl_FragColor.rgb = backdrop(rdir);
  35
  36         HitPoint hit;
  37         if(isect_scene(v_rorg, rdir, hit)) {
  38                 gl_FragColor.rgb = shade(v_rorg, rdir, hit);
  39         } else {
  40                 gl_FragColor.rgb = backdrop(rdir);
  41         }
  42         gl_FragColor.a = 1.0;
  43 }
  44
  45 vec3 shade(in vec3 ro, in vec3 rd, in HitPoint hit)
  46 {
  47         HitPoint shadow_hit;
  48         vec3 ldir = light_pos - hit.pos;
  49
  50         vec3 col = vec3(0.03, 0.03, 0.03);      // ambient
  51
  52         if(!isect_scene(hit.pos + hit.norm * 0.01, ldir, shadow_hit) || shadow_hit.dist > 1.0) {
  53                 vec3 l = normalize(ldir);
  54                 vec3 v = normalize(-rd);
  55                 vec3 h = normalize(v + l);
  56                 float ndotl = max(dot(hit.norm, l), 0.0);
  57                 float ndoth = max(dot(hit.norm, h), 0.0);
  58
  59                 col += hit.mtl.diffuse * ndotl + hit.mtl.specular * pow(ndoth, hit.mtl.shin);
  60         }
  61
  62         return col;
  63 }
  64
  65 #define M_PI    3.1415926
  66 #define M_2PI   (M_PI * 2.0)
  67
  68 vec3 backdrop(in vec3 dir)
  69 {
  70         return mix(vec3(0.8, 0.3, 0.2), vec3(0.2, 0.3, 0.8), smoothstep(-0.1, 0.1, dir.y));
  71 }
  72
  73 bool isect_scene(in vec3 ro, in vec3 rd, out HitPoint hit_res)
  74 {
  75         HitPoint hit, nearest;
  76
  77         nearest.dist = 10000.0;
  78
  79         if(isect_sphere(ro, rd, vec3(0.0, 0.0, 0.0), 1.0, hit)) {
  80                 nearest = hit;
  81                 nearest.mtl = mtl_sph;
  82         }
  83
  84         if(isect_floor(ro, rd, 5.0, hit) && hit.dist < nearest.dist) {
  85                 nearest = hit;
  86                 nearest.mtl = mtl_floor;
  87         }
  88
  89         if(nearest.dist >= 10000.0) {
  90                 return false;
  91         }
  92
  93         hit_res = nearest;
  94         return true;
  95 }
  96
  97 #define FLOOR_OFFS      vec3(2.0, 0.0, 0.0)
  98
  99 bool isect_floor(in vec3 ro, in vec3 rd, float rad, out HitPoint hit)
 100 {
 101         if(!isect_plane(ro - FLOOR_OFFS, rd, vec4(0.0, 1.0, 0.0, -1.0), hit)) {
 102                 return false;
 103         }
 104
 105         float d = max(abs(hit.pos.x), abs(hit.pos.z));
 106         if(d >= rad) return false;
 107
 108         hit.pos += FLOOR_OFFS;
 109         return true;
 110 }
 111
 112 bool isect_plane(in vec3 ro, in vec3 rd, in vec4 plane, out HitPoint hit)
 113 {
 114         float ndotrd = dot(rd, plane.xyz);
 115
 116         if(abs(ndotrd) < 1e-6) {
 117                 return false;
 118         }
 119
 120         vec3 pp = plane.xyz * plane.w;
 121         vec3 pdir = pp - ro;
 122         float t = dot(pdir, plane.xyz) / ndotrd;
 123
 124         if(t < 1e-6) {
 125                 return false;
 126         }
 127
 128         hit.dist = t;
 129         hit.pos = ro + rd * t;
 130         hit.norm = plane.xyz;
 131         hit.surfpos = hit.pos.xz;       /* XXX */
 132         return true;
 133 }
 134
 135 bool isect_sphere(in vec3 ro, in vec3 rd, in vec3 pos, float rad, out HitPoint hit)
 136 {
 137         float a = dot(rd, rd);
 138         float b = dot(rd * 2.0, (ro - pos));
 139         float c = dot(ro, ro) + dot(pos, pos) - 2.0 * dot(ro, pos) - rad * rad;
 140
 141         float d = b * b - 4.0 * a * c;
 142         if(d < 1e-6) {
 143                 return false;
 144         }
 145
 146         float t0 = (-b + sqrt(d)) / (2.0 * a);
 147         float t1 = (-b - sqrt(d)) / (2.0 * a);
 148
 149         if(t0 < 0.0) t0 = t1;
 150         if(t1 < 0.0) t1 = t0;
 151         float t = min(t0, t1);
 152
 153         if(t < 1e-6) {
 154                 return false;
 155         }
 156
 157         hit.dist = t;
 158         hit.pos = ro + rd * t;
 159         hit.norm = normalize(hit.pos - pos);
 160         hit.surfpos.x = atan(hit.norm.z, hit.norm.x);
 161         hit.surfpos.y = acos(hit.norm.y);
 162         return true;
 163 }