git.mutantstargoat.com Git - demo_prior/blob - sdr/whitted.p.glsl

   1 struct Ray {
   2         vec3 org, dir;
   3         float energy, ior;
   4 };
   5
   6 struct Material {
   7         vec3 diffuse, specular;
   8         float shin;
   9         float refl, refr;
  10         float ior;
  11 };
  12
  13 struct HitPoint {
  14         float dist;
  15         vec3 pos, norm;
  16         vec2 surfpos;
  17         Material mtl;
  18         float shadow;   /* opacity along the line of sight up to dist=1 */
  19 };
  20
  21 varying vec3 v_rorg, v_rdir;
  22
  23
  24 vec3 shade(in vec3 ro, in vec3 rd, in HitPoint hit);
  25 vec3 backdrop(in vec3 dir);
  26
  27 bool isect_scene(in vec3 ro, in vec3 rd, out HitPoint hit);
  28
  29 bool isect_floor(in vec3 ro, in vec3 rd, in vec2 sz, out HitPoint hit);
  30 bool isect_plane(in vec3 ro, in vec3 rd, in vec4 plane, out HitPoint hit);
  31 bool isect_sphere(in vec3 ro, in vec3 rd, in vec3 pos, float rad, out HitPoint hit);
  32
  33 /* schlick's approximation: [5.0, 1.0, R(0deg)] */
  34 float hack_fresnel(vec3 i, vec3 n, vec3 fresnel_val);
  35
  36 vec3 tex_chess(in vec3 col1, in vec3 col2, in vec2 spos);
  37
  38 #define GREY(x) vec3(x, x, x)
  39
  40 const Material mtl_sph = Material(GREY(0.1), GREY(1.0), 80.0, 0.8, 0.0, 0.0);
  41 const Material mtl_glass = Material(GREY(0.0), GREY(0.99), 80.0, 0.99, 0.99, 1.52);
  42 const Material mtl_air = Material(GREY(0.0), GREY(0.99), 80.0, 0.99, 0.99, 1.0);
  43 const Material mtl_floor = Material(GREY(0.5), GREY(0.0), 1.0, 0.0, 0.0, 0.0);
  44
  45 const vec3 light_pos = vec3(-10, 50, 30);
  46
  47 bool cast_ray(in Ray ray, inout vec3 color, out HitPoint hit)
  48 {
  49         if(isect_scene(ray.org, ray.dir, hit)) {
  50                 color += shade(ray.org, ray.dir, hit) * ray.energy;
  51                 return true;
  52         }
  53         color += backdrop(ray.dir);
  54         return false;
  55 }
  56
  57 #define MAX_LEVEL       8
  58
  59 struct StackFrame {
  60         int op;
  61         Ray ray;
  62         HitPoint hit;
  63 };
  64
  65 void main()
  66 {
  67         StackFrame stack[MAX_LEVEL];
  68
  69         vec3 color = vec3(0.0, 0.0, 0.0);
  70
  71         stack[0].op = 0;
  72         stack[0].ray.org = v_rorg;
  73         stack[0].ray.dir = normalize(v_rdir);
  74         stack[0].ray.energy = stack[0].ray.ior = 1.0;
  75
  76         int top = 0;
  77         while(top >= 0) {
  78                 if(top >= MAX_LEVEL - 1) {
  79                         color += backdrop(stack[top].ray.dir) * stack[top].ray.energy;
  80                         top--;
  81                         continue;
  82                 }
  83                 if(stack[top].ray.energy < 1e-3) {
  84                         top--;
  85                         continue;
  86                 }
  87
  88                 if(!cast_ray(stack[top].ray, color, stack[top].hit)) {
  89                         /* no hit, return */
  90                         top--;
  91                         continue;
  92                 }
  93
  94                 /* found a hit, recurse for reflection/refraction */
  95                 HitPoint hit = stack[top].hit;
  96
  97                 // 1.0 when entering, 0.0 when leaving
  98                 float entering = step(0.0, dot(-stack[top].ray.dir, hit.norm));
  99                 vec3 norm = faceforward(hit.norm, stack[top].ray.dir, hit.norm);
 100
 101                 float fr = hack_fresnel(-stack[top].ray.dir, norm, vec3(5.0, 4.0, 0.01));
 102                 // fr = 1 everywhere when ior < 0.5 to avoid affecting the metal sphere
 103                 fr = min(1.0, (1.0 - step(0.5, hit.mtl.ior)) + fr);
 104
 105                 int op = stack[top].op++;
 106                 if(op == 0) {
 107                         // reflection
 108                         float energy = stack[top].ray.energy * hit.mtl.refl * fr;
 109                         if(hit.mtl.refr > 1e-4) {
 110                                 energy += fr * 0.01;
 111                         }
 112                         if(energy > 1e-4) {
 113                                 int next = top + 1;
 114                                 stack[next].op = 0;
 115                                 stack[next].ray.org = hit.pos + norm * 1e-5;
 116                                 stack[next].ray.dir = reflect(stack[top].ray.dir, norm);
 117                                 stack[next].ray.energy = energy;
 118                                 top = next;
 119                         }
 120                 } else if(op == 1) {
 121                         // refraction
 122                         float energy = stack[top].ray.energy * hit.mtl.refr * (1.0 - fr);
 123                         if(energy > 1e-4) {
 124                                 float next_ior = mix(stack[top - 1].ray.ior, hit.mtl.ior, entering);
 125                                 float ior = stack[top].ray.ior / next_ior;
 126                                 int next = top + 1;
 127                                 stack[next].op = 0;
 128                                 stack[next].ray.org = hit.pos - norm * 1e-5;
 129                                 stack[next].ray.dir = refract(stack[top].ray.dir, norm, ior);
 130                                 stack[next].ray.energy = energy;
 131                                 stack[next].ray.ior = next_ior;
 132                                 top = next;
 133                         }
 134                 } else if(op == 2) {
 135                         // return
 136                         top--;
 137                 }
 138         }
 139
 140         gl_FragColor = vec4(color, 1.0);
 141 }
 142
 143 vec3 shade(in vec3 ro, in vec3 rd, in HitPoint hit)
 144 {
 145         HitPoint shadow_hit;
 146         vec3 norm = faceforward(hit.norm, rd, hit.norm);
 147         vec3 ldir = light_pos - hit.pos;
 148
 149         vec3 amb = hit.mtl.diffuse * 0.02;
 150
 151         isect_scene(hit.pos + norm * 0.01, ldir, shadow_hit);
 152
 153         vec3 l = normalize(ldir);
 154         vec3 v = normalize(-rd);
 155         vec3 h = normalize(v + l);
 156         float ndotl = max(dot(norm, l), 0.0);
 157         float ndoth = max(dot(norm, h), 0.0);
 158
 159         vec3 lit = hit.mtl.diffuse * ndotl + hit.mtl.specular * pow(ndoth, hit.mtl.shin);
 160
 161         return amb + lit * shadow_hit.shadow;
 162 }
 163
 164 #define M_PI    3.1415926
 165 #define M_2PI   (M_PI * 2.0)
 166
 167 vec3 backdrop(in vec3 dir)
 168 {
 169         return vec3(0.1, 0.15, 1.0);
 170 }
 171
 172 #define FLOOR_OFFS      vec3(3.0, 0.0, 0.0)
 173 #define FLOOR_SIZE      vec2(5.5, 15.0)
 174
 175 #define GLASS_POS       vec3(0.0, 0.2, 1.2)
 176
 177 bool isect_scene(in vec3 ro, in vec3 rd, out HitPoint hit_res)
 178 {
 179         float opacity = 1.0;
 180         HitPoint hit, nearest;
 181
 182         nearest.dist = 10000.0;
 183
 184         if(isect_sphere(ro, rd, vec3(1.5, -0.5, 0.0), 0.85, hit)) {
 185                 nearest = hit;
 186                 nearest.mtl = mtl_sph;
 187                 if(hit.dist < 1.0) {
 188                         opacity *= mtl_sph.refr;
 189                 }
 190         }
 191
 192         if(isect_sphere(ro, rd, GLASS_POS, 0.9, hit)) {
 193                 if(hit.dist < nearest.dist) {
 194                         nearest = hit;
 195                         nearest.mtl = mtl_glass;
 196                 }
 197                 if(hit.dist < 1.0) {
 198                         opacity *= mtl_glass.refr;
 199                 }
 200         }
 201
 202         if(isect_sphere(ro, rd, GLASS_POS, 0.86, hit)) {
 203                 if(hit.dist < nearest.dist) {
 204                         nearest = hit;
 205                         nearest.mtl = mtl_air;
 206                 }
 207         }
 208
 209         if(isect_floor(ro, rd, FLOOR_SIZE, hit) && hit.dist < nearest.dist) {
 210                 nearest = hit;
 211                 nearest.mtl = mtl_floor;
 212                 nearest.mtl.diffuse = tex_chess(vec3(1.0, 0.0, 0.0), vec3(1.0, 1.0, 0.0), hit.surfpos);
 213         }
 214
 215         if(nearest.dist >= 10000.0) {
 216                 hit_res.shadow = 1.0;
 217                 return false;
 218         }
 219
 220         hit_res = nearest;
 221         hit_res.shadow = opacity;
 222         return true;
 223 }
 224
 225 bool isect_floor(in vec3 ro, in vec3 rd, in vec2 sz, out HitPoint hit)
 226 {
 227         if(!isect_plane(ro - FLOOR_OFFS, rd, vec4(0.0, 1.0, 0.0, -1.8), hit)) {
 228                 return false;
 229         }
 230
 231         if(abs(hit.pos.x) >= sz.x || abs(hit.pos.z) >= sz.y) {
 232                 return false;
 233         }
 234
 235         hit.pos += FLOOR_OFFS;
 236         hit.surfpos /= sz * 2.0;
 237         return true;
 238 }
 239
 240 bool isect_plane(in vec3 ro, in vec3 rd, in vec4 plane, out HitPoint hit)
 241 {
 242         float ndotrd = dot(rd, plane.xyz);
 243
 244         if(abs(ndotrd) < 1e-6) {
 245                 return false;
 246         }
 247
 248         vec3 pp = plane.xyz * plane.w;
 249         vec3 pdir = pp - ro;
 250         float t = dot(pdir, plane.xyz) / ndotrd;
 251
 252         if(t < 1e-6) {
 253                 return false;
 254         }
 255
 256         hit.dist = t;
 257         hit.pos = ro + rd * t;
 258         hit.norm = plane.xyz;
 259         hit.surfpos = hit.pos.xz;       /* XXX */
 260         return true;
 261 }
 262
 263 bool isect_sphere(in vec3 ro, in vec3 rd, in vec3 pos, float rad, out HitPoint hit)
 264 {
 265         float a = dot(rd, rd);
 266         float b = dot(rd * 2.0, (ro - pos));
 267         float c = dot(ro, ro) + dot(pos, pos) - 2.0 * dot(ro, pos) - rad * rad;
 268
 269         float d = b * b - 4.0 * a * c;
 270         if(d < 1e-6) {
 271                 return false;
 272         }
 273
 274         float t0 = (-b + sqrt(d)) / (2.0 * a);
 275         float t1 = (-b - sqrt(d)) / (2.0 * a);
 276
 277         if(t0 < 0.0) t0 = t1;
 278         if(t1 < 0.0) t1 = t0;
 279         float t = min(t0, t1);
 280
 281         if(t < 1e-6) {
 282                 return false;
 283         }
 284
 285         hit.dist = t;
 286         hit.pos = ro + rd * t;
 287         hit.norm = normalize(hit.pos - pos);
 288         hit.surfpos.x = atan(hit.norm.z, hit.norm.x);
 289         hit.surfpos.y = acos(hit.norm.y);
 290         return true;
 291 }
 292
 293 /* schlick's approximation: [5.0, 1.0, R(0deg)] */
 294 float hack_fresnel(vec3 i, vec3 n, vec3 fresnel_val)
 295 {
 296         return fresnel_val.z + pow(1.0 - dot(i, n), fresnel_val.x) * fresnel_val.y;
 297 }
 298
 299 vec3 tex_chess(in vec3 col1, in vec3 col2, in vec2 spos)
 300 {
 301         float foo = step(0.5, mod(spos.x * 8.0, 1.0)) * 2.0 - 1.0;
 302         float bar = step(0.5, mod(spos.y * 24.0, 1.0)) * 2.0 - 1.0;
 303
 304         float xor = (foo * bar) * 0.5 + 0.5;
 305
 306         return mix(col1, col2, xor);
 307 }