git.mutantstargoat.com Git - freeglut/blob - CMakeLists.txt

   1 PROJECT(freeglut)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   3
   4 # NOTE: On Windows and Cygwin, the dll's are placed in the
   5 # CMAKE_RUNTIME_OUTPUT_DIRECTORY, while their corresponding import
   6 # libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY. On other
   7 # platforms, such as Linux, the shared libraries are put in
   8 # CMAKE_ARCHIVE_OUTPUT_DIRECTORY instead.
   9 # Static libraries end up in CMAKE_ARCHIVE_OUTPUT_DIRECTORY on all
  10 # platforms (unless
  11 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
  12 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
  13
  14 # setup version numbers
  15 # TODO: Update these for each release!
  16 set(VERSION_MAJOR 3)
  17 set(VERSION_MINOR 0)
  18 set(VERSION_PATCH 0)
  19
  20
  21 # BUILD_SHARED_LIBS is already a standard CMake variable, but we need to
  22 # re-declare it here so it will show up in the GUI.
  23 # by default, we want to build both
  24 OPTION(BUILD_SHARED_LIBS "Build FreeGLUT shared library." ON)
  25 OPTION(BUILD_STATIC_LIBS "Build FreeGLUT static library." ON)
  26
  27 # OpenGL ES support
  28 OPTION(FREEGLUT_GLES1 "Use OpenGL ES 1.x (requires EGL)" OFF)
  29 OPTION(FREEGLUT_GLES2 "Use OpenGL ES 2.x (requires EGL) (overrides BUILD_GLES1)" OFF)
  30
  31
  32 SET(FREEGLUT_HEADERS
  33     include/GL/freeglut.h
  34     include/GL/freeglut_ext.h
  35     include/GL/freeglut_std.h
  36     include/GL/glut.h
  37 )
  38 SET(FREEGLUT_SRCS
  39     ${FREEGLUT_HEADERS}
  40     src/fg_callbacks.c
  41     src/fg_cursor.c
  42     src/fg_display.c
  43     src/fg_ext.c
  44     src/fg_font_data.c
  45     src/fg_gamemode.c
  46     src/fg_init.c
  47     src/fg_internal.h
  48     src/fg_input_devices.c
  49     src/fg_joystick.c
  50     src/fg_main.c
  51     src/fg_misc.c
  52     src/fg_overlay.c
  53     src/fg_spaceball.c
  54     src/fg_state.c
  55     src/fg_stroke_mono_roman.c
  56     src/fg_stroke_roman.c
  57     src/fg_structure.c
  58     src/fg_videoresize.c
  59     src/fg_window.c
  60 )
  61 # TODO: OpenGL ES requires a compatible version of these files:
  62 IF(NOT FREEGLUT_GLES2 AND NOT FREEGLUT_GLES1)
  63     LIST(APPEND FREEGLUT_SRCS
  64         src/fg_font.c
  65         src/fg_geometry.c
  66         src/fg_menu.c
  67         src/fg_teapot.c
  68     )
  69 ENDIF()
  70
  71 IF(WIN32)
  72     LIST(APPEND FREEGLUT_SRCS
  73         src/mswin/fg_cursor_mswin.c
  74         src/mswin/fg_display_mswin.c
  75         src/mswin/fg_ext_mswin.c
  76         src/mswin/fg_gamemode_mswin.c
  77         src/mswin/fg_init_mswin.c
  78         src/mswin/fg_internal_mswin.h
  79         src/mswin/fg_input_devices_mswin.c
  80         src/mswin/fg_joystick_mswin.c
  81         src/mswin/fg_main_mswin.c
  82         src/mswin/fg_menu_mswin.c
  83         src/mswin/fg_spaceball_mswin.c
  84         src/mswin/fg_state_mswin.c
  85         src/mswin/fg_structure_mswin.c
  86         src/mswin/fg_window_mswin.c
  87         ${CMAKE_BINARY_DIR}/freeglut.rc # generated below from freeglut.rc.in
  88     )
  89     IF (MSVC AND NOT CMAKE_CL_64)
  90         # .def file only for 32bit Windows builds
  91         LIST(APPEND FREEGLUT_SRCS
  92             ${CMAKE_BINARY_DIR}/freeglutdll.def # generated below from src/freeglutdll.def.in
  93         )
  94     ENDIF()
  95
  96 ELSEIF(ANDROID)
  97     LIST(APPEND FREEGLUT_SRCS
  98         src/egl/fg_internal_egl.h
  99         src/egl/fg_display_egl.c
 100         src/egl/fg_init_egl.c
 101         src/egl/fg_structure_egl.c
 102         src/egl/fg_window_egl.c
 103         src/egl/fg_window_egl.h
 104         src/android/native_app_glue/android_native_app_glue.c
 105         src/android/native_app_glue/android_native_app_glue.h
 106         src/android/fg_runtime_android.c
 107         src/android/fg_gamemode_android.c
 108         src/android/fg_init_android.c
 109         src/android/fg_input_devices_android.c
 110         src/android/fg_joystick_android.c
 111         src/android/fg_main_android.c
 112         src/android/fg_spaceball_android.c
 113         src/android/fg_state_android.c
 114         src/android/fg_window_android.c
 115         src/android/opengles_stubs.c
 116         src/android/fg_internal_android.h
 117     )
 118 ELSE()
 119     LIST(APPEND FREEGLUT_SRCS
 120         src/x11/fg_cursor_x11.c
 121         src/x11/fg_display_x11.c
 122         src/x11/fg_ext_x11.c
 123         src/x11/fg_gamemode_x11.c
 124         src/x11/fg_glutfont_definitions_x11.c
 125         src/x11/fg_init_x11.c
 126         src/x11/fg_internal_x11.h
 127         src/x11/fg_input_devices_x11.c
 128         src/x11/fg_joystick_x11.c
 129         src/x11/fg_main_x11.c
 130         src/x11/fg_menu_x11.c
 131         src/x11/fg_spaceball_x11.c
 132         src/x11/fg_state_x11.c
 133         src/x11/fg_structure_x11.c
 134         src/x11/fg_window_x11.c
 135         src/x11/fg_xinput_x11.c
 136     )
 137 ENDIF()
 138
 139 # For OpenGL ES (GLES):
 140 # - compile with -DFREEGLUT_GLES1 and -DFREEGLUT_GLES2 to cleanly
 141 #   bootstrap headers inclusion in freeglut_std.h; these constants
 142 #   also need to be defined in client applications (e.g through
 143 #   pkg-config), but use GLES constants directly for all other needs
 144 # - define GLES version-specific library
 145 IF(FREEGLUT_GLES2)
 146   ADD_DEFINITIONS(-DFREEGLUT_GLES2)
 147   LIST(APPEND LIBS GLESv2 EGL)
 148 ELSEIF(FREEGLUT_GLES1)
 149   ADD_DEFINITIONS(-DFREEGLUT_GLES1)
 150   LIST(APPEND LIBS GLESv1 EGL)
 151 ELSE()
 152   FIND_PACKAGE(OpenGL REQUIRED)
 153   LIST(APPEND LIBS ${OPENGL_gl_LIBRARY})
 154   INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
 155 ENDIF()
 156
 157 # lib m for math, not needed on windows
 158 IF (NOT WIN32)
 159     LIST(APPEND LIBS m)
 160 ENDIF()
 161
 162 IF(WIN32)
 163     # hide insecure CRT warnings, common practice
 164     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 165 ENDIF()
 166
 167 if(UNIX AND NOT ANDROID)
 168     FIND_PACKAGE(X11 REQUIRED)
 169     LIST(APPEND LIBS ${X11_LIBRARIES})
 170     IF(X11_Xrandr_FOUND)
 171         SET(HAVE_X11_EXTENSIONS_XRANDR_H TRUE)
 172         LIST(APPEND LIBS ${X11_Xrandr_LIB})
 173     ENDIF()
 174     IF(X11_xf86vmode_FOUND)
 175         SET(HAVE_X11_EXTENSIONS_XF86VMODE_H TRUE)
 176         # Work-around http://www.cmake.org/Bug/bug_view_page.php?bug_id=6976
 177         IF(NOT "${X11_Xxf86vm_LIB}")
 178             SET(X11_Xxf86vm_LIB "Xxf86vm")
 179         ENDIF()
 180         LIST(APPEND LIBS ${X11_Xxf86vm_LIB})
 181     ENDIF()
 182 ENDIF()
 183
 184 INCLUDE(CheckIncludeFiles)
 185 INCLUDE(CheckFunctionExists)
 186 INCLUDE(CheckTypeSize)
 187 CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
 188 CHECK_INCLUDE_FILES(unistd.h    HAVE_UNISTD_H)
 189 CHECK_INCLUDE_FILES(sys/time.h  HAVE_SYS_TIME_H)
 190 CHECK_INCLUDE_FILES(stdbool.h   HAVE_STDBOOL_H)
 191 CHECK_INCLUDE_FILES(sys/param.h HAVE_SYS_PARAM_H)
 192 CHECK_INCLUDE_FILES(sys/ioctl.h HAVE_SYS_IOCTL_H)
 193 CHECK_INCLUDE_FILES(fcntl.h     HAVE_FCNTL_H)
 194 CHECK_INCLUDE_FILES(errno.h     HAVE_ERRNO_H)
 195 CHECK_INCLUDE_FILES(usbhid.h    HAVE_USBHID_H)
 196 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 197 CHECK_FUNCTION_EXISTS(vfprintf  HAVE_VFPRINTF)
 198 CHECK_FUNCTION_EXISTS(_doprnt   HAVE_DOPRNT)
 199 CHECK_FUNCTION_EXISTS(XParseGeometry   HAVE_XPARSEGEOMETRY)
 200 IF (NOT HAVE_XPARSEGEOMETRY)
 201    LIST(APPEND FREEGLUT_SRCS
 202         src/util/xparsegeometry_repl.c
 203         src/util/xparsegeometry_repl.h)
 204    SET(NEED_XPARSEGEOMETRY_IMPL TRUE)
 205 ENDIF()
 206 # decide on suitable type for internal time keeping, 64-bit if possible
 207 CHECK_INCLUDE_FILES(stdint.h    HAVE_STDINT_H)
 208 CHECK_INCLUDE_FILES(inttypes.h  HAVE_INTTYPES_H)
 209 IF (NOT (HAVE_STDINT_H OR HAVE_INTTYPES_H))
 210     IF (MSVC)
 211         # Some old Microsoft VC don't support unsigned long long, but all we
 212         # care about support unsigned __int64, so test for presence of that
 213         # type
 214         CHECK_TYPE_SIZE("unsigned __int64" U__INT64 BUILTIN_TYPES_ONLY)
 215     ELSEIF()
 216         CHECK_TYPE_SIZE("unsigned long long" ULONG_LONG BUILTIN_TYPES_ONLY)
 217     ENDIF()
 218 ENDIF()
 219
 220
 221 # The generated config.h is placed in the project's build directory, just to
 222 # ensure that all CMake-generated files are kept away from the main source tree.
 223 # As a result, the build directory must to be added to the include path list.
 224 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/config.h.in ${CMAKE_BINARY_DIR}/config.h)
 225 INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/include ${CMAKE_SOURCE_DIR}/src)
 226 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 227 IF(WIN32)
 228     # we also have to generate freeglut.rc, which contains the version
 229     # number
 230     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.rc.in ${CMAKE_BINARY_DIR}/freeglut.rc)
 231     IF (MSVC AND NOT CMAKE_CL_64)
 232         # .def file only for 32bit Windows builds with Visual Studio
 233         CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/src/freeglutdll.def.in ${CMAKE_BINARY_DIR}/freeglutdll.def)
 234     ENDIF()
 235 ENDIF()
 236
 237 IF(BUILD_SHARED_LIBS)
 238     ADD_LIBRARY(freeglut SHARED ${FREEGLUT_SRCS})
 239 ENDIF()
 240 IF(BUILD_STATIC_LIBS)
 241     ADD_LIBRARY(freeglut_static STATIC ${FREEGLUT_SRCS})
 242 ENDIF()
 243
 244
 245 IF(WIN32)
 246     LIST(APPEND LIBS winmm)
 247     IF(BUILD_SHARED_LIBS)
 248         SET_TARGET_PROPERTIES(freeglut PROPERTIES COMPILE_FLAGS -DFREEGLUT_EXPORTS)
 249     ENDIF()
 250     IF(BUILD_STATIC_LIBS)
 251         SET_TARGET_PROPERTIES(freeglut_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 252         # need to set machine:x64 for linker, at least for VC10, and
 253         # doesn't hurt for older compilers:
 254         # http://public.kitware.com/Bug/view.php?id=11240#c22768
 255         IF (CMAKE_CL_64)
 256             SET_TARGET_PROPERTIES(freeglut_static PROPERTIES STATIC_LIBRARY_FLAGS "/machine:x64")
 257         ENDIF()
 258     ENDIF()
 259 ELSE()
 260     # on UNIX we need to make sure:
 261     # - all shared libraries must have a soname/version, see :
 262     #   http://sourceware.org/autobook/autobook/autobook_91.html#SEC91
 263     #   http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
 264     #   Current: -version-info 12:0:9 -> 3.9.0
 265     # - the output library should be named glut so it'll be linkable with -lglut
 266     # - the shared library should link to the dependency libraries so that the user
 267     #   won't have to link them explicitly (they shouldn't have to know that we depend
 268     #   on Xrandr or Xxf86vm)
 269     SET_TARGET_PROPERTIES(freeglut PROPERTIES VERSION 3.9.0 SOVERSION 3 OUTPUT_NAME glut)
 270     SET_TARGET_PROPERTIES(freeglut_static PROPERTIES OUTPUT_NAME glut)
 271     IF(ANDROID)
 272         # Not in CMake toolchain file, because the toolchain
 273         # file is called several times and generally doesn't
 274         # seem to be meant for modifying CFLAGS:
 275         # '-mandroid' is not mandatory but doesn't hurt
 276         # '-O0 -gstabs+' helps the currently buggy GDB port
 277         # Too late to manipulate ENV: SET(ENV{CFLAGS} "$ENV{CFLAGS} -mandroid")
 278         # Not using _INIT variables, they seem to be used internally only
 279         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mandroid")
 280         SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -O0 -gstabs+")
 281     ENDIF()
 282 ENDIF()
 283 IF(BUILD_SHARED_LIBS)
 284     TARGET_LINK_LIBRARIES(freeglut ${LIBS})
 285 ENDIF()
 286 IF(BUILD_STATIC_LIBS)
 287     TARGET_LINK_LIBRARIES(freeglut_static ${LIBS})
 288 ENDIF()
 289
 290 IF(BUILD_SHARED_LIBS)
 291     INSTALL(TARGETS freeglut DESTINATION lib)
 292 ENDIF()
 293 IF(BUILD_STATIC_LIBS)
 294     INSTALL(TARGETS freeglut_static DESTINATION lib)
 295 ENDIF()
 296 INSTALL(FILES ${FREEGLUT_HEADERS} DESTINATION include/GL)
 297
 298
 299
 300 # Optionally build demos, on by default.
 301 option( FREEGLUT_BUILD_DEMOS "Build FreeGLUT demos." ON )
 302
 303 SET(DEMO_LIBS ${OPENGL_glu_LIBRARY} ${LIBS})
 304 # lib m for math, not needed on windows
 305 IF (NOT WIN32)
 306     LIST(APPEND DEMO_LIBS m)
 307 ENDIF()
 308
 309 MACRO(ADD_DEMO name)
 310     IF( FREEGLUT_BUILD_DEMOS )
 311         IF(BUILD_SHARED_LIBS)
 312             ADD_EXECUTABLE(${name} ${ARGN})
 313             TARGET_LINK_LIBRARIES(${name} ${DEMO_LIBS} freeglut)
 314         ENDIF()
 315         IF(BUILD_STATIC_LIBS)
 316             ADD_EXECUTABLE(${name}_static ${ARGN})
 317             TARGET_LINK_LIBRARIES(${name}_static ${DEMO_LIBS} freeglut_static)
 318             SET_TARGET_PROPERTIES(${name}_static PROPERTIES COMPILE_FLAGS -DFREEGLUT_STATIC)
 319         ENDIF()
 320     ENDIF()
 321 ENDMACRO()
 322
 323 ADD_DEMO(CallbackMaker   progs/demos/CallbackMaker/CallbackMaker.c)
 324 ADD_DEMO(Fractals        progs/demos/Fractals/fractals.c)
 325 ADD_DEMO(Fractals_random progs/demos/Fractals_random/fractals_random.c)
 326 ADD_DEMO(Lorenz          progs/demos/Lorenz/lorenz.c)
 327 ADD_DEMO(One             progs/demos/One/one.c)
 328 ADD_DEMO(Resizer         progs/demos/Resizer/Resizer.cpp)
 329 ADD_DEMO(shapes          progs/demos/shapes/shapes.c)
 330 ADD_DEMO(smooth_opengl3  progs/demos/smooth_opengl3/smooth_opengl3.c)
 331 ADD_DEMO(spaceball       progs/demos/spaceball/spaceball.c
 332                          progs/demos/spaceball/vmath.c
 333                          progs/demos/spaceball/vmath.h)
 334 ADD_DEMO(subwin          progs/demos/subwin/subwin.c)
 335 ADD_DEMO(timer           progs/demos/timer/timer.c)
 336
 337 # finally, if any demos are built, copy needed files to output directory
 338 # (currently, thats just the input file for the Fractals demo)
 339 IF(FREEGLUT_BUILD_DEMOS)
 340     # 1) copy fractals.dat from freeglut/progs/demos/Fractals
 341     IF(BUILD_SHARED_LIBS)
 342         SET(Frac_target Fractals)
 343     ELSE()
 344         SET(Frac_target Fractals_static)
 345     ENDIF()
 346     GET_TARGET_PROPERTY(DEMO_OUTPUT_DIRECTORY ${Frac_target} RUNTIME_OUTPUT_DIRECTORY)
 347     ADD_CUSTOM_COMMAND(
 348         TARGET ${Frac_target}
 349         POST_BUILD
 350         COMMAND ${CMAKE_COMMAND} -E copy
 351         ${PROJECT_SOURCE_DIR}/progs/demos/Fractals/fractals.dat
 352         ${DEMO_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}
 353     )
 354 ENDIF()
 355
 356 # pkg-config support, to install at $(libdir)/pkgconfig
 357 # Define static build dependencies
 358 IF(WIN32)
 359   SET(PC_LIBS_PRIVATE "-lopengl32 -lwinmm -lgdi32")
 360 ELSEIF(ANDROID)
 361   SET(PC_LIBS_PRIVATE "-llog -landroid -lGLESv2 -lEGL")
 362 ELSE()
 363   SET(PC_LIBS_PRIVATE "-lX11 -lXxf86vm -lXrandr -lGLESv2 -lEGL")
 364 ENDIF()
 365 # Client applications need to define FreeGLUT GLES version to
 366 # bootstrap headers inclusion in freeglut_std.h:
 367 IF(FREEGLUT_GLES2)
 368   SET(PC_CFLAGS "-DFREEGLUT_GLES2")
 369 ELSEIF(FREEGLUT_GLES1)
 370   SET(PC_CFLAGS "-DFREEGLUT_GLES1")
 371 ENDIF()
 372 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/freeglut.pc.in ${CMAKE_BINARY_DIR}/freeglut.pc @ONLY)
 373 INSTALL(FILES ${CMAKE_BINARY_DIR}/freeglut.pc DESTINATION share/pkgconfig)
 374 # TODO: change the library and .pc name when building for GLES,
 375 # e.g. -lglut-GLES2